기호를 사용하여 수학적 진술을 작성하십시오.

• There exists at least one non-negative integer( E실존 수량 화기 로 작성 )
• All non-negative integers( A, 범용 정량 자로 작성 됨 )
• + (부가)
• * (곱셈)
• = (평등)
• >, <(비교 연산자)
• &(그리고), |(또는), !(아님)
• (, )(그룹화 용)
• 변수 이름

이것은 진술과 같습니다

π + e * a가 합리적 이도록 합리적인 수 a가 있습니다.

(물론, $\pi =3.1415...$ 는 원주와 나눈 둘레와 같은 수학적 상수이고, $e=2.7182...$ 는 오일러 수입니다 )

귀하의 진술이 실제로 상기 진술과 동일하다는 것을 증명해야합니다.

분명히,이 문제를 해결하는“가장 짧은”방법은 진술을 참 또는 거짓으로 증명 한 다음, 모든 참 진술이 모두 거짓 진술과 같이 서로 동일하므로 사소한 참 또는 거짓 진술로 대답하는 것입니다.

그러나 주어진 진술의 진실 가치는 수학에서 해결되지 않은 문제입니다 . 우리는 $\pi+e$ 가 비이성적 인지조차 알지 못합니다 ! 따라서 획기적인 수학적 연구를 제외하고는 "간단한"동등한 진술을 찾아서 그에 상응하는 것을 증명하고 가능한 한 간략하게 설명해야합니다.

채점

E A + * = > < & |그리고 !각각의 점수에 1을 추가합니다. (그리고 )점수에 아무것도 추가하지 마십시오. 각 변수 이름은 점수에 1을 더합니다.

예 : E x (A ba x+ba>x*(x+ba))점수 13 ( E x A ba x + ba > x * x + ba)

최저 점수가 이깁니다.

노트 :

_{면책 조항 :이 메모는 OP가 작성하지 않았습니다.}

• 입니다 하지 코드 골프 도전. 답변은 코드를 포함하지 않아도됩니다.
• 이것은 진술을 작성하고 다른 진술과 동등한 것으로 증명해야하기 때문에 증명 골프 도전 과 유사하지만 그렇지는 않습니다 .
• 위의 진술이 참 / 거짓임을 입증 할 수있는 경우 사소한 사실 (예 : 모든 x, x = x Ax x=x) 또는 사소한 거짓 진술 (예 : 모든 x, x> x Ax x>x) 을 제출할 수 있습니다.
• 추가 기호 (proof-golf의 lemma와 유사)를 사용할 수 있지만 점수는 사용하지 않는 것과 동일하게 계산됩니다.
  예를 들어, a => b를 의미로 정의 하면 증명에 (!a) | b사용할 때마다 =>점수가 2 씩 증가합니다.

• 상수는 허용 된 기호에 나열되어 있지 않으므로 사용해서는 안됩니다.
  예를 들어 : 명령문 1 > 0과 같이 쓸 수있다

  
  Forall zero: ( zero + zero = zero ) =>
  Forall one: ( Forall x: x * one = x ) =>
  one > zero
  

  23의 점수에. ( =>사용 당 2 비용 이 든다는 것을 기억하십시오 ).

힌트

• 자연 상수를 사용하기 위해 할 수 있습니다 E0, 0+0=0 & E1, At 1*t=t &(따라서 =>더 넓은 것이 필요하지 않습니다 ). 1보다 큰 숫자의 경우 1을 추가하십시오.

671

E a (a+a>a*a & (E b (E c (E d (A e (A f (f<a | (E g (E h (E i ((A j ((!(j=(f+f+h)*(f+f+h)+h | j=(f+f+a+i)*(f+f+a+i)+i) | j+a<e & (E k ((A l (!(l>a & (E m k=l*m)) | (E m l=e*m))) & (E l (E m (m<k & g=(e*l+(j+a))*k+m)))))) & (A k (!(E l (l=(j+k)*(j+k)+k+a & l<e & (E m ((A n (!(n>a & (E o m=n*o)) | (E o n=e*o))) & (E n (E o (o<m & g=(e*n+l)*m+o))))))) | j<a+a & k=a | (E l (E m ((E n (n=(l+m)*(l+m)+m+a & n<e & (E o ((A p (!(p>a & (E q o=p*q)) | (E q p=e*q))) & (E p (E q (q<o & g=(e*p+n)*o+q))))))) & j=l+a+a & k=j*j*m))))))) & (E j (E k (E l ((E m (m=(k+l)*(k+l)+l & (E n (n=(f+m)*(f+m)+m+a & n<e & (E o ((A p (!(p>a & (E q o=p*q)) | (E q p=e*q))) & (E p (E q (q<o & j=(e*p+n)*o+q))))))))) & (A m (A n (A o (!(E p (p=(n+o)*(n+o)+o & (E q (q=(m+p)*(m+p)+p+a & q<e & (E r ((A s (!(s>a & (E t r=s*t)) | (E t s=e*t))) & (E s (E t (t<r & j=(e*s+q)*r+t))))))))) | m<a & n=a & o=f | (E p (E q (E r (!(E s (s=(q+r)*(q+r)+r & (E t (t=(p+s)*(p+s)+s+a & t<e & (E u ((A v (!(v>a & (E w u=v*w)) | (E w v=e*w))) & (E v (E w (w<u & j=(e*v+t)*u+w))))))))) | m=p+a & n=(f+a)*q & o=f*r)))))))) & (E m (m=b*(h*f)*l & (E n (n=b*(h*f+h)*l & (E o (o=c*(k*f)*i & (E p (p=c*(k*f+k)*i & (E q (q=d*i*l & (m+o<q & n+p>q | m<p+q & n>o+q | o<n+q & p>m+q))))))))))))))))))))))))))

