조직 모드에서 소스 파일을 포함 할 때 시작 및 끝 줄을 자동으로 계산하는 방법은 무엇입니까?

내 문서에 아래 내용이 있습니다.

#+INCLUDE: "code/basic.sv" :src systemverilog :lines "14-117"

여기서 14 행은 내가있는 곳 class basic extends ..이고 116 행은 내가있는 곳 endclass입니다.

숫자 14와 117 (= 116 + 1)을 자동으로 삽입하여 매번 업데이트 할 때마다 수동으로 업데이트 할 필요가 없도록하는 방법이 code/basic.sv있습니까?

다른 옵션이 있습니다. 이것은 정규 표현식을 포함별로 사용자 정의 할 수있게합니다. 확장 기반 정의로 제한되지 않으므로 일부 워크 플로에 더 적합합니다.

쓰다

조직 파일에서 다음과 같은 작업을 수행하십시오. ( :lines키워드는 선택 사항입니다)

#+INCLUDE: "code/my-class.sv" :src systemverilog :range-begin "^class" :range-end "^endclass" :lines "14-80"

이 함수는 "my-class.sv"를 방문하여 두 정규 표현식을 검색 한 다음 :lines일치 결과에 따라 키워드 를 업데이트합니다 .

:range-begin누락 된 경우 범위는 "-80"입니다. 누락 된
경우 :range-end범위는 "14-"입니다.

코드

(add-hook 'before-save-hook #'endless/update-includes)

(defun endless/update-includes (&rest ignore)
  "Update the line numbers of #+INCLUDE:s in current buffer.
Only looks at INCLUDEs that have either :range-begin or :range-end.
This function does nothing if not in org-mode, so you can safely
add it to `before-save-hook'."
  (interactive)
  (when (derived-mode-p 'org-mode)
    (save-excursion
      (goto-char (point-min))
      (while (search-forward-regexp
              "^\\s-*#\\+INCLUDE: *\"\\([^\"]+\\)\".*:range-\\(begin\\|end\\)"
              nil 'noerror)
        (let* ((file (expand-file-name (match-string-no-properties 1)))
               lines begin end)
          (forward-line 0)
          (when (looking-at "^.*:range-begin *\"\\([^\"]+\\)\"")
            (setq begin (match-string-no-properties 1)))
          (when (looking-at "^.*:range-end *\"\\([^\"]+\\)\"")
            (setq end (match-string-no-properties 1)))
          (setq lines (endless/decide-line-range file begin end))
          (when lines
            (if (looking-at ".*:lines *\"\\([-0-9]+\\)\"")
                (replace-match lines :fixedcase :literal nil 1)
              (goto-char (line-end-position))
              (insert " :lines \"" lines "\""))))))))

(defun endless/decide-line-range (file begin end)
  "Visit FILE and decide which lines to include.
BEGIN and END are regexps which define the line range to use."
  (let (l r)
    (save-match-data
      (with-temp-buffer
        (insert-file file)
        (goto-char (point-min))
        (if (null begin)
            (setq l "")
          (search-forward-regexp begin)
          (setq l (line-number-at-pos (match-beginning 0))))
        (if (null end)
            (setq r "")
          (search-forward-regexp end)
          (setq r (1+ (line-number-at-pos (match-end 0)))))
        (format "%s-%s" l r)))))

내가 생각할 수있는 가장 좋은 방법은 내보내기 직전에 또는 평가하기 전에이 숫자를 업데이트하는 것입니다.

업데이터

이것은 버퍼를 통과하는 기능입니다. 키에 바인딩하거나 후크에 추가 할 수 있습니다. 다음 코드 는 파일을 저장할 때마다 줄을 업데이트 하지만 사용 사례가 다른 경우 필요한 후크를 찾으십시오! (org 모드는 후크 로 가득합니다 )

(add-hook 'before-save-hook #'endless/update-includes)

(defun endless/update-includes (&rest ignore)
  "Update the line numbers of all #+INCLUDE:s in current buffer.
Only looks at INCLUDEs that already have a line number listed!
This function does nothing if not in org-mode, so you can safely
add it to `before-save-hook'."
  (interactive)
  (when (derived-mode-p 'org-mode)
    (save-excursion
      (goto-char (point-min))
      (while (search-forward-regexp
              "^\\s-*#\\+INCLUDE: *\"\\([^\"]+\\)\".*:lines *\"\\([-0-9]+\\)\""
              nil 'noerror)
        (let* ((file (expand-file-name (match-string-no-properties 1)))
               (lines (endless/decide-line-range file)))
          (when lines
            (replace-match lines :fixedcase :literal nil 2)))))))

정규식

여기에 포함 할 첫 번째 및 마지막 행으로 사용될 정규식을 정의합니다. 각 파일 확장자에 대한 정규식 목록을 제공 할 수 있습니다.

(defcustom endless/extension-regexp-map 
  '(("sv" ("^class\\b" . "^endclass\\b") ("^enum\\b" . "^endenum\\b")))
  "Alist of regexps to use for each file extension.
Each item should be
    (EXTENSION (REGEXP-BEGIN . REGEXP-END) (REGEXP-BEGIN . REGEXP-END))
See `endless/decide-line-range' for more information."
  :type '(repeat (cons string (repeat (cons regexp regexp)))))

백그라운드 워커

이것은 대부분의 작업을 수행하는 사람입니다.

(defun endless/decide-line-range (file)
  "Visit FILE and decide which lines to include.
The FILE's extension is used to get a list of cons cells from
`endless/extension-regexp-map'. Each cons cell is a pair of
regexps, which determine the beginning and end of region to be
included. The first one which matches is used."
  (let ((regexps (cdr-safe (assoc (file-name-extension file)
                                  endless/extension-regexp-map)))
        it l r)
    (when regexps
      (save-match-data
        (with-temp-buffer
          (insert-file file)
          (while regexps
            (goto-char (point-min))
            (setq it (pop regexps))
            (when (search-forward-regexp (car it) nil 'noerror)
              (setq l (line-number-at-pos (match-beginning 0)))
              (when (search-forward-regexp (cdr it) nil 'noerror)
                (setq regexps nil
                      r (line-number-at-pos (match-end 0))))))
          (when r (format "%s-%s" l (+ r 1))))))))