파이썬에서 함수의 두 가지 인수를 바꾸는 방법?

파이썬 함수 호출에서 두 인수를 어떻게 바꿀 수 있습니까?

point이 두 논쟁 사이에 공백을 두면

self.assertEqual(json.loads(some.data), json_data)

그런 다음 M-t( transpose-words), 나는 얻는다 :

self.assertEqual(json.loads(some.json), data_data)

반면에 CMt ( transpose-sexps)를 사용하면 다음 과 같은 이점 이 있습니다.

self.assertEqual(json.loadsjson_data, (some.data))

내가 원하는 것은 :

self.assertEqual(json_data, json.loads(some.data))

그렇게 할 명령이 있습니까?

이것은 나도 오랫동안 갖고 싶었던 일이며, 여기에서 일할 동기가 있습니다. 아마 강력하지는 않지만 처음 시도 할 때 시도한 사례를 다루는 것 같습니다.

(defun my/calculate-stops ()
  (save-excursion
    (let ((start
           (condition-case e
               (while t (backward-sexp))
             (error (point))))
          stops)
      (push start stops)
      (condition-case e
          (while t
            (forward-sexp)
            (when (looking-at "\\s-*,")
              (push (point) stops)))
        (error (push (point) stops)))
      (nreverse stops))))

(defun my/transpose-args ()
  (interactive)
  (when (looking-at "\\s-") (backward-sexp))
  (cl-loop with p = (point)
           with previous = nil
           for stop on (my/calculate-stops)
           for i upfrom 0
           when (<= p (car stop)) do
           (when previous
             (let* ((end (cadr stop))
                    (whole (buffer-substring previous end))
                    middle last)
               (delete-region previous end)
               (goto-char previous)
               (setf middle (if (> i 1) (- (car stop) previous)
                              (string-match "[^, \\t]" whole 
                                            (- (car stop) previous)))
                     last (if (> i 1) (substring whole 0 middle)
                            (concat (substring whole (- (car stop) previous) middle)
                                    (substring whole 0 (- (car stop) previous)))))
               (insert (substring whole middle) last)))
           (cl-return)
           end do (setf previous (car stop))))

나는 transpose-sexps당신이 묘사하고 쉼표로 구분 된 것을 바꾸거나 규칙적으로하는 경우를 찾는 변형을 사용합니다 transpose-sexps. 또한 커서를 앞으로 드래그하는 대신 제자리에 둡니다. 조금 다르지만 개인적으로 좋아합니다.

(defun my-transpose-sexps ()
  "If point is after certain chars transpose chunks around that.
Otherwise transpose sexps."
  (interactive "*")
  (if (not (looking-back "[,]\\s-*" (point-at-bol)))
      (progn (transpose-sexps 1) (forward-sexp -1))
    (let ((beg (point)) end rhs lhs)
      (while (and (not (eobp))
                  (not (looking-at "\\s-*\\([,]\\|\\s)\\)")))
        (forward-sexp 1))
      (setq rhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (re-search-backward "[,]\\s-*" nil t)
      (setq beg (point))
      (while (and (not (bobp))
                  (not (looking-back "\\([,]\\|\\s(\\)\\s-*" (point-at-bol))))
        (forward-sexp -1))
      (setq lhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (insert rhs)
      (re-search-forward "[,]\\s-*" nil t)
      (save-excursion
        (insert lhs)))))

SMIE를 사용하는 모드에서는 transpose-sexp해당 경우에 올바르게 작동해야합니다. 접두어 기호 (일명 "분리 자")가 ,(또는 a ;)가 아니라 단어 (예 :) 인 경우에도 여전히 실패합니다 and.

따라서 제 의견은 그 명령 transpose-sexp이 올바르게 작동하지 않을 때 버그로 생각합니다 (그러나 버그가 고칠 수 있고 / 또는 수정하고 우선 순위가 낮은 버그는 고려하지 마십시오) 숨을 참으십시오). 이 문제를 해결하는 방법 forward-sexp-function은 "쉼표를 본 후에 전체 인수를 건너 뛰는 것"이라는 기능을 설정 하는 것입니다.