작동 원리

먼저 a와 (π + e · a)의 공통 공통 분모를 곱하여 다음과 같이 조건을 다시 씁니다. a · π + b · e = c 또는 a, b, c a · π-b · e = c 또는 -a · π + b · e = c. 사인 문제를 해결하려면 세 가지 경우가 필요합니다.

그런 다음 합리적인 근사를 통해 π와 e에 대해 이야기하기 위해 이것을 다시 작성해야합니다. b · e₁ 또는 a · π₀ − b · e₁ <c <a · π₁ + b · e₀ 또는 -a · π₁ + b · e₀ <c <-a · π₀ + b · e₁. (이제“0이 아님”조건은 무료로 제공됩니다.)

이제 어려운 부분입니다. 이 합리적인 근사치는 어떻게 얻습니까? 우리는 같은 공식을 사용하고 싶습니다

2/1 · 2/3 · 4/3 · 4/5 ⋯ (2 · k) / (2 · k + 1) <π / 2 <2/1 · 2/3 · 4/3 · 4/5 ⋯ (2 · k) / (2 · k + 1) · (2 ​​· k + 2) / (2 · k + 1),

((k + 1) / k) ^k <e <((k + 1) / k) ^{k + 1} ,

그러나 이러한 제품의 반복적 인 정의를 작성하는 확실한 방법은 없습니다. 그래서 우리는 이 Quora post 에서 처음 설명한 약간의 기계를 만듭니다. 밝히다:

나누기 (d, a) : = ∃b, a = d · b,

powerOfPrime (a, p) : = ∀b, ((b> 1 및 나누기 (b, a)) ⇒ 나누기 (p, b)),

이는 iff a = 1 또는 p = 1이거나, p는 소수이고 a는 그것의 거듭 제곱입니다. 그때

isDigit (a, s, p) : = a <p and ∃b, (powerOfPrime (b, p) 및 ∃qr, (r <b and s = (p · q + a) · b + r))

a = 0이면 만족되거나 a는 base-p 숫자 s의 숫자입니다. 이를 통해 base-p 숫자의 숫자를 사용하여 유한 세트를 나타낼 수 있습니다. 이제 최종 상태가 세트에 있도록 중간 상태 세트가 존재하며 세트의 모든 상태가 초기 상태이거나 다른 단계의 한 단계에서 다음 단계를 수행하여 반복 계산을 변환 할 수 있습니다. 세트.

자세한 내용은 아래 코드에 있습니다.

하스켈 에서 코드 생성

