굵은 글꼴을 방지하기 위해 org-mode에서 *를 어떻게 벗어날 수 있습니까?

*shrug*조직 모드 와 같은 것을 쓰면 자동으로 굵은 글씨체 로 글꼴이 지정됩니다 . 어떻게 *shrug*내보내는 경우 즉, 실제로 그대로 그대로 표시 되는 것을 방지 할 수 있습니까?

편집하다:

여전히 굵은 글꼴의 기본 스타 구문을 변경하지 않고 굵은 글씨체를 사용할 수 있기를 원하며 내 조직 파일을 내보내는 파일 형식과 상관 없습니다. 예를 들어 HTML뿐만 아니라 Markdown에서도 작동합니다 수출.

이것은 중요한 것들이므로 굵은 글씨로 쓰여 있습니다. 그러나 다른 것을 위해, 나는 아이디어 * shrug *가 없다.

이 답변은에 공동 제안 후 영감을 이맥스 조직 모드 GNU 목록 사용에 org-entity( C-h i g (org) Special symbols) \ast{}대신 제로 폭 공간 (나는에서 제시 자 여기 내 다른 대답 ).

다음은 사용자가 다양한 기호에 대한 조직 엔티티를 기억할 필요가없는 일반적인 솔루션입니다. 사용자가 할 때 조직 엔티티 (사용 가능한 경우)를 삽입합니다 C-u SYMBOL. 작품에 대한 C-u *, C-u /, C-u =, 등

