데몬 모드 : 시작시 대화식 프롬프트를 연기 하시겠습니까?

(반대로,이 질문은 데몬 모드에서 시작하고 대화식 대화 상자를 억제하는 방법 과 동일하지 않습니다 . 제출자에 의해 해당 질문에 "응답"되어 특정 프롬프트가 나타나는 원인을 제거했습니다.)

아직 존재하지 않는 미니 버퍼에 표시되는 프롬프트에 대한 응답을 영원히 기다리지 않는 일반적인 방법 이 있는지 알고 싶습니다 emacs --daemon.

Emacs가 시작 순서를 마칠 때까지 서버가 시작되지 않기 때문에이 프롬프트에 응답하기 위해 emacsclient에 연결할 수 없습니다. (이것은 ALTERNATE_EDITOR를 빈 문자열로 설정하여 emacsclient서버가 새 데몬을 시작할 수 없다는 것을 의미하면 여러 Emacs 데몬이 모두 멈추고 대기 할 수 있습니다.) killall emacs문제를 해결 해야합니다. 계속하기 전에.

(데몬 모드가 아닌 모드에서 Emacs를 시작하고 요청한 내용을 확인하여) 시작할 때 프롬프트를 표시하는 각각의 일로 whack-a-mole을 재생할 수 있지만 다음 데몬을 멈출 수 없기 때문에 해결책 이 아닙니다. 새로운 이유 때문에 스타트 업에 매달리지 않아도됩니다.

예를 들어 : 시스템 재부팅 또는 Emacs 크래시 이후 첫 번째 재부팅 후 Emacs가 기능 상실 Emacs에서 잠금 파일을 훔치는 것이 좋은지 알고 싶을 때 발생하는 일반적인 이유입니다. 프롬프트가 항상 "예"라고 상호 작용하지 않고 응답하도록 조언을 작성하여 문제를 해결할 수 있습니다. 그러나 이전 세션 저장에서 열린 파일 중 하나는 sudo 또는 SSH 비밀번호가 필요한 TRAMP 파일이므로 디먼이 비밀번호 프롬프트에서 대기 중입니다. 따라서 문제가 발생한 파일 을 제거하기 위해 세션 파일 ( vi또는 emacs -q!로)을 수동으로 편집하여 문제를 해결 하지만 다음 번에는 발생하지 않습니다.

따라서 시작시 세션 자동로드를 중지하고 첫 번째 emacsclient에서 수동으로 실행해야하는 명령으로 변경할 수 있습니다. 그러나 백그라운드에서 내 세션을로드하지 않으므로 사용할 준비가 될 때까지 준비가되면 데몬의 전체 목적이 손실됩니다!

그래서 내가 원하는 것은 :

• (최상의) 나머지 초기화를 완료하면서 emacsclient를 열 때까지 미니 버퍼 프롬프트를 연기하는 방법.
• (OK) 위의 설명과 같이 이미 조언하지 않은 모든 미니 버퍼 프롬프트를 만드는 방법 no은 emacsclient가 실행되고 있지 않으면 반환 됩니다. TRAMP 버퍼가 작동하는 한 오류가 발생하여 살 수 있습니다.

이러한 목표 중 하나를 달성 할 수있는 방법이 있습니까?

우리가 논의한 바에 따르면, X-server를 실행하지 않으면 첫 번째 솔루션을 사용할 수 없게됩니다.

다음에서는 텍스트 터미널 프레임과 함께 작동하는 두 번째 솔루션을 제시합니다.

초기화시 하나를 통한 사용자 입력이 필요한 avoid-initial-terminal경우 텍스트 터미널 프레임을 열 때까지 Emacs에서 권장하는 기능이 대기합니다. 해당 프레임의 미니 버퍼에 프롬프트가 나타나고 대화 형 응답을 제공 할 수 있습니다.

코드 관련 정보는 코드에서 주석으로 제공됩니다. TODO자신의 구성을 삽입 할 위치를 나타내는 설명 이있는 마커가 있습니다. 현재 코드를 확인하는 테스트 양식이 있습니다.

;; TODO: Do here configure the server if needed.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Startup the server:
;; Analysis of read_from_minibuffer in src/minibuf.c and daemon_type in src/emacs.c
;; shows that daemon-initialized must have run before read-passwd / read-string
;; works on frames. Before it only works on stdin & stdout.
(server-start) ;;< early start
(let ((after-init-time before-init-time))
  (daemon-initialized)) ;; Finalize the daemon, 

(advice-add 'daemon-initialized :override #'ignore)
;;< Ignore `daemon-initialized' after initialization. It may only run once!
;; Now the background emacs is no longer marked as daemon. It just runs the server.

(defun prevent-server-start (&rest _ignore)
  "Prevent starting a server one time after `server-start' has been advised with this."
  (advice-remove 'server-start #'prevent-server-start))

