확장자가없는 파일의 기억 모드

확장자가 없지만 여전히 주 모드 형식 인 많은 파일을 편집하기 시작했습니다.

나는 팀의 유일한 Emacs 사용자이며 편집자가 특별한 것들을 필요로한다는 것을 고통스럽게 분명하게하고 싶지 않습니다 . 코드베이스 변경을 피하고 싶습니다.

• 파일 이름을 변경할 수 없습니다
• 특별한 Emacs 의견을 사용할 수 없습니다

Emacs가 파일을 마지막에 수동으로 넣은 모드 (예 :)를 기억 M-x conf-mode하고 다시 방문 할 때 자동으로 해당 모드를 활성화하고 싶습니다.

savehist-mode지속성을 처리 하는 데 사용 합니다.

이 고통없이 할 수 있습니까?

확장명에 의존하지 않는 파일의 주 모드를 식별하는 방법은 여러 가지가 있습니다. 설명서의 파일 모드 선택을 참조하십시오 .

처리중인 파일의 종류에 따라을 사용할 수 있습니다 magic-mode-alist. 또한 auto-mode-alist일치하는 확장자로만 제한되지는 않습니다. 파일 이름 또는 경로의 모든 부분을 일치시킬 수 있습니다.

처리하는 파일이 해당 메커니즘에 대해 일관성이없는 경우 한 가지 옵션은 auto-mode-alist전체 파일 이름과 일치하는 항목 을 추가 하거나 일부 프로젝트의 루트 경로와 일치하고 사용자 정의 함수를 호출하여 이름을 모드와 일치시키는 것입니다.

지정된 디렉토리의 모든 파일이 동일한 유형 인 경우 디렉토리 로컬 변수를 사용하여 모드를 설정할 수도 있습니다. 디렉토리 변수는 .dir-locals 파일이 아닌 init 파일에서 설정할 수 있습니다 . 자세한 내용 은 디렉토리 변수 를 참조하십시오.

최신 정보

다음은 자신의 절대 파일 이름 및 주요 모드 목록을 관리하는 빠른 시도입니다.

(defvar my-custom-mode-alist '())
(defvar my-custom-mode-alist-file (expand-file-name "custom-file-assoc" user-emacs-directory))

;; command to save the file->mode association of the current buffer
(defun save-file-mode-association ()
  (interactive)
  (when buffer-file-name
    (add-to-list 'my-custom-mode-alist (cons buffer-file-name major-mode))
    (write-custom-mode-alist my-custom-mode-alist-file)))

(defun write-custom-mode-alist (file)
  (with-current-buffer (get-buffer-create " *Custom File Assocations*")
    (goto-char (point-min))
    (delete-region (point-min) (point-max))
    (pp my-custom-mode-alist (current-buffer))
    (condition-case nil
        (write-region (point-min) (point-max) file)
      (file-error (message "Can't write %s" file)))
    (kill-buffer (current-buffer))
    (message "Wrote custom file associations to file %s" file)))

(defun load-custom-mode-alist (file)
  (when (file-exists-p file)
    (with-current-buffer
        (let ((enable-local-variables nil))
          (find-file-noselect file))
      (goto-char (point-min))
      (setq my-custom-mode-alist (read (current-buffer)))
      (setq auto-mode-alist (append auto-mode-alist my-custom-mode-alist))
      (kill-buffer (current-buffer)))))

;; Load any custom file associations and add them to auto-mode-alist
(load-custom-mode-alist my-custom-mode-alist-file)

Glucas의 조언에 근거한 다음은 완벽하게 작동하는 것 같습니다.

(defvar file-name-mode-alist '())
;; other stuff here, of course
(setq savehist-additional-variables '(file-name-mode-alist))
(savehist-mode +1)
(setq auto-mode-alist (append auto-mode-alist file-name-mode-alist))

(add-hook 'after-change-major-mode-hook
  (lambda ()
    (when (and
            buffer-file-name
            (not
              (file-name-extension
                buffer-file-name)))
       (setq file-name-mode-alist
        (cons
          (cons buffer-file-name major-mode)
          file-name-mode-alist))
      (setq auto-mode-alist
        (append auto-mode-alist
          (list (cons buffer-file-name major-mode)))))))