x86 머신 코드 (128 비트 SSE1 & AVX를 사용한 SIMD 4x 플로트) 94 바이트
x86 머신 코드 (256 비트 AVX를 사용하는 SIMD 4x 이중) 123 바이트
float문제의 테스트 사례를 통과하지만 루프 종료 임계 값이 충분히 작아서 임의의 입력으로 무한 루프에 빠지기 쉽습니다.
SSE1 묶음 단 정밀도 명령어의 길이는 3 바이트이지만 SSE2와 간단한 AVX 명령어의 길이는 4 바이트입니다. (같은 스칼라 단일 명령의 sqrtss길이도 4 바이트이므로 sqrtps낮은 요소 만 신경 쓰더라도 사용합니다. 최신 하드웨어의 sqrtss보다 느리지 않습니다). 비파괴 대상으로 AVX를 사용하여 movaps + op에 비해 2 바이트를 절약했습니다.
이중 버전에서는 movlhps64 비트 청크를 복사하기 위해 여전히 몇 가지 작업을 수행 할 수 있습니다 (종종 수평 합의 하위 요소 만 고려하기 때문에). 256 비트 SIMD 벡터의 수평 합은 또한 floatvextractf128 의 느리지 만 작은 2 배 haddps전략에 비해 높은 절반을 얻는 데 추가 가 필요합니다 . 그만큼double버전에는 2x 4 바이트 대신 2x 8 바이트 상수가 필요합니다. 전체적으로 float버전 크기의 4/3에 가깝습니다 .
mean(a,b) = mean(a,a,b,b)이 4 가지 방법 모두에 대해 입력을 4 개까지 간단히 복제 할 수 있으며 length = 2를 구현할 필요가 없습니다. 따라서 우리는 예를 들어 기하 평균을 4th-root = sqrt (sqrt)로 하드 코딩 할 수 있습니다. 그리고 하나의 FP 상수 만 필요합니다 4.0.
우리는 모두 4의 단일 SIMD 벡터를 가지고 있습니다 [a_i, b_i, c_i, d_i]. 이로부터 우리는 4 개의 평균을 별도의 레지스터에서 스칼라로 계산하고 다음 반복을 위해 다시 섞습니다. (SIMD 벡터에 대한 수평 작업은 불편하지만, 균형을 잡을 수있는 충분한 경우에 4 가지 요소 모두에 대해 동일한 작업을 수행해야합니다. x87 버전으로 시작했지만 시간이 오래 걸리고 재미 있지 않았습니다.)
의 루프 종료 조건 }while(quadratic - harmonic > 4e-5)(또는보다 작은 상수 double) 은 @RobinRyder의 R answer 및 Kevin Cruijssen의 Java 답변을 기반으로합니다 . 2 차 평균은 항상 가장 큰 크기이며 고조파 평균은 항상 가장 작습니다 (반올림 오류 무시). 수렴을 감지하기 위해이 둘 사이의 델타를 확인할 수 있습니다. 산술 평균을 스칼라 결과로 반환합니다. 일반적으로 그 둘 사이에 있으며 반올림 오류에 가장 취약합니다.
부동 버전 : float meanmean_float_avx(__m128);arg와 마찬가지로 호출 가능하며 xmm0의 반환 값. (따라서 x86-64 System V 또는 Windows x64 벡터 호출이지만 x64 빠른 호출은 아닙니다.) 또는 return-type을 다음과 같이 선언하십시오.__m128 하여 2 차 및 고조파 평균을 테스트 할 수 있도록합니다.
이 테이크 2 개 분리시키는 floatXMM0와 XMM1에 인수하는 것은 1 개의 여분 바이트를 요할 것입니다 : 우리는 필요한 것 shufps(대신의 IMM8와 unpcklps xmm0,xmm0함께 셔플 2 개 입력을 중복).
40 address align 32
41 code bytes global meanmean_float_avx
42 meanmean_float_avx:
43 00000000 B9[52000000] mov ecx, .arith_mean ; allows 2-byte call reg, and a base for loading constants
44 00000005 C4E2791861FC vbroadcastss xmm4, [rcx-4] ; float 4.0
45
46 ;; mean(a,b) = mean(a,b,a,b) for all 4 types of mean
47 ;; so we only ever have to do the length=4 case
48 0000000B 0F14C0 unpcklps xmm0,xmm0 ; [b,a] => [b,b,a,a]
49
50 ; do{ ... } while(quadratic - harmonic > threshold);
51 .loop:
52 ;;; XMM3 = geometric mean: not based on addition. (Transform to log would be hard. AVX512ER has exp with 23-bit accuracy, but not log. vgetexp = floor(lofg2(x)), so that's no good.)
53 ;; sqrt once *first*, making magnitudes closer to 1.0 to reduce rounding error. Numbers are all positive so this is safe.
54 ;; both sqrts first was better behaved, I think.
55 0000000E 0F51D8 sqrtps xmm3, xmm0 ; xmm3 = 4th root(x)
56 00000011 F30F16EB movshdup xmm5, xmm3 ; bring odd elements down to even
57 00000015 0F59EB mulps xmm5, xmm3
58 00000018 0F12DD movhlps xmm3, xmm5 ; high half -> low
59 0000001B 0F59DD mulps xmm3, xmm5 ; xmm3[0] = hproduct(sqrt(xmm))
60 ; sqrtps xmm3, xmm3 ; sqrt(hprod(sqrt)) = 4th root(hprod)
61 ; common final step done after interleaving with quadratic mean
62
63 ;;; XMM2 = quadratic mean = max of the means
64 0000001E C5F859E8 vmulps xmm5, xmm0,xmm0
65 00000022 FFD1 call rcx ; arith mean of squares
66 00000024 0F14EB unpcklps xmm5, xmm3 ; [quad^2, geo^2, ?, ?]
67 00000027 0F51D5 sqrtps xmm2, xmm5 ; [quad, geo, ?, ?]
68
69 ;;; XMM1 = harmonic mean = min of the means
70 0000002A C5D85EE8 vdivps xmm5, xmm4, xmm0 ; 4/x
71 0000002E FFD1 call rcx ; arithmetic mean (under inversion)
72 00000030 C5D85ECD vdivps xmm1, xmm4, xmm5 ; 4/. (the factor of 4 cancels out)
73
74 ;;; XMM5 = arithmetic mean
75 00000034 0F28E8 movaps xmm5, xmm0
76 00000037 FFD1 call rcx
77
78 00000039 0F14E9 unpcklps xmm5, xmm1 ; [arith, harm, ?,?]
79 0000003C C5D014C2 vunpcklps xmm0, xmm5,xmm2 ; x = [arith, harm, quad, geo]
80
81 00000040 0F5CD1 subps xmm2, xmm1 ; largest - smallest mean: guaranteed non-negative
82 00000043 0F2E51F8 ucomiss xmm2, [rcx-8] ; quad-harm > convergence_threshold
83 00000047 73C5 jae .loop
84
85 ; return with the arithmetic mean in the low element of xmm0 = scalar return value
86 00000049 C3 ret
87
88 ;;; "constant pool" between the main function and the helper, like ARM literal pools
89 0000004A ACC52738 .fpconst_threshold: dd 4e-5 ; 4.3e-5 is the highest we can go and still pass the main test cases
90 0000004E 00008040 .fpconst_4: dd 4.0
91 .arith_mean: ; returns XMM5 = hsum(xmm5)/4.
92 00000052 C5D37CED vhaddps xmm5, xmm5 ; slow but small
93 00000056 C5D37CED vhaddps xmm5, xmm5
94 0000005A 0F5EEC divps xmm5, xmm4 ; divide before/after summing doesn't matter mathematically or numerically; divisor is a power of 2
95 0000005D C3 ret
96 0000005E 5E000000 .size: dd $ - meanmean_float_avx
0x5e = 94 bytes
(으로 작성된 NAS 리스팅 nasm -felf64 mean-mean.asm -l/dev/stdout | cut -b -34,$((34+6))-. 리스팅 부분을 제거하고cut -b 34- > mean-mean.asm )
SIMD 수평 합과 4로 나누기 (즉, 산술 평균)는 별도의 함수 call(주소의 비용을 상각하기위한 함수 포인터 )로 구현됩니다 . 와 4/x전 / 후 또는 x^2이전과 SQRT 후, 우리는 조화 평균과 차 평균을 얻는다. ( div정확하게 표현할 수있는 것을 곱하는 대신 이 지시 사항 을 작성하는 것은 고통 스러웠다0.25 .)
기하 평균은 곱셈 및 연쇄 sqrt로 별도로 구현됩니다. 또는 1 sqrt를 먼저 사용하여 지수 크기를 줄이고 숫자 정밀도를 도울 수 있습니다. floor(log2(x))AVX512를 통해서만 로그를 사용할 수 없습니다 vgetexpps/pd. Exp는 AVX512ER (Xeon Phi 만 해당)을 통해 사용할 수 있지만 정확도는 2 ^ -23입니다.
128 비트 AVX 명령어와 레거시 SSE를 혼합하는 것은 성능 문제가 아닙니다. 256 비트 AVX와 레거시 SSE를 혼합하는 작업은 Haswell에있을 수 있지만 Skylake에서는 SSE 명령에 대한 잠재적 인 잘못된 종속성을 만들 수 있습니다. 내 double버전은 불필요한 루프 전송 딥 체인과 div / sqrt 대기 시간 / 처리량의 병목 현상을 피 한다고 생각 합니다.
이중 버전 :
108 global meanmean_double_avx
109 meanmean_double_avx:
110 00000080 B9[E8000000] mov ecx, .arith_mean
111 00000085 C4E27D1961F8 vbroadcastsd ymm4, [rcx-8] ; float 4.0
112
113 ;; mean(a,b) = mean(a,b,a,b) for all 4 types of mean
114 ;; so we only ever have to do the length=4 case
115 0000008B C4E37D18C001 vinsertf128 ymm0, ymm0, xmm0, 1 ; [b,a] => [b,a,b,a]
116
117 .loop:
118 ;;; XMM3 = geometric mean: not based on addition.
119 00000091 C5FD51D8 vsqrtpd ymm3, ymm0 ; sqrt first to get magnitude closer to 1.0 for better(?) numerical precision
120 00000095 C4E37D19DD01 vextractf128 xmm5, ymm3, 1 ; extract high lane
121 0000009B C5D159EB vmulpd xmm5, xmm3
122 0000009F 0F12DD movhlps xmm3, xmm5 ; extract high half
123 000000A2 F20F59DD mulsd xmm3, xmm5 ; xmm3 = hproduct(sqrt(xmm0))
124 ; sqrtsd xmm3, xmm3 ; xmm3 = 4th root = geomean(xmm0) ;deferred until quadratic
125
126 ;;; XMM2 = quadratic mean = max of the means
127 000000A6 C5FD59E8 vmulpd ymm5, ymm0,ymm0
128 000000AA FFD1 call rcx ; arith mean of squares
129 000000AC 0F16EB movlhps xmm5, xmm3 ; [quad^2, geo^2]
130 000000AF 660F51D5 sqrtpd xmm2, xmm5 ; [quad , geo]
131
132 ;;; XMM1 = harmonic mean = min of the means
133 000000B3 C5DD5EE8 vdivpd ymm5, ymm4, ymm0 ; 4/x
134 000000B7 FFD1 call rcx ; arithmetic mean under inversion
135 000000B9 C5DB5ECD vdivsd xmm1, xmm4, xmm5 ; 4/. (the factor of 4 cancels out)
136
137 ;;; XMM5 = arithmetic mean
138 000000BD C5FC28E8 vmovaps ymm5, ymm0
139 000000C1 FFD1 call rcx
140
141 000000C3 0F16E9 movlhps xmm5, xmm1 ; [arith, harm]
142 000000C6 C4E35518C201 vinsertf128 ymm0, ymm5, xmm2, 1 ; x = [arith, harm, quad, geo]
143
144 000000CC C5EB5CD1 vsubsd xmm2, xmm1 ; largest - smallest mean: guaranteed non-negative
145 000000D0 660F2E51F0 ucomisd xmm2, [rcx-16] ; quad - harm > threshold
146 000000D5 77BA ja .loop
147
148 ; vzeroupper ; not needed for correctness, only performance
149 ; return with the arithmetic mean in the low element of xmm0 = scalar return value
150 000000D7 C3 ret
151
152 ; "literal pool" between the function
153 000000D8 95D626E80B2E113E .fpconst_threshold: dq 1e-9
154 000000E0 0000000000001040 .fpconst_4: dq 4.0 ; TODO: golf these zeros? vpbroadcastb and convert?
155 .arith_mean: ; returns YMM5 = hsum(ymm5)/4.
156 000000E8 C4E37D19EF01 vextractf128 xmm7, ymm5, 1
157 000000EE C5D158EF vaddpd xmm5, xmm7
158 000000F2 C5D17CED vhaddpd xmm5, xmm5 ; slow but small
159 000000F6 C5D35EEC vdivsd xmm5, xmm4 ; only low element matters
160 000000FA C3 ret
161 000000FB 7B000000 .size: dd $ - meanmean_double_avx
0x7b = 123 bytes
C 테스트 하니스
#include <immintrin.h>
#include <stdio.h>
#include <math.h>
static const struct ab_avg {
double a,b;
double mean;
} testcases[] = {
{1, 1, 1},
{1, 2, 1.45568889},
{100, 200, 145.568889},
{2.71, 3.14, 2.92103713},
{0.57, 1.78, 1.0848205},
{1.61, 2.41, 1.98965438},
{0.01, 100, 6.7483058},
};
// see asm comments for order of arith, harm, quad, geo
__m128 meanmean_float_avx(__m128); // or float ...
__m256d meanmean_double_avx(__m128d); // or double ...
int main(void) {
int len = sizeof(testcases) / sizeof(testcases[0]);
for(int i=0 ; i<len ; i++) {
const struct ab_avg *p = &testcases[i];
#if 1
__m128 arg = _mm_set_ps(0,0, p->b, p->a);
double res = meanmean_float_avx(arg)[0];
#else
__m128d arg = _mm_loadu_pd(&p->a);
double res = meanmean_double_avx(arg)[0];
#endif
double allowed_diff = (p->b - p->a) / 100000.0;
double delta = fabs(p->mean - res);
if (delta > 1e-3 || delta > allowed_diff) {
printf("%f %f => %.9f but we got %.9f. delta = %g allowed=%g\n",
p->a, p->b, p->mean, res, p->mean - res, allowed_diff);
}
}
while(1) {
double a = drand48(), b = drand48(); // range= [0..1)
if (a>b) {
double tmp=a;
a=b;
b=tmp; // sorted
}
// a *= 0.00000001;
// b *= 123156;
// a += 1<<11; b += (1<<12)+1; // float version gets stuck inflooping on 2048.04, 4097.18 at fpthreshold = 4e-5
// a *= 1<<11 ; b *= 1<<11; // scaling to large magnitude makes sum of squares loses more precision
//a += 1<<11; b+= 1<<11; // adding to large magnitude is hard for everything, catastrophic cancellation
#if 1
printf("testing float %g, %g\n", a, b);
__m128 arg = _mm_set_ps(0,0, b, a);
__m128 res = meanmean_float_avx(arg);
double quad = res[2], harm = res[1]; // same order as double... for now
#else
printf("testing double %g, %g\n", a, b);
__m128d arg = _mm_set_pd(b, a);
__m256d res = meanmean_double_avx(arg);
double quad = res[2], harm = res[1];
#endif
double delta = fabs(quad - harm);
double allowed_diff = (b - a) / 100000.0; // calculated in double even for the float case.
// TODO: use the double res as a reference for float res
// instead of just checking quadratic vs. harmonic mean
if (delta > 1e-3 || delta > allowed_diff) {
printf("%g %g we got q=%g, h=%g, a=%g. delta = %g, allowed=%g\n",
a, b, quad, harm, res[0], quad-harm, allowed_diff);
}
}
}
로 빌드 :
nasm -felf64 mean-mean.asm &&
gcc -no-pie -fno-pie -g -O2 -march=native mean-mean.c mean-mean.o
AVX를 지원하는 CPU 또는 Intel SDE와 같은 에뮬레이터가 필요합니다. 기본 AVX 지원없이 호스트에서 컴파일하려면 -march=sandybridge또는-mavx
실행 : 하드 코딩 된 테스트 사례를 통과하지만 플로트 버전의 경우 임의 테스트 사례가 종종 (b-a)/10000질문에 설정된 임계 값에 실패합니다 .
$ ./a.out
(note: empty output before the first "testing float" means clean pass on the constant test cases)
testing float 3.90799e-14, 0.000985395
3.90799e-14 0.000985395 we got q=3.20062e-10, h=3.58723e-05, a=2.50934e-05. delta = -3.5872e-05, allowed=9.85395e-09
testing float 0.041631, 0.176643
testing float 0.0913306, 0.364602
testing float 0.0922976, 0.487217
testing float 0.454433, 0.52675
0.454433 0.52675 we got q=0.48992, h=0.489927, a=0.489925. delta = -6.79493e-06, allowed=7.23169e-07
testing float 0.233178, 0.831292
testing float 0.56806, 0.931731
testing float 0.0508319, 0.556094
testing float 0.0189148, 0.767051
0.0189148 0.767051 we got q=0.210471, h=0.210484, a=0.21048. delta = -1.37389e-05, allowed=7.48136e-06
testing float 0.25236, 0.298197
0.25236 0.298197 we got q=0.274796, h=0.274803, a=0.274801. delta = -6.19888e-06, allowed=4.58374e-07
testing float 0.531557, 0.875981
testing float 0.515431, 0.920261
testing float 0.18842, 0.810429
testing float 0.570614, 0.886314
testing float 0.0767746, 0.815274
testing float 0.118352, 0.984891
0.118352 0.984891 we got q=0.427845, h=0.427872, a=0.427863. delta = -2.66135e-05, allowed=8.66539e-06
testing float 0.784484, 0.893906
0.784484 0.893906 we got q=0.838297, h=0.838304, a=0.838302. delta = -7.09295e-06, allowed=1.09422e-06
FP 오류는 일부 입력에서 쿼드 하모가 0보다 작게 나오기에 충분합니다.
또는 a += 1<<11; b += (1<<12)+1;주석 처리되지 않은 상태 :
testing float 2048, 4097
testing float 2048.04, 4097.18
^C (stuck in an infinite loop).
이 문제들 중 어떤 것도 발생하지 않습니다 double. printf각 테스트 전에 주석 처리 하여 출력이 비어 있는지 확인하십시오.if(delta too high) 블록 ).
TODO : double버전 float이 쿼드 하마와 수렴하는 방식을 보는 대신 버전을 참조로 사용하십시오 .