PWM 주파수를 25kHz로 설정

현재 다음 코드를 사용하여 4 개의 PWM 핀을 약 31kHz로 설정할 수 있습니다.

void setup()
{
    TCCR1B = TCCR1B & B11111000 | B00000001; // Set PWM frequency for D9 & D10:
    pinMode(pwmPin9, OUTPUT); // Sets the pin as output
    pinMode(pwmPin10, OUTPUT); // Sets the pin as output


    TCCR2B = TCCR2B & B11111000 | B00000001; // Set PWM for D3 & D11
    pinMode(pwmPin3, OUTPUT); // Sets the pin as output
    pinMode(pwmPin11, OUTPUT); // Sets the pin as output
}

이 설정을 어딘가에서 찾았지만이 4 개의 PWM 핀을 약 25 kHz로 설정하는 방법을 모르겠습니다. 어떻게 가능합니까?

단일 Arduino Uno에서 161 단계로 25kHz에서 4 개의 PWM 채널을 가질 수 있다는 것을 깨달았 으므로이 두 번째 답변을 게시하고 있습니다. 이것은 포함 8 MHz의 메인 클럭 주파수를 변경 빠른 절반을 실행 전체 프로그램 이후 부작용을 보유하고 있습니다. 또한 세 타이머 아두 이노 타이밍 기능을 푸는 수단을 재구성하는 것을 포함한다 ( millis(), micros(), delay()및 delayMicroseconds()). 이러한 트레이드 오프가 허용 가능한 경우 다음과 같은 방식으로 진행됩니다.

void setup()
{
    // Set the main system clock to 8 MHz.
    noInterrupts();
    CLKPR = _BV(CLKPCE);  // enable change of the clock prescaler
    CLKPR = _BV(CLKPS0);  // divide frequency by 2
    interrupts();

    // Configure Timer 0 for phase correct PWM @ 25 kHz.
    TCCR0A = 0;           // undo the configuration done by...
    TCCR0B = 0;           // ...the Arduino core library
    TCNT0  = 0;           // reset timer
    TCCR0A = _BV(COM0B1)  // non-inverted PWM on ch. B
        | _BV(WGM00);  // mode 5: ph. correct PWM, TOP = OCR0A
    TCCR0B = _BV(WGM02)   // ditto
        | _BV(CS00);   // prescaler = 1
    OCR0A  = 160;         // TOP = 160

    // Same for Timer 1.
    TCCR1A = 0;
    TCCR1B = 0;
    TCNT1  = 0;
    TCCR1A = _BV(COM1A1)  // non-inverted PWM on ch. A
        | _BV(COM1B1)  // same on ch. B
        | _BV(WGM11);  // mode 10: ph. correct PWM, TOP = ICR1
    TCCR1B = _BV(WGM13)   // ditto
        | _BV(CS10);   // prescaler = 1
    ICR1   = 160;

    // Same for Timer 2.
    TCCR2A = 0;
    TCCR2B = 0;
    TCNT2  = 0;
    TCCR2A = _BV(COM2B1)  // non-inverted PWM on ch. B
        | _BV(WGM20);  // mode 5: ph. correct PWM, TOP = OCR2A
    TCCR2B = _BV(WGM22)   // ditto
        | _BV(CS20);   // prescaler = 1
    OCR2A  = 160;
}

void loop()
{
    analogWrite( 3,   1);  // duty cycle = 1/160
    analogWrite( 5,  53);  // ~ 1/3
    analogWrite( 9, 107);  // ~ 2/3
    analogWrite(10, 159);  // 159/160
}

다른 답변 과 달리 수정 버전이 필요하지 않습니다 analogWrite(). 표준 버전이 정상적으로 작동합니다. 다음 사항 만주의해야합니다.

1. 기록 된 값은 0 (항상 LOW를 의미 함)과 160 (항상 HIGH)을 포함해야합니다.
2. 핀 3, 5, 9 및 10 만 사용할 수 있습니다. 시도 analogWrite() 만 PWM 출력을 제공하지 않을 것이다 핀 (6) 또는 (11), 또한 각 핀 (5) 또는 (3)에 주파수를 변경한다.

위상 보정 PWM 모드에서 타이머 1을 25kHz로 순환하도록 타이머 1을 구성 할 수 있으며 핀 9와 10에서 두 개의 출력을 다음과 같이 사용할 수 있습니다.

// PWM output @ 25 kHz, only on pins 9 and 10.
// Output value should be between 0 and 320, inclusive.
void analogWrite25k(int pin, int value)
{
    switch (pin) {
        case 9:
            OCR1A = value;
            break;
        case 10:
            OCR1B = value;
            break;
        default:
            // no other pin will work
            break;
    }
}

void setup()
{
    // Configure Timer 1 for PWM @ 25 kHz.
    TCCR1A = 0;           // undo the configuration done by...
    TCCR1B = 0;           // ...the Arduino core library
    TCNT1  = 0;           // reset timer
    TCCR1A = _BV(COM1A1)  // non-inverted PWM on ch. A
           | _BV(COM1B1)  // same on ch; B
           | _BV(WGM11);  // mode 10: ph. correct PWM, TOP = ICR1
    TCCR1B = _BV(WGM13)   // ditto
           | _BV(CS10);   // prescaler = 1
    ICR1   = 320;         // TOP = 320

    // Set the PWM pins as output.
    pinMode( 9, OUTPUT);
    pinMode(10, OUTPUT);
}

void loop()
{
    // Just an example:
    analogWrite25k( 9, 110);
    analogWrite25k(10, 210);
    for (;;) ;  // infinite loop
}

값을 0으로 쓰면 analogWrite25k()핀은 항상 낮음을, 320은 항상 높음을 의미합니다. 일반 analogWrite() 은 거의 작동하지만 255를 320과 동일하게 해석합니다 (즉, 항상 HIGH).

이 코드는 Arduino Uno 또는 이와 유사한 보드 (ATmega168 또는 328 @ 16 MHz)를 가정합니다. 여기에 사용 된 방법에는 16 비트 타이머가 필요하므로 Uno에서 유일하게 사용할 수있는 타이머 1을 사용합니다. 그렇기 때문에 두 개의 출력 만 사용할 수 있습니다. 이 방법은 16 비트 타이머를 사용하여 다른 AVR 기반 보드에 적용 할 수 있습니다. Gerben이 지적했듯이 타이머에는 해당 ICRx 레지스터가 있어야합니다. Arduino Mega에는 각각 3 개의 출력을 가진 4 개의 타이머가 있습니다.