나는 대리 키의 팬입니다. 내 결과가 확인 편향 될 위험이 있습니다.
여기와 http://stackoverflow.com 에서 본 많은 질문 은 IDENTITY()값을 기반으로하는 대리 키 대신 자연 키를 사용 합니다.
컴퓨터 시스템에 대한 나의 배경은 정수에 대한 비교 작업을 수행하는 것이 문자열을 비교하는 것보다 빠릅니다.
이 의견은 저의 신념에 의문을 제기했기 때문에 SQL Server에서 키로 사용하기 위해 정수가 문자열보다 빠르다는 논문을 조사하는 시스템을 만들 것이라고 생각했습니다.
작은 데이터 집합에는 눈에 띄지 않는 차이가 거의 없기 때문에 기본 테이블에 1,000,000 개의 행이 있고 보조 테이블에 기본 테이블의 각 행에 대해 10 만 개의 행이있는 2 개의 테이블 설정을 즉시 생각했습니다. 보조 테이블. 내 테스트의 전제는 자연 키를 사용하는 것과 정수 키를 사용하는 것과 같은 두 가지 테이블 세트를 만들고 다음과 같은 간단한 쿼리에서 타이밍 테스트를 실행하는 것입니다.
SELECT *
FROM Table1
INNER JOIN Table2 ON Table1.Key = Table2.Key;다음은 테스트 베드로 만든 코드입니다.
USE Master;
IF (SELECT COUNT(database_id) FROM sys.databases d WHERE d.name = 'NaturalKeyTest') = 1
BEGIN
ALTER DATABASE NaturalKeyTest SET SINGLE_USER WITH ROLLBACK IMMEDIATE;
DROP DATABASE NaturalKeyTest;
END
GO
CREATE DATABASE NaturalKeyTest
ON (NAME = 'NaturalKeyTest', FILENAME =
'C:\SQLServer\Data\NaturalKeyTest.mdf', SIZE=8GB, FILEGROWTH=1GB)
LOG ON (NAME='NaturalKeyTestLog', FILENAME =
'C:\SQLServer\Logs\NaturalKeyTest.mdf', SIZE=256MB, FILEGROWTH=128MB);
GO
ALTER DATABASE NaturalKeyTest SET RECOVERY SIMPLE;
GO
USE NaturalKeyTest;
GO
CREATE VIEW GetRand
AS
SELECT RAND() AS RandomNumber;
GO
CREATE FUNCTION RandomString
(
@StringLength INT
)
RETURNS NVARCHAR(max)
AS
BEGIN
DECLARE @cnt INT = 0
DECLARE @str NVARCHAR(MAX) = '';
DECLARE @RandomNum FLOAT = 0;
WHILE @cnt < @StringLength
BEGIN
SELECT @RandomNum = RandomNumber
FROM GetRand;
SET @str = @str + CAST(CHAR((@RandomNum * 64.) + 32) AS NVARCHAR(MAX));
SET @cnt = @cnt + 1;
END
RETURN @str;
END;
GO
CREATE TABLE NaturalTable1
(
NaturalTable1Key NVARCHAR(255) NOT NULL
CONSTRAINT PK_NaturalTable1 PRIMARY KEY CLUSTERED
, Table1TestData NVARCHAR(255) NOT NULL
);
CREATE TABLE NaturalTable2
(
NaturalTable2Key NVARCHAR(255) NOT NULL
CONSTRAINT PK_NaturalTable2 PRIMARY KEY CLUSTERED
, NaturalTable1Key NVARCHAR(255) NOT NULL
CONSTRAINT FK_NaturalTable2_NaturalTable1Key
FOREIGN KEY REFERENCES dbo.NaturalTable1 (NaturalTable1Key)
ON DELETE CASCADE ON UPDATE CASCADE
, Table2TestData NVARCHAR(255) NOT NULL
);
GO
/* insert 1,000,000 rows into NaturalTable1 */
INSERT INTO NaturalTable1 (NaturalTable1Key, Table1TestData)
VALUES (dbo.RandomString(25), dbo.RandomString(100));
GO 1000000
/* insert 10,000,000 rows into NaturalTable2 */
INSERT INTO NaturalTable2 (NaturalTable2Key, NaturalTable1Key, Table2TestData)
SELECT dbo.RandomString(25), T1.NaturalTable1Key, dbo.RandomString(100)
FROM NaturalTable1 T1
GO 10
CREATE TABLE IDTable1
(
IDTable1Key INT NOT NULL CONSTRAINT PK_IDTable1
PRIMARY KEY CLUSTERED IDENTITY(1,1)
, Table1TestData NVARCHAR(255) NOT NULL
CONSTRAINT DF_IDTable1_TestData DEFAULT dbo.RandomString(100)
);
CREATE TABLE IDTable2
(
IDTable2Key INT NOT NULL CONSTRAINT PK_IDTable2
PRIMARY KEY CLUSTERED IDENTITY(1,1)
, IDTable1Key INT NOT NULL
CONSTRAINT FK_IDTable2_IDTable1Key FOREIGN KEY
REFERENCES dbo.IDTable1 (IDTable1Key)
ON DELETE CASCADE ON UPDATE CASCADE
, Table2TestData NVARCHAR(255) NOT NULL
CONSTRAINT DF_IDTable2_TestData DEFAULT dbo.RandomString(100)
);
GO
INSERT INTO IDTable1 DEFAULT VALUES;
GO 1000000
INSERT INTO IDTable2 (IDTable1Key)
SELECT T1.IDTable1Key
FROM IDTable1 T1
GO 10위의 코드는 데이터베이스와 4 개의 테이블을 만들고 테스트 할 준비가 된 데이터로 테이블을 채 웁니다. 내가 실행 한 테스트 코드는 다음과 같습니다.
USE NaturalKeyTest;
GO
DECLARE @loops INT = 0;
DECLARE @MaxLoops INT = 10;
DECLARE @Results TABLE (
FinishedAt DATETIME DEFAULT (GETDATE())
, KeyType NVARCHAR(255)
, ElapsedTime FLOAT
);
WHILE @loops < @MaxLoops
BEGIN
DBCC FREEPROCCACHE;
DBCC FREESESSIONCACHE;
DBCC FREESYSTEMCACHE ('ALL');
DBCC DROPCLEANBUFFERS;
WAITFOR DELAY '00:00:05';
DECLARE @start DATETIME = GETDATE();
DECLARE @end DATETIME;
DECLARE @count INT;
SELECT @count = COUNT(*)
FROM dbo.NaturalTable1 T1
INNER JOIN dbo.NaturalTable2 T2 ON T1.NaturalTable1Key = T2.NaturalTable1Key;
SET @end = GETDATE();
INSERT INTO @Results (KeyType, ElapsedTime)
SELECT 'Natural PK' AS KeyType, CAST((@end - @start) AS FLOAT) AS ElapsedTime;
DBCC FREEPROCCACHE;
DBCC FREESESSIONCACHE;
DBCC FREESYSTEMCACHE ('ALL');
DBCC DROPCLEANBUFFERS;
WAITFOR DELAY '00:00:05';
SET @start = GETDATE();
SELECT @count = COUNT(*)
FROM dbo.IDTable1 T1
INNER JOIN dbo.IDTable2 T2 ON T1.IDTable1Key = T2.IDTable1Key;
SET @end = GETDATE();
INSERT INTO @Results (KeyType, ElapsedTime)
SELECT 'IDENTITY() PK' AS KeyType, CAST((@end - @start) AS FLOAT) AS ElapsedTime;
SET @loops = @loops + 1;
END
SELECT KeyType, FORMAT(CAST(AVG(ElapsedTime) AS DATETIME), 'HH:mm:ss.fff') AS AvgTime
FROM @Results
GROUP BY KeyType;결과는 다음과 같습니다.
여기에 잘못된 것이 있습니까, 아니면 INT 키가 25 문자의 자연 키보다 3 배 빠릅니다.
여기에 후속 질문을 작성했습니다 .
1
INT는 4 바이트이고 유효 NVARCHAR (25)는 길이와 같은 시스템 데이터를 포함하여 약 14 배 더 길기 때문에 인덱스만으로도 훨씬 넓고 깊은 PK 인덱스를 가질 수 있다고 생각합니다. 처리 시간에 영향을주는 / O가 필요합니다. Howevev 자연 정수 (아마도 체크 숫자로 표시)는 대리 ID 열에 사용하는 것과 거의 동일한 INT입니다. 따라서 "자연 키"는 INT, BIGINT, CHAR, NVARCHAR 등 모든 것이 중요합니다.
—
RLF
@ MikeSherrill'Catcall '의 성능 향상은 자연 키를 사용할 때 실제로 "lookup"테이블에 대한 조인이 필요하지 않다는 것입니다. 쿼리를 비교하여 값이 기본 테이블에 이미 저장된 쿼리와 조인으로 조회 값을 가져옵니다. 조회 테이블의 자연 키 길이와 행 수에 따라 다른 "우승자"가 표시 될 수 있습니다.
—
Mikael Eriksson
@MikaelEriksson이 말한 것 외에도 2 개 이상의 테이블 (예 : 4) 사이에 조인이있는 경우 (대리인을 사용하면 A와 D를 통해 B와 C를 통해 테이블 A를 조인해야하며 자연 키를 사용하면 A와 D를 직접 조인 할 수 있음)
—
ypercubeᵀᴹ