Emacs를 열면 인터넷 연결을 통해 패키지 아카이브를 새로 고치는 것을 포함하여 init 파일을 평가합니다. 인터넷에 연결되어 있지 않으면 문제가되므로 인터넷에 연결하지 않고 Emacs를 시작할 때 해당 코드가 실행되지 않도록해야합니다. 이 문제를 해결하기 위해 인터넷에 연결되어 있지 않을 때 Emacs가 패키지 새로 고침 코드를 무시하도록하는 방법이 있는지 궁금합니다.

내 첫 번째 몇 줄은 다음과 같습니다 init.el.

;; Requisites: Emacs >= 24
(require 'package)
(package-initialize)

;; PACKAGE MANAGEMENT
(add-to-list 'package-archives 
  '("melpa" . "http://melpa.milkbox.net/packages/") t)

(package-refresh-contents)       

다음과 같이 Emacs 파일을로드하는 코드를 추가 할 수 있다고 생각합니다.

;; Requisites: Emacs >= 24
(when (connected-to-internet-p)   ; I need this predicate function
  (require 'package)
  (package-initialize)
  (add-to-list 'package-archives 
               '("melpa" . "http://melpa.milkbox.net/packages/") t)
  (package-refresh-contents))

(connected-to-internet)이 문제를 해결하기 위한 기능 또는 유사한 방법이 있습니까?

글쎄, 여전히 자동으로 내용을 새로 고치려면 가능할 때마다 아래 코드와 같은 작업을 수행 할 수 있습니다.

(defun can-retreive-packages ()
  (cl-loop for url in '("http://marmalade-repo.org/packages/"
                        "http://melpa.milkbox.net/packages/"
                        "http://elpa.gnu.org/packages/")
           do (condition-case e
                  (kill-buffer (url-retrieve-synchronously url))
                (error (cl-return)))
           finally (cl-return t)))

몇 가지 기한이 있습니다 :

1. 속도가 느리고 정상적으로 시작할 때 속도가 느리므로 수동으로 수행합니다.
2. 일반적으로 인터넷 연결을 테스트 할 방법이 없습니다. 시도한 시간이 지나면 특정 서비스에 연결할 수 없다는 것을 알 수 있습니다. 이것이 너무 느린 이유 중 하나입니다.
3. 이 코드는 문제에 접근하는 방법을 보여줍니다. (ignore-errors (package-refresh-contents))성공했는지 여부를 신경 쓰지 않으면 쉽게 할 수 있습니다.

쉘 스크립트에서 채택한 간단한 솔루션은

(defun internet-up-p (&optional host)
    (= 0 (call-process "ping" nil nil nil "-c" "1" "-W" "1" 
                       (if host host "www.google.com"))))

*scratch*버퍼 에서 이것을 테스트 할 수 있습니다 .

(message (if (internet-up-p) "Up" "Down"))
"Up"

당신이 시도 할 수있는 한 가지는 기능 network-interface-list입니다. 네트워크 인터페이스 목록과 해당 IP 주소를 반환합니다.

나에게 이것은 이더넷과 와이파 이에 모두 연결되었을 때 반환되는 것입니다.

(("en5" .
  [10 151 0 63 0])
 ("en0" .
  [10 151 2 76 0])
 ("lo0" .
  [127 0 0 1 0]))

Wi-Fi를 끄면 en0사라집니다.

(("en5" .
  [10 151 0 63 0])
 ("lo0" .
  [127 0 0 1 0]))

인터넷을 사용하지 않을 때 얻을 수있는 것들을 실험 해보십시오. 예를 들어, 작동 중일 때만 패키지를 새로 고치려면 en0다음과 같이하십시오.

(when (assoc "en0" (network-interface-list))
  (package-refresh-contents))

레고 시아의 답변을 확장하려면 :

(defun test-internet ()
  (remove-if (lambda (el)
                   (string-match-p "lo.*" (car el)))
                 (network-interface-list)))

활성 네트워크 연결 목록을 반환합니다 ( lo.*일부 경우 루프백 인터페이스 lo임) lo#.

테스트를 반환하는 경우 non-nil, 다음 네트워크 연결이 (와이파이 / 이더넷는 보장은 실제로 그러나 외부 인터넷에 도달하지. 그에 대한 테스트로 핑 곳 할 것)가 반환하는 경우, nil다음 패키지를 검색 할 수있는 방법이 없습니다 명부.

다음을 사용하여 loopback인터페이스와 VirtualBox 및 Docker 인터페이스 를 제외 합니다. 도움이 되길 바랍니다.

(defun tzz-has-network ()
  (remove-if (lambda (i)
               (or (string-match-p "\\(vboxnet\\|docker\\).*" i)
                   (member 'loopback (nth 4 (network-interface-info i)))))
             (mapcar 'car (network-interface-list))))

DBus 및 NetworkManager가있는 최신 Linux 시스템에서 :

(defun nm-is-connected()
  (equal 70 (dbus-get-property
             :system "org.freedesktop.NetworkManager" "/org/freedesktop/NetworkManager"
             "org.freedesktop.NetworkManager" "State")))

나는 당신이 그것을 잘못보고 있다고 생각합니다. 패키지를 자동으로 업데이트하려면 시작할 때 동 기적으로 수행하지 마십시오. 일종의 유휴 타이머에서 수행하십시오. 예 :

(run-with-idle-timer 10 nil
  (lambda ()
    (package-refresh-contents)
    ..etc..))