format-time-string과 같은 함수를 구현하는 가장 쉬운 방법은 무엇입니까

이 format-time-string 함수는 문자열을 가져와 해당 문자열의 특수 구조 세트 (로 시작하는 문자 %)를 특정 텍스트로 바꿉니다 .

내 자신의 기능으로 이와 같은 기능을 구현하고 싶습니다.

• 문자와 기호 사이에 다음과 같은 목록이 '((?n . name) (?r . reputation))있습니다.
• 이 함수는와 같은 문자열을 가져야합니다 "My name is %n, and my rep is %r".
• 그것은 교체해야 %n하고 %r변수의 값 name과 reputation, 그 결과를 반환한다.
• %%처럼 처리해야합니다 format-time-string(로 교체하십시오 %).

이 기능을 구현하는 가장 쉬운 방법은 무엇입니까?
이것을 용이하게하는 라이브러리 또는 함수가 있습니까? %%올바르게 취급 하는 것이 중요합니다.

사용되는 기본 기능은 다음 format-spec과 format-spec-make같습니다.

(let* ((name "Malabarba")
       (reputation "good")
       (fs (format-spec-make ?n name ?r reputation)))
  (format-spec "My name is %n, with a %r reputation.  %% is kept." fs))

elisp에는 문자열 처리를위한 기본 기능이 있으므로 형식 문자열을 버퍼에 넣고 반복하는 것이 좋습니다.

(defvar malabarba-alist '((?n . "Malabarba") (?r . 7488) (?% . "%")))

(defun malabarba-format (string)
  (with-temp-buffer
    (insert string)
    (goto-char 1)
    (while (search-forward "%" nil t)
      (let ((s (cdr (assoc (char-after) malabarba-alist))))
        (cond
          (s (delete-char -1) (delete-char 1) (insert (format "%s" (eval s))))
          (t (unless (eobp) (forward-char))))))
    (buffer-string)))

사소한 미묘함 — 버퍼의 끝에서 리턴 %하기 때문에 문자열 끝에 고독이 있으면 깨지지 않습니다 .char-afternil

가짜 달력의 형식 시간 문자열에 사용하는 코드는 다음과 같습니다.

(defun mystcal-format-time (format-string time)
  "Format time
%Y is the year.
%m is the numeric month.
%B is the full name of the month.
%d is the day of the month, zero-padded, %e is blank-padded.
%u is the numeric day of week from 1 (Monday) to 7, %w from 0 (Sunday) to 6.
%A is the locale's full name of the day of week.
%H is the hour on a 24-hour clock, %I is on a 12-hour clock, %k is like %H
 only blank-padded, %l is like %I blank-padded.
%p is the locale's equivalent of either AM or PM.
%M is the minute.
%S is the second."
  (let* (output
         (start 0)
         (decoded-time (if (listp time)
                           time
                         (mystcal-decode-time time)))
         (turn (nth 0 decoded-time))
         (minute (nth 1 decoded-time))
         (hour (nth 2 decoded-time))
         (day (nth 3 decoded-time))
         (month (mystcal-month decoded-time))
         (year (nth 5 decoded-time))
         (weekday (mystcal-weekday-of-day day))
         (hour12 (mod hour 12)))
    (save-match-data
      (while (string-match "%" format-string start)
        (let ((index (match-beginning 0)))
          ;; First copy non-format text
          (setq output (concat output (substring format-string start 
                                                 index)))
          ;; Process format codes here
          (let (fmted)
            (setq output (concat output 
                                 (case (aref format-string (1+ index))
                                   (?Y (number-to-string year))
                                   (?m (number-to-string month))
                                   (?B (mystcal-month-name month))
                                   (?d (format "%02d" day))
                                   (?e (format "%2d" day))
                                   (?u (number-to-string (if (zerop weekday)
                                                             7
                                                           weekday)))
                                   (?w (number-to-string weekday))
                                   (?A (mystcal-weekday-name 
                                        (mystcal-weekday-of-day day)))
                                   (?H (format "%02d" hour))
                                   (?k (format "%2d" hour))
                                   (?I (format "%02d" (if (zerop hour12) 12 hour12)))
                                   (?l (format "%2d" (if (zerop hour12) 12 hour12)))
                                   (?p (if (< hour 12)
                                           "AM" "PM"))
                                   (?M (format "%02d" minute))
                                   (?S "00")))))
          (setq start (+ 2 index)))))
    (setq output (concat output (substring format-string start)))
    output))