OS X에서 동일한 응용 프로그램의 여러 전체 화면 창을 전환하는 방법은 무엇입니까? [복제]

전체 화면 모드에서 동일한 앱의 여러 인스턴스 (Chrome 별도의 창 또는 여러 IntelliJ 프로젝트 일 수 있음)를 실행하는 경우을 사용하여 구체적인 앱으로 이동할 수 없으며 앱의 ⌘-Tab아이콘 하나만 표시되지만 백그라운드에서 실행 중입니다.

또한 응용 프로그램 별 바로 가기가 없습니다.

⌘-Tab글로벌 앱 아이콘 대신 쇼 인스턴스 를 만드는 방법이 있습니까?

불행히도 동일한 응용 프로그램의 전체 화면 창간에 전환하는 바로 가기 는 없습니다 .

당신은이 두 가지 대안 적합하지만 충분하지 않습니다 :

1. 공간 / 데스크톱 간을 전환하거나 특정 항목으로 이동하는 바로 가기

2. 공간 / 데스크톱 간 전환 제스처

이 워크 플로가 제대로 작동하려면 전체 화면 창을 나란히 두십시오 .

Mission Control 외에도 Dock도 있습니다.

반복적으로 클릭하면 응용 프로그램의 전체 화면 공간을 순환합니다.

Applescript를 키보드 단축키 / 트랙 패드 제스처에 바인딩하는 방법을 알고 있다면 이것이 바로 해답입니다.

스크립트는 보편적입니다. 가장 일반적인 용어를 사용하여 가능한 많은 시나리오를 포함시킵니다. Finder, Script Editor 및 Firefox에서 테스트했습니다. 오류가 없습니다.

그러나 다음과 같은 경고가 있습니다.

1. 스크립트는 앱 인스턴스가 하나만있는 경우에만 작동합니다. (BTW, OP의 텍스트에는 여전히 "여러 인스턴스"라고 표시되어 있습니다.) 여러 인스턴스로 작업 할 수는 있지만 다른 날의 싸움입니다.

2. 이 스크립트는 Window메뉴 에서 창의 목록을 아래로 스크롤 합니다. 본질적으로 확인 표시 ( "✓")가있는 항목 바로 아래의 항목을 클릭합니다. "✓"가있는 항목이 마지막 항목 인 경우 스크립트는 마지막 구분선 아래에서 첫 번째 항목을 클릭합니다. 반대 방향으로 돌아가는 스크립트는이 스크립트를 수정하여 얻을 수 있습니다. 그러나 두 스크립트를 단일 스크립트로 결합하는 방법을 알 수 없습니다.

3. try을 생산 문은 errorMessage내가의 인덱스를 생산하는 알 CPU를 가장 효율적인 방법입니다 separator. 더 좋은 방법을 알고 있다면 저를 계몽하십시오.

스크립트 :

tell application "System Events" to tell (first application process whose frontmost is true) to tell menu bar 1 to tell menu "Window"

    set cellingSeperator to last menu item whose value of attribute "AXEnabled" is false
    set checkedItem to first menu item whose value of attribute "AXMenuItemMarkChar" is "✓"

    try
        set intentionalError to cellingSeperator as Unicode text
    on error errorMessage
        set firstItemIndex to (characters ((offset of "«class menI» " in errorMessage) + 13) through ((offset of " of" in errorMessage) - 1) of errorMessage as string as integer) + 1
    end try

    repeat with iterator from firstItemIndex to number of menu items
        if value of attribute "AXFrame" of menu item iterator is equal to value of attribute "AXFrame" of checkedItem then
            set clickItemIndex to iterator + 1
            exit repeat
        end if
    end repeat

    if clickItemIndex is greater than number of menu items then set clickItemIndex to firstItemIndex

    tell menu item clickItemIndex to perform action "AXPress"

end tell