SQL Server 데이터베이스에 사용자가 있는지 확인

SQL Server 2012에서 작업하고 있습니다. 데이터베이스에 추가하기 전에 사용자가 있는지 확인하고 싶습니다.

이것이 내가 테스트 한 것입니다.

USE [MyDatabase]
GO

IF NOT EXISTS (SELECT name 
                FROM [sys].[server_principals]
                WHERE name = N'IIS APPPOOL\MyWebApi AppPool')
Begin
    CREATE USER [IIS APPPOOL\MyWebApi AppPool] 
    FOR LOGIN [IIS APPPOOL\MyWebApi AppPool] WITH DEFAULT_SCHEMA=[dbo]
end
ALTER ROLE [db_owner] ADD MEMBER [IIS APPPOOL\MyWebApi AppPool]
GO

그러나 SELECT name FROM [sys].[server_principals]해당 사용자가에 있으면 이 코드 는 반환되지 않습니다 MyDatabase.

사용자가 존재하는지 어떻게 확인할 수 MyDatabase있습니까?

sys.database_principals대신에 사용하십시오 sys.server_principals.

따라서 최종 쿼리는 다음과 같습니다 (사용자 필터 설명).

USE [MyDatabase]
GO

IF NOT EXISTS (SELECT [name]
                FROM [sys].[database_principals]
                WHERE [type] = N'S' AND [name] = N'IIS APPPOOL\MyWebApi AppPool')
Begin
    CREATE USER [IIS APPPOOL\MyWebApi AppPool] 
    FOR LOGIN [IIS APPPOOL\MyWebApi AppPool] WITH DEFAULT_SCHEMA=[dbo]
end
ALTER ROLE [db_owner] ADD MEMBER [IIS APPPOOL\MyWebApi AppPool]
GO

이런 종류의 일에는 SUSER_ID () 및 USER_ID ()를 사용합니다.

-- Check SQL Server Login
IF SUSER_ID('SomeLogin') IS NULL
    CREATE LOGIN SomeLogin WITH PASSWORD = 'SomePassword';

-- Check database user
IF USER_ID('SomeUser') IS NULL
    CREATE USER SomeUser FOR LOGIN SomeLogin;

보다 최적의 판독을 할 수 있도록 개선

USE [MyDatabase]
GO

IF DATABASE_PRINCIPAL_ID('IIS APPPOOL\MyWebApi AppPool') IS NULL
BEGIN
    CREATE USER [IIS APPPOOL\MyWebApi AppPool] 
    FOR LOGIN [IIS APPPOOL\MyWebApi AppPool] WITH DEFAULT_SCHEMA=[dbo]
END
ALTER ROLE [db_owner] ADD MEMBER [IIS APPPOOL\MyWebApi AppPool]
GO

저항 서버를 사용하는 경우 한 번에 많은 서버를 확인하고 다음과 같이 true / false를 반환 할 수 있습니다.

SELECT @@servername,    
    CASE 
        WHEN EXISTS(SELECT name FROM sys.database_principals WHERE name = 'LoginName') THEN 1 
        ELSE 0 
    END AS YesNo