여러 변수에 동일한 값을 할당 하시겠습니까?

때로는 여러 변수에 동일한 값을 설정해야합니다.

파이썬에서는 할 수 있습니다

f_loc1 = f_loc2 = "/foo/bar"

그러나 간혹, 나는 쓰고있다

(setq f_loc1 "/foo/bar" f_loc2 "/foo/bar")

"/foo/bar"한 번만 사용하여이를 달성 할 수있는 방법이 있는지 궁금합니다 .

setq 값을 반환하므로 다음과 같이 할 수 있습니다.

(setq f-loc1 (setq f-loc2 "/foo/bar"))

그것에 의존하고 싶지 않다면 다음을 사용하십시오.

(setq f-loc1 "/foo/bar" f-loc2 f-loc1)

개인적으로 나는 후자를 피하고 대신 다음과 같이 씁니다.

(setq f-loc1 "/foo/bar"
      f-loc2 f-loc1)

또는

(setq f-loc1 "/foo/bar")
(setq f-loc2 f-loc1)

그리고 첫 번째 접근 방식은 실제로 의도를 강조 하는 대체 상황 이나 대안이 두 번째 접근 방식 또는 다른 방법을 사용하는 경우에만 사용하는 것 progn입니다.

위의 내용이 만족스러운 경우 여기에서 읽기를 중단 할 수 있습니다. 그러나 나는 이것이 당신과 다른 사람들에게 매크로를 남용하지 말라고 경고 할 수있는 좋은 기회라고 생각합니다.

마지막으로, setq-every"이것이 lisp이고 우리가 할 수 있기 때문에" 와 같은 매크로를 작성하고 싶은 유혹 이지만, 그렇게하지 않는 것이 좋습니다. 당신은 그것을함으로써 거의 얻을 수 없습니다 :

(setq-every value a b)
   vs
(setq a (setq b value))

그러나 동시에 다른 독자가 코드를 읽고 어떤 일이 발생하는지 확인하기가 훨씬 어렵습니다. setq-every다양한 방법으로 구현 될 수 있으며 다른 사용자 (미래를 포함하여)는이를 사용하는 코드를 살펴보면 저자가 선택한 사람을 알 수 없습니다. [원래 여기에 몇 가지 예를 들었지만, 이는 비꼬는 것으로 간주되어 누군가에 의해 광란이되었습니다.]

당신은 당신이 볼 때마다 그 정신적 오버 헤드를 처리 setq-every하거나 하나의 추가 캐릭터와 함께 살 수 있습니다. (적어도 두 개의 변수 만 설정해야하지만 한 번에 두 개 이상의 변수를 동일한 값으로 설정해야한다는 것을 기억할 수 없습니다. 그렇게 해야하는 경우 다른 문제가있을 수 있습니다 코드와 함께)

반면에이 매크로를 실제로 6 십회 이상 사용하려는 경우 추가 간접적 가치가있을 수 있습니다. 예를 들어 내가 좋아하는 매크로 사용 --when-let로부터 dash.el라이브러리를. 그것은 내 코드에서 그것을 처음 접하는 사람들에게는 더 어렵게 만듭니다. 그러나 그 이해의 어려움을 극복하는 것은 단지 몇 번 이상 사용되며 적어도 내 견해로는 코드를 더 읽기 쉽기 때문에 가치가 있습니다. .

에 동일하게 적용된다고 주장 할 수도 setq-every있지만이 특정 매크로가 몇 번 이상 사용될 가능성은 매우 낮습니다. 일반적으로 매크로 정의 (doc-string 포함)가 매크로를 사용하는 것보다 더 많은 코드를 추가하면 매크로가 과도하게 사용되는 경우가 많습니다 (거의 사실이 아닐 수도 있음).

원하는 것을하는 매크로

일종의 연습으로 :

(defmacro setq-every (value &rest vars)
  "Set every variable from VARS to value VALUE."
  `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))

이제 시도해보십시오.

(setq-every "/foo/bar" f-loc1 f-loc2)

작동 원리

사람들은 그것이 어떻게 작동하는지 궁금하기 때문에 (설명에 따라) 여기에 설명이 있습니다. 매크로를 작성하는 방법을 배우려면 좋은 Lisp 책을 선택하십시오 (예, Common Lisp, Emacs Lisp에서도 동일한 작업을 수행 할 수 있지만 Common Lisp은 조금 더 강력하고 더 나은 책을 가지고 있습니다) IMHO.

매크로는 원시 코드에서 작동합니다. 매크로는 함수와 달리 인수를 평가하지 않습니다. 그래서 우리는 여기에 대한 평가되지 않은 value컬렉션을 가지고 있습니다 vars.

progn여러 setq양식을 하나로 그룹화합니다 . 이건 :

(mapcar (lambda (x) (list 'setq x value)) vars)

setqOP의 예를 사용하여 양식 목록을 생성 하면됩니다.

((setq f-loc1 "/foo/bar") (setq f-loc2 "/foo/bar"))

보시다시피, 양식은 역 따옴표 양식 안에 있으며 앞에 쉼표가 붙습니다 ,. 내부 인용 된 양식은 모든 것이 일반적으로 인용되지만 , 일시적으로 "켜짐"평가되므로 전체 mapcar가 거시 확장 시간에 평가됩니다.

마지막으로 s를 사용하여 @목록에서 외부 괄호를 제거 setq하여 다음을 얻습니다.

(progn
  (setq f-loc1 "/foo/bar")
  (setq f-loc2 "/foo/bar"))

매크로는 소스 코드를 임의로 변형시킬 수 있습니다.

경고

다음은 작은 경고입니다.이 매크로는 본질적으로 다음과 같이 확장되기 때문에 첫 번째 인수는 여러 번 평가됩니다.

(progn
  (setq f-loc1 "/foo/bar")
  (setq f-loc2 "/foo/bar"))

여기에 변수 또는 문자열이 있으면 괜찮지 만 다음과 같이 작성하면됩니다.

(setq-every (my-function-with-side-effects) f-loc1 f-loc2)

그런 다음 함수가 두 번 이상 호출됩니다. 바람직하지 않을 수 있습니다. 다음은 MMT 패키지once-only 에서 사용 가능 하도록 수정하는 방법입니다 .

(defmacro setq-every (value &rest vars)
  "Set every variable from VARS to value VALUE.

VALUE is only evaluated once."
  (mmt-once-only (value)
    `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars))))

그리고 문제는 사라졌습니다.

lisp에서 기호를 사용하고 조작 할 수 있으므로 기호 목록을 반복하여 사용하면 set됩니다.

(dolist (var '(foo bar baz)) (set var 10))

(mapc (lambda (var) (set var 10)) '(foo bar baz))

(loop for var in '(foo bar baz) do (set var 11))

(--each '(foo bar baz) (set it 10))