(defun modi/org-entity-get-name (char)
  "Return the entity name for CHAR. For example, return \"ast\" for *."
  (let ((ll (append org-entities-user
                    org-entities))
        e name utf8)
    (catch 'break
      (while ll
        (setq e (pop ll))
        (when (not (stringp e))
          (setq utf8 (nth 6 e))
          (when (string= char utf8)
            (setq name (car e))
            (throw 'break name)))))))

(defun modi/org-insert-org-entity-maybe (&rest args)
  "When the universal prefix C-u is used before entering any character,
    insert the character's `org-entity' name if available.

    If C-u prefix is not used and if `org-entity' name is not available, the
    returned value `entity-name' will be nil."
  ;; It would be fine to use just (this-command-keys) instead of
  ;; (substring (this-command-keys) -1) below in emacs 25+.
  ;; But if the user pressed "C-u *", then
  ;;  - in emacs 24.5, (this-command-keys) would return "^U*", and
  ;;  - in emacs 25.x, (this-command-keys) would return "*".
  ;; But in both versions, (substring (this-command-keys) -1) will return
  ;; "*", which is what we want.
  ;; http://thread.gmane.org/gmane.emacs.orgmode/106974/focus=106996
  (let ((pressed-key (substring (this-command-keys) -1))
        entity-name)
    (when (and (listp args) (eq 4 (car args)))
      (setq entity-name (modi/org-entity-get-name pressed-key))
      (when entity-name
        (setq entity-name (concat "\\" entity-name "{}"))
        (insert entity-name)
        (message (concat "Inserted `org-entity' "
                         (propertize entity-name
                                     'face 'font-lock-function-name-face)
                         " for the symbol "
                         (propertize pressed-key
                                     'face 'font-lock-function-name-face)
                         "."))))
    entity-name))

;; Run `org-self-insert-command' only if `modi/org-insert-org-entity-maybe'
;; returns nil.
(advice-add 'org-self-insert-command :before-until #'modi/org-insert-org-entity-maybe)

사용자가 입력 그래서 C-u *, \ast{}삽입되고 메시지는 아래의 에코 영역에 표시되는,

기호 *에 'org-entity'\ ast {}를 삽입했습니다.

를 org-pretty-entities로 설정 t하면 삽입 된 \ast{}이로 표시 됩니다 *.

이 경우 org-entity않는 문자가 존재하지 X 사용자가 않는 경우 C-u X를 , X는 (단순히 4 번 삽입 C-u일반적으로 할 것).

ZERO WIDTH SPACE 유니 코드 문자 사용

첫 번째 별표 앞이나 두 번째 별표 뒤에 폭이 0 인 공백 문자 (아래 스 니펫에 [ZWS]로 표시)를 추가하여 굵은 강조 구문 분석에 실패 할 수 있습니다.

아래 스 니펫은 테스트에서 HTML로 잘 내보내졌습니다.

• [ZWS] 첫 번째 별표 앞

  This is some *bold* test and this is ​[ZWS]*not bold*.
  

• 두 번째 별표 후 [ZWS]

  This is some *bold* test and this is *not bold*​[ZWS].
  

을 수행하여 ZERO WIDTH SPACE (유니 코드 이름)를 입력 할 수 있습니다 C-x 8 RET 200b RET.
나는 이것을 매우 자주 사용하므로 이것을에 바인딩했습니다C-x 8 0 .

최신 정보

emacs-org-mode 메일 링리스트에 대한 논의에 따르면 , 비 ASCII 문자를 이스케이프 처리하는 것은 권장하지 않습니다. org-entities해당되는 경우 대신 사용해야합니다. 나도 그 동의와 함께했다 이 다른 솔루션 에 삽입하게 org-entities(쉽게 정말 C-u *이 경우).

구두로, 실제로 내 보낸 LaTeX에서 일부 마크 업을 사용하려는 경우을 사용할 수 있습니다 =*shrug*=. 그러나으로 내보내기 *shrug*를 원하고 항상하려는 경우 필터를 사용하는 것이 좋습니다 . 그러나의 일부 인스턴스에 대해서만 필요한 경우 *shrug*@wvxvw에서 제안한 대안을 사용해야합니다. 매크로를 사용하여이 작업을 깔끔하게 수행 할 수 있습니다. 다음은 몇 가지 예입니다.

필터

(defun my-bold (contents backend info)
  (when (org-export-derived-backend-p backend 'latex)
    (replace-regexp-in-string "\\`\\\\textbf{\\(.+\\)}"
                              "\\\\ast{}\\1\\\\ast{}" contents)))

(add-to-list 'org-export-filter-bold-functions 'my-bold)

본질적으로 위의 필터는 \textbf{..}트랜스 코딩 된 문자열에서 마크 업을 찾아 \ast{}..\ast{}내부에 래핑 된 내용을 변경하지 않고로 바꿉니다 {..}. 정규식과 대체 문자열을 테스트하지 않았으므로 실수가있을 수 있지만 아이디어를 얻을 수 있습니다. 다른 백엔드를 포함하기 위해 다음과 같은 추가 스 니펫을 포함 할 수 있습니다.

(when (org-export-derived-backend-p backend 'html)
   (replace-regexp-in-string "<b>\\(.+\\)</b>" "\&#2a;\\1\&#2a;" contents))

위의 정규식에 대해서도 같은 경고가 있습니다.

매크로

조직 소스 :

#+macro: nobold @@latex:\ast{}$1\ast{}@@ @@html:&#2a;$1&#2a;@@

This text is *bold* this is nobold{{{not}}}

다음과 같이 LaTeX로 내보내기 :

This text is \textbf{bold} this is \ast{}not\ast{}

HTML로 :

This text is <b>bold</b> this is  &#2a;not&#2a;

물론 매크로에 원하는만큼 백엔드를 추가 할 수 있습니다.

편집 : Kaushal이 주석에서 지적한 것처럼이 경우 라텍스 내보내기 스 니펫은 선택 사항입니다. 그러나 org-entities조직 소스에서 베어 라텍스를 식별하는 데 대한 목록 과 특정 규칙을 추적하는 것이 다소 어렵 기 때문에 베어 라텍스가 포함될 때마다 사용하는 것을 선호합니다 .

노트 :

• 필터 예제는 테스트되지 않았습니다.
• 모르겠다 HTML. 따라서 각 비트에 약간의 실수가있을 수 있습니다.

이것은 변수 org-emphasis-alist에 의해 제어되며 쉽게 수정할 수 있습니다.

• 굵은 체 텍스트 위에 포인트를 놓고 what-cursor-position 명령을 사용 C-u C-x =하여면을 찾고 속성이 있음에 유의하십시오 org-emphasis.
• 전화 customize-group및 강조 강조 검색
• org-emphasis-alist가 텍스트를 표시하기위한 다양한 옵션과 함께 나타나야합니다.
• *에 해당하는 항목을 삭제하십시오.
• 변경 사항을 적용하고 org-mode 또는 emacs를 다시 시작하십시오.