org-mode 의제에서 무료 시간 블록 표시

내 조직 모드 의제에서 무료 시간 블록이 어디에 있는지 쉽게 찾을 수 있기를 원합니다.

예를 들어, 9:30 am-10:30am과 다른 11:15 am-12:30pm에 두 약속이 있으면 10:30 am-11:15am 블록이 한눈에 들어오고 싶습니다.

다시 말해, 구글 캘린더와 같은 그래픽 아젠다 에서처럼 자유 시간을 쉽게 구별 할 수 있기를 원합니다.

빈 시간 블록을 쉽게 볼 수있는 방법이 있습니까? 주어진 시간 (분)보다 긴 빈 블록을 채색 할 수 있습니까?

때문에의 이 질문에 내 자신의 I의 기능 보았다 org-agenda-add-time-grid-maybe시간 그리드를 만듭니다. OP의 의견에 요청 된대로 시간이 바쁘면 거기에 게시 된 코드 (나에 의해 작성되지 않은)는 그리드 라인을 제거합니다.

당신처럼, 나는 어떤 방식으로 시각적 블록을 만들고 싶었습니다. org-agenda-add-time-grid-maybeMichael Ekstrand 의 원래 코드 와 defadvice를 다른 스레드에 게시하여에 대한 다음 코드를 생각해 냈습니다 org-agenda-add-time-grid-maybe. 그리드 선을 다른 색상으로 출력하고 (얼굴을 사용하는 순간 org-archived) 시간에 다른 문자열이 따라옵니다. 둘 다 원하는대로 변경할 수 있습니다.

(defun org-agenda-add-time-grid-maybe (list ndays todayp)
  "Add a time-grid for agenda items which need it.

LIST is the list of agenda items formatted by `org-agenda-list'.
NDAYS is the span of the current agenda view.
TODAYP is t when the current agenda view is on today."

  (catch 'exit
   (cond ((not org-agenda-use-time-grid) (throw 'exit list))
         ((and todayp (member 'today (car org-agenda-time-grid))))
         ((and (= ndays 1) (member 'daily (car org-agenda-time-grid))))
         ((member 'weekly (car org-agenda-time-grid)))
         (t (throw 'exit list)))
   (let* ((blocks (mapcar (lambda (x)
                            (let ((start (get-text-property 1 'time-of-day x))
                                  (dur (get-text-property 1 'duration x)))
                              (cond
                               ((and start dur) (cons start
                                                      (org-time-from-minutes
                                                       (truncate
                                                        (+ dur (org-time-to-minutes start))))))
                               (start start)
                               (t nil))))
                          list))
          (have (delq nil (mapcar
                           (lambda (x) (get-text-property 1 'time-of-day x))
                           list)))
          (string (nth 3 org-agenda-time-grid))
          (gridtimes (nth 1 org-agenda-time-grid))
          (req (car org-agenda-time-grid))
          (remove (member 'remove-match req))
          new time)
     (if (and (member 'require-timed req) (not have))
         ;; don't show empty grid
         (throw 'exit list))

     (while (setq time (pop gridtimes))
       (unless (and remove (member time have))
         (let* ((windows (delq nil blocks))
                (hit nil))
           (dolist (busy windows)
             (unless hit
               (when (and (>= time (car busy))
                          (< time (cdr busy)))
                 (setq hit t))))
           (setq time (replace-regexp-in-string " " "0" (format "%04s" time)))
           (if hit
               (progn
                 (push (org-agenda-format-item
                        (concat string " dito") string nil "" nil
                        (concat (substring time 0 -2) ":" (substring time -2)))
                       new)
                 (put-text-property 2 (length (car new)) 'face 'org-archived (car new)))
             (progn
               (push (org-agenda-format-item
                      nil string nil "" nil
                      (concat (substring time 0 -2) ":" (substring time -2)))
                     new)
               (put-text-property 2 (length (car new)) 'face 'org-time-grid (car new))))
           (setq hit nil))))

     (when (and todayp org-agenda-show-current-time-in-grid)
       (push (org-agenda-format-item
              nil org-agenda-current-time-string nil "" nil
              (format-time-string "%H:%M "))
             new)
       (put-text-property
        2 (length (car new)) 'face 'org-agenda-current-time (car new)))

     (if (member 'time-up org-agenda-sorting-strategy-selected)
         (append new list)
       (append list new)))))

(defun org-time-to-minutes (time)
  "Convert an HHMM TIME to minutes."
  (+ (* (/ time 100) 60) (% time 100)))

(defun org-time-from-minutes (minutes)
  "Convert a number of MINUTES to an HHMM time."
  (+ (* (/ minutes 60) 100) (% minutes 60)))

분명히, defadvice를 사용하는 것이 더 우아 할 것이지만, 정확히 개입 할 곳을 알 수 없었습니다. 함수 자체는 모든 그리드 시간 (에서 설정 org-agenda-time-grid)을 거치며 면 (신규)을 포함하여 최종 그리드로 새 목록을 만듭니다.