기본 브라우저에서 폴더 열기

localhost에서 개발 한 많은 웹 프로젝트가 있습니다. 일반적으로 이들을 얻으려면 루트 디렉토리에서 탐색하거나 URL을 북마크해야합니다.

기본 브라우저에서 OS 디렉토리 / 폴더를 열 수 있기를 원합니다. 예를 들어 '프로젝트 A'폴더를 마우스 오른쪽 버튼으로 클릭하고 '브라우저에서 열기'를 선택하고 직접 이동하십시오. URL의 시작 부분을 지정할 수 있기를 바래서 URL을 변경할 수 있습니다. file:/// 에 http://localhost/ 또는 mymac.local/.

나는 이것이 Applescript로 할 수 있다고 상상하고있다. 그러나 나는 그것에 경험이 없다. 이것을 달성 할 수있는 방법이 있습니까?

Automator를 통해 오른쪽 클릭 항목을 추가 할 수 있습니다. Automator를 열고이 워크 플로를 복사하십시오.

저장하면 서비스 아래의 오른쪽 클릭 메뉴에 나타납니다.

URL 프로토콜을 변경하면 무엇을 의미하는지 완전히 알 수는 없지만이를 수정하여 원하는 것을 성취 할 수 있어야합니다.

나는 Applescript가 서비스로 저장했다고 생각한다.
( "서비스 받기를 선택했습니다. files or folders ...에서 Finder ")

on run {input, parameters}
    set basePath to "users/username/folder/"
    set baseURL to "http://localhost"

    repeat with i in input
        tell application "Safari"
            if not (exists (document 1)) then
                --
                -- Safari is *Not* Opened, Call Open New Window Function, Go To Preferred Page
                -- and Activate Safari to Enable Scripting
                --
                tell application "Safari" to activate
                my open_new_window()
                --
                -- Set Safari Location to Preferred Page
                -- 
                set theFileName to POSIX path of i
                set thePath to text (length of basePath+1) thru -1 of theFileName
                set the URL of document 1 to baseURL & thePath
            else
                --
                -- Safari is Opened, Bring it To Front and Open New Tab w/Preferred Page
                --
                if (exists (URL of document 1)) then
                    my open_new_tab()
                end if
                --
                -- and Activate Safari to Enable Scripting
                --
                tell application "Safari" to activate
                --
                -- Set Safari Location to Preferred Page
                --
                set theFileName to POSIX path of i
                set thePath to text (length of basePath+1) thru -1 of theFileName
                set the URL of document 1 to baseURL & thePath
            end if
        end tell

    end repeat

    return input
end run

--
-- Open New Window Function
--
on open_new_window()
    tell application "Safari" to activate
    tell application "System Events"
        tell process "Safari"
            click menu item "New Window" of menu "File" of menu bar 1
        end tell
    end tell
end open_new_window

--
-- Open New Tab Function
--
on open_new_tab()
    tell application "Safari" to activate
    tell application "System Events"
        tell process "Safari"
            click menu item "New Tab" of menu "File" of menu bar 1
        end tell
    end tell
end open_new_tab

몇 가지 출처에서 함께 자르다!