{-# LANGUAGE ImplicitParams, TypeFamilies, Rank2Types #-}

-- Define an embedded domain-specific language for propositions.
infixr 2 :|

infixr 3 :&

infix 4 :=

infix 4 :>

infix 4 :<

infixl 6 :+

infixl 7 :*

data Nat v
  = Var v
  | Nat v :+ Nat v
  | Nat v :* Nat v

instance Num (Nat v) where
  (+) = (:+)
  (*) = (:*)
  abs = id
  signum = error "signum Nat"
  fromInteger = error "fromInteger Nat"
  negate = error "negate Nat"

data Prop v
  = Ex (v -> Prop v)
  | Al (v -> Prop v)
  | Nat v := Nat v
  | Nat v :> Nat v
  | Nat v :< Nat v
  | Prop v :& Prop v
  | Prop v :| Prop v
  | Not (Prop v)

-- Display propositions in the given format.
allVars :: [String]
allVars = do
  s <- "" : allVars
  c <- ['a' .. 'z']
  pure (s ++ [c])

showNat :: Int -> Nat String -> ShowS
showNat _ (Var v) = showString v
showNat prec (a :+ b) =
  showParen (prec > 6) $ showNat 6 a . showString "+" . showNat 7 b
showNat prec (a :* b) =
  showParen (prec > 7) $ showNat 7 a . showString "*" . showNat 8 b

showProp :: Int -> Prop String -> [String] -> ShowS
showProp prec (Ex p) (v:free) =
  showParen (prec > 1) $ showString ("E " ++ v ++ " ") . showProp 4 (p v) free
showProp prec (Al p) (v:free) =
  showParen (prec > 1) $ showString ("A " ++ v ++ " ") . showProp 4 (p v) free
showProp prec (a := b) _ =
  showParen (prec > 4) $ showNat 5 a . showString "=" . showNat 5 b
showProp prec (a :> b) _ =
  showParen (prec > 4) $ showNat 5 a . showString ">" . showNat 5 b
showProp prec (a :< b) _ =
  showParen (prec > 4) $ showNat 5 a . showString "<" . showNat 5 b
showProp prec (p :& q) free =
  showParen (prec > 3) $
  showProp 4 p free . showString " & " . showProp 3 q free
showProp prec (p :| q) free =
  showParen (prec > 2) $
  showProp 3 p free . showString " | " . showProp 2 q free
showProp _ (Not p) free = showString "!" . showProp 9 p free

-- Compute the score.
scoreNat :: Nat v -> Int
scoreNat (Var _) = 1
scoreNat (a :+ b) = scoreNat a + 1 + scoreNat b
scoreNat (a :* b) = scoreNat a + 1 + scoreNat b

scoreProp :: Prop () -> Int
scoreProp (Ex p) = 2 + scoreProp (p ())
scoreProp (Al p) = 2 + scoreProp (p ())
scoreProp (p := q) = scoreNat p + 1 + scoreNat q
scoreProp (p :> q) = scoreNat p + 1 + scoreNat q
scoreProp (p :< q) = scoreNat p + 1 + scoreNat q
scoreProp (p :& q) = scoreProp p + 1 + scoreProp q
scoreProp (p :| q) = scoreProp p + 1 + scoreProp q
scoreProp (Not p) = 1 + scoreProp p

-- Convenience wrappers for n-ary exists and forall.
class OpenProp p where
  type OpenPropV p
  ex, al :: p -> Prop (OpenPropV p)

instance OpenProp (Prop v) where
  type OpenPropV (Prop v) = v
  ex = id
  al = id

instance (OpenProp p, a ~ Nat (OpenPropV p)) => OpenProp (a -> p) where
  type OpenPropV (a -> p) = OpenPropV p
  ex p = Ex (ex . p . Var)
  al p = Al (al . p . Var)

-- Utility for common subexpression elimination.
cse :: Int -> Nat v -> (Nat v -> Prop v) -> Prop v
cse uses x cont
  | (scoreNat x - 1) * (uses - 1) > 6 = ex (\x' -> x' := x :& cont x')
  | otherwise = cont x

-- p implies q.
infixl 1 ==>

p ==> q = Not p :| q

-- Define one as the unique n with n+n>n*n.
withOne ::
     ((?one :: Nat v) =>
        Prop v)
  -> Prop v
withOne p =
  ex
    (\one ->
       let ?one = one
       in one + one :> one * one :& p)

-- a is a multiple of d.
divides d a = ex (\b -> a := d * b)

-- a is a power of p (assuming p is prime).
powerOfPrime a p = al (\b -> b :> ?one :& divides b a ==> divides p b)

-- a is 0 or a digit of the base-p number s (assuming p is prime).
isDigit a s p =
  cse 2 a $ \a ->
    a :< p :&
    ex
      (\b -> powerOfPrime b p :& ex (\q r -> r :< b :& s := (p * q + a) * b + r))

-- An injection from ℕ² to ℕ, for representing tuples.
pair a b = (a + b) ^ 2 + b

-- πn₀/πd < π/4 < πn₁/πd, with both fractions approaching π/4 as k
-- increases:
-- πn₀ = 2²·4²·6²⋯(2·k)²·k
-- πn₁ = 2²·4²·6²⋯(2·k)²·(k + 1)
-- πd = 1²⋅3²·5²⋯(2·k + 1)²
πBound p k cont =
  ex
    (\s x πd ->
       al
         (\i ->
            (i := pair (k + k) x :| i := pair (k + k + ?one) πd ==>
             isDigit (i + ?one) s p) :&
            al
              (\a ->
                 isDigit (pair i a + ?one) s p ==>
                 ((i :< ?one + ?one :& a := ?one) :|
                  ex
                    (\i' a' ->
                       isDigit (pair i' a' + ?one) s p :&
                       i := i' + ?one + ?one :& a := i ^ 2 * a')))) :&
       let πn₀ = x * k
           πn₁ = πn₀ + x
       in cont πn₀ πn₁ πd)

-- en₀/ed < e < en₁/ed, with both fractions approaching e as k
-- increases:
-- en₀ = (k + 1)^k * k
-- en₁ = (k + 1)^(k + 1)
-- ed = k^(k + 1)
eBound p k cont =
  ex
    (\s x ed ->
       cse 3 (pair x ed) (\y -> isDigit (pair k y + ?one) s p) :&
       al
         (\i a b ->
            cse 3 (pair a b) (\y -> isDigit (pair i y + ?one) s p) ==>
            (i :< ?one :& a := ?one :& b := k) :|
            ex
              (\i' a' b' ->
                 cse 3 (pair a' b') (\y -> isDigit (pair i' y + ?one) s p) ==>
                 i := i' + ?one :& a := (k + ?one) * a' :& b := k * b')) :&
       let en₀ = x * k
           en₁ = en₀ + x
       in cont en₀ en₁ ed)

-- There exist a, b, c ∈ ℕ (not all zero) with a·π/4 + b·e = c or
-- a·π/4 = b·e + c or b·e = a·π/4 + c.
prop :: Prop v
prop =
  withOne $
  ex
    (\a b c ->
       al
         (\p k ->
            k :< ?one :|
            (πBound p k $ \πn₀ πn₁ πd ->
               eBound p k $ \en₀ en₁ ed ->
                 cse 3 (a * πn₀ * ed) $ \x₀ ->
                   cse 3 (a * πn₁ * ed) $ \x₁ ->
                     cse 3 (b * en₀ * πd) $ \y₀ ->
                       cse 3 (b * en₁ * πd) $ \y₁ ->
                         cse 6 (c * πd * ed) $ \z ->
                           (x₀ + y₀ :< z :& x₁ + y₁ :> z) :|
                           (x₀ :< y₁ + z :& x₁ :> y₀ + z) :|
                           (y₀ :< x₁ + z :& y₁ :> x₀ + z))))

main :: IO ()
main = do
  print (scoreProp prop)
  putStrLn (showProp 0 prop allVars "")

온라인으로 사용해보십시오!

270

E1                                                                              { Exist 1, defined when Any k introduced }
Ec1 Ec2 Ec3 Ec4 Ec5 Ak k*1=k & c3>1 & ( En0 An n<n0 |                           { for large enough n, |(c1-c4)e+c3(4-pi)/8+(c2-c5)|<1/k }
Ex Ep Ew Emult At (Eb ((b>1 & Eh b*h=t) &! Eh h*p=b)) |                         { x read in base-p, then each digit in base-w. t as a digit }
Ee1 Ee2 Ehigher Elower e2<p & lower<t & ((higher*p+e1)*p+e2)*t+lower=x &        { last digit e1, this digit e2 }
    { Can infer that e2=w+1 | e1<=e2 & u1<=u2 & i1<=i2 & s1<=s2 & t1<=t2, so some conditions omitted }
Ei1 Es1 Et1 Eu1 (((u1*w)+i1)*w+t1)*w+s1=e1 &                                    { (u,i,t,s) }
Ei2 Es2 Et2 Eu2 i2<w & s2<w & t2<w & (((u2*w)+i2)*w+t2)*w+s2=e2 &               { e2=1+w is initial state u=i=0, s=t=1 }
(e2=w+1 | e1=e2 | i2=i1+1+1 & s2=s1*(n+1) & t2=t1*n &                           { i=2n, s=(n+1)^n, mult=t=n^n, s/mult=e }
Eg1 Eg2 g1+1=(i2+i2)*(i2+i2) & g1*u1+mult=g1*u2+g2 & g2<g1) &                   { u/mult=sum[j=4,8,...,4n]1/(j*j-1)=(4-pi)/8. mult=g1*(u2-u1)+g2 }
(t>1 | i2=n+n & t2=mult & Ediff Ediff2                                          { check at an end t=1 }
c1*s2+c2*mult+c3*u2+diff=c4*s2+c5*mult+diff2 & k*(diff+diff2)<mult))            { |diff-diff2|<=diff+diff2<mult/k, so ...<1/k }

a|b&c이다 a|(b&c)나는이 괄호를 제거하면 어쨌든 그들은 자유 야, 더 잘하게 생각하기 때문이다.

"(expr)".replace(/\{.*?\}/g,'').match(/[a-z0-9]+|[^a-z0-9\s\(\)]/g)토큰을 계산하기 위해 JavaScript 를 사용했습니다 .