면책 조항 / 경고
숨겨진 파일은 보통 이유로 숨겨져 있습니다. 자신이하고있는 일을 합리적으로 확신하는 경우에만 아래 스크립트를 사용하십시오. 다시 말해, 숨겨진 파일을 무작위로 삭제하여 시스템을 손상시키는 것은 사용자 자신의 잘못입니다.
Finder 내부에 숨겨진 파일 표시 / 표시 안 함을 전환하는 데 사용하는 스크립트는 다음과 같습니다 .
( 위의 Mateusz Szlosek는 열기 / 저장 대화 상자 에서 숨겨진 파일을 토글하는 OSX 기본 바로 가기 에 대해 언급했습니다)
내 스크립트와 지금까지 본 다른 스크립트의 차이점 :
대부분의 스크립트는 Finder를 종료 한 후 다른 작업을 수행하지 않습니다. 일반적으로 자동 Finder 재실행이 마지막 활성 폴더를 안정적으로 열지 않기 때문에 원래 있던 폴더로 다시 이동해야 함을 의미합니다.
대신 아래 스크립트는 마지막 활성 폴더, 즉 토글을 사용할 때 사용한 폴더이지만 숨겨진 파일을 표시하거나 표시하지 않는 폴더를 다시 열어 초점을 맞 춥니 다.
바로 가기 (cmd + shift +.)를 할당하고 Finder에서 숨겨진 파일로 작업하는 것이 훨씬 편리하다는 것을 알았습니다.
얼마 전이 사이트에 '마지막 폴더 다시 열기'기능을 추가 한 스크립트를 게시 한 Tetsujin에게 감사의 말을 전합니다.
on run {input, parameters}
tell application "Finder"
set var1 to POSIX path of (target of window 1 as alias)
end tell
set newHiddenVisiblesState to "YES"
set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
if oldHiddenVisiblesState is in {"1", "YES"} then
set newHiddenVisiblesState to "NO"
end if
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState
---- Sleep hack mentioned below. 0.5s minimum, 1-2s safer. Ugly, but (probably) unavoidable.
do shell script "killall Finder; sleep 0.5s"
tell application "Finder"
---- Close other windows if Finder managed to relaunch already
if application "Finder" is running then
close every window
end if
open (var1 as POSIX file)
activate
end tell
end run
스크립트를 사용하려면 : Automator에서 새 워크 플로우를 열고 "AppleScript 실행"을 드래그하여 위의 코드를 복사하여 붙여 넣은 다음 서비스 폴더 안에 저장하십시오 (보통 ~ / Library / Services /, afaik).
스크립트 실행을위한 바로 가기 첨부는이 사이트의 다른 곳에서 다루어야합니다. 바로 가기의 범위를 Finder로만 제한했습니다.
스타일 비고 :
원래 폴더를 수동으로 열기 전에 Finder를 죽인 후 '수면'을 사용하여 약간의 추악한 해킹에 의지해야합니다.
이 지연을 강제하지 않으면 OSX가 이미 Finder를 다시 시작하고 폴더를 열었을 가능성이 있습니다 (필자의 경험에서 마지막으로 활성화 된 폴더 일 필요는 없음). 내 자신의 '열린'명령과 함께 두 개의 (살해 불가능한, 심지어는) 파인더 프로세스가 실행되고 파인더가 더 이상 작동하지 않는 불쾌한 결과를 초래할 수 있습니다. 이 경우 로그 아웃했다가 다시 수정하면 시간이 많이 걸리므로 '수면'을 사용합니다.
수면 값이 0.5 초이면 나에게 도움이되지만 안전을 위해 약간 증가시킬 수 있습니다 (그런 다음 프로세스에 눈에 띄는 지연을 추가 함).
누군가 killall 신호를 보낸 후 Finder가 다시 시작되고 일부 창이 열리지 않는 방법을 알고 있거나 '수면'해킹을 제거하는 다른 방법을 알고 있다면 기뻐할 것입니다!