(advice-add 'server-start :override #'prevent-server-start)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Prepare waiting for a real terminal frame when user input is required:

(defun avoid-initial-terminal (fun &rest args)
  "Wait until we are no longer on \"intial-terminal\".
Afterwards run `fun' with frame on the other terminal selected."
  (message "Avoiding initial terminal. Terminal: %S" (get-device-terminal nil))
  (while (string-equal
      (terminal-name (get-device-terminal nil))
      "initial_terminal")
    (sleep-for 1))
  ;; (message "Selected frame: %S; Running %S with %S." (selected-frame) fun args)
  (apply fun args))

(advice-add 'read-string :around #'avoid-initial-terminal)

(advice-add 'read-passwd :around #'avoid-initial-terminal)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; TODO: Your initialization that is not daemon related
;; and may require user input:

;; Currently this is just a test.
(read-passwd "Passwd: ")

(read-string "String: ")

(y-or-n-p "y-or-n query")

테스트 : 이맥스 버전 : 26.1

1) emacs --daemon콘솔에서 실행하십시오 .

2) emacsclient --tty다른 콘솔에서 실행하십시오 . 비밀번호와 문자열을 묻는 메시지가 표시됩니다. 그 후에는 y 또는 np 조회에 응답해야합니다.

정확히 당신이 요구하는 것이 아니라 원래 문제에 대한 해결책 일 수 있습니다.

emacs --daemon이 아직 존재하지 않는 미니 버퍼에 표시되는 프롬프트에 대한 응답을 영원히 기다리지 못하게하는 일반적인 방법이 있는지 알고 싶습니다.

데몬이 시작 단계에서 발생하는 질문에 대답하기위한 그래픽 프레임을 제공하면 더 이상 멈추지 않습니다.

아래 코드는 my-with-initial-frame사용 가능한 첫 번째 디스플레이 (예 :)에서 프레임을 여는 일반적인 조언 을 정의합니다 :0.0.

이 조언은 아래와 같이 y-or-n-p또는 과 같은 명령을 쿼리하는 데 쉽게 추가 할 수 있습니다 read-passwd.

프레임을 열면 사용자 인터페이스에서 쿼리에 응답 할 수있는 대략적인 가능성이 제공됩니다. 대화 상자를 사용할 수도 y-or-n-p있지만 특정 쿼리 명령에 대한 특수 솔루션이 필요합니다. 나는 그것을 피하고 싶었다.

init 파일에서 해당 코드를 시도하면 첫 번째 코드인지 확인하십시오.

(when (daemonp)

  (defun my-with-initial-frame (&rest _)
    "Ensure a frame on display :0.0 and ignore args."
    (let* ((display-list (x-display-list))
           (display-re (and display-list (regexp-opt display-list)))
           (term (and display-re (cl-some (lambda (term) (and (string-match display-re (terminal-name term)) term)) (terminal-list))))
           (frame (and term (cl-some (lambda (frame) (and (frame-live-p frame) frame)) (frames-on-display-list term)))))
      (select-frame (or frame (make-frame-on-display (getenv "DISPLAY"))))))

  (message "Advising querying functions with `my-with-initial-frame'.")
  (advice-add 'y-or-n-p :before #'my-with-initial-frame)
  (advice-add 'read-passwd :before #'my-with-initial-frame))

테스트:

가정 :

프로그램이 DISPLAY환경 변수 를 통해 연결할 수있는 실행중인 xserver가 있어야 합니다.

xterm에 입력 :

emacs --daemon

emacsclient --eval '(y-or-n-p "A")'

y-or-n-p쿼리 프롬프트 가있는 프레임이 열립니다 A (y or n). 해당 쿼리에 응답하고 다시 시도하십시오.

emacsclient --eval '(y-or-n-p "B")'

B (y or n)동일한 프레임에 프롬프트 가있는 새 쿼리 예를 들어 다음과 같이 해당 프레임을 닫고 C-x 5 0다시 시도하십시오.

emacsclient --eval '(y-or-n-p "C")'

쿼리 프롬프트와 함께 새 프레임이 열립니다 C (y or n).

암호 입력에서도 동일하게 작동합니다.

나는 프롬프트를 연기 하는 것이 일반적으로 어려울 것이라고 생각 하지만, 그러한 프롬프트가 즉시 오류를 나타내도록 Emacs를 변경하는 것은 상당히 쉬워야합니다.

그뿐만 아니라 많은 체조가 없다면 그 프롬프트에 답할 수 없다면, 그것이 버그로 자격이 있다고 생각합니다. 그래서 버그 보고서를 제출하는 것이 좋습니다.