다음과 같은 elisp 코드가 있다고 가정 해보십시오.

(+ 2 3▮(+ 3
          4))

기호를 추가하거나 제거 할 때 커서 다음에 sexp를 자동으로 다시 들여 쓰는 방법이 있습니까?

따라서를 누르면 SPC 4 SPC자동으로 다음을 얻습니다.

(+ 2 3 4 ▮(+ 3
             4))

나는 호출하여이 설명서를 할 수있는 mark-sexp다음 indent-region. 더 좋은 방법이 있습니까?

mark-sexp+ 대신에을 indent-region누를 수 있습니다 C-M-q. 이 호출 indent-pp-sexp됩니다. 자동은 아니지만 두 명령을 호출하는 것보다 약간 낫습니다.

또는을 사용하는 paredit-mode경우을 누릅니다 M-q. 그것은 당신이 속한 전체 함수 정의를 다시 들여 쓸 것입니다.

공격적인 들여 쓰기 모드

어떤 사람들은 그것을 요청했기 때문에이 답변 을 패키지로 바꿨습니다 .

Melpa를 구성한 경우 다음과 같이 설치할 수 있습니다.

M-x package-install RET aggressive-indent

모든 옵션에 대해서는 Readme 를 참조하십시오. 가장 간단한 방법은 다음과 같습니다.

(add-hook 'emacs-lisp-mode-hook #'aggressive-indent-mode)

옛 대답

다음은 elisp 버퍼에서만 자동 들여 쓰기를 수행합니다. 입력하는 대신 물건을 지우거나 k 때 작업하는 이점도 있습니다. 다른 모드에도 쉽게 추가 할 수 있습니다.

이 함수는 현재 내부에있는 s- 표현을 들여 쓰기합니다. 원하는 경우 키에 바인딩 할 수 있지만 먼저 아래를 참조하십시오.

(require 'cl-lib)

(defun endless/indent-defun ()
  "Indent current defun.
Do nothing if mark is active (to avoid deactivating it), or if
buffer is not modified (to avoid creating accidental
modifications)."
  (interactive)
  (ignore-errors
    (unless (or (region-active-p)
                buffer-read-only
                (null (buffer-modified-p)))
      (let ((l (save-excursion (beginning-of-defun 1) (point)))
            (r (save-excursion (end-of-defun 1) (point))))
        (cl-letf (((symbol-function 'message) #'ignore))
          (indent-region l r))))))

이 후크는 아무것도 입력 한 후 elisp 버퍼에서만이 기능이 실행되도록합니다. 이렇게하면 모든 것이 항상 들여 쓰기됩니다.

(add-hook
 'emacs-lisp-mode-hook
 (lambda ()
   (add-hook 'post-command-hook
             #'endless/indent-defun nil 'local)))

시도 해봐! 그것은 잘 작동합니다.

또한 주석에서 @holocronweaver의 제안에 따라 c와 같은 언어에 다음과 같은 것을 사용할 수 있습니다.

(define-key c++-mode-map ";"
  (lambda () (interactive)
    (insert ";")
    (endless/indent-defun)))

기존 솔루션을 모르지만 post-self-insert-hook직접 수행 하는 데 사용할 수 있습니다 .

(defun my-indent-next-sexp ()
  (interactive)
  (mark-sexp)
  (indent-region))

(add-hook 'post-self-insert-hook 'my-indent-next-sexp)

그래도 잠재적 인 성능 문제에 대해 걱정할 것입니다.

Elisp를 처리 할 때보 다 더 잘 작동하는 el-fly-indent-mode를 시도 할 수 있습니다 aggressive-indent-mode.