전체 줄 번호 막대를 사용자 정의 배경색으로 채우려면 어떻게해야합니까?

아래 스크린 샷에서 linum얼굴 의 배경 을 약간의 색상으로 설정했지만 버퍼 끝에 빈 영역이 있으며 줄 바꿈 ( global-visual-line-mode)이 활성화 된 경우 선 사이에 간격이 있습니다 .

이상적으로는 전체 왼쪽이 균일 한 색상이어야합니다. 이것이 가능한가? 나는 Elisp를 알고 있으므로 가능하다면 몇 가지 지침으로 직접 수정 프로그램을 작성할 수 있습니다.

문제

여기서 문제는 여백의 모양을 제어 할 얼굴이 없다는 것입니다. 오버레이를 사용하여 여백에 텍스트를 표시 할 수 linum-mode있지만 (이것이 무엇이든 ) Emacs의 텍스트와 마찬가지로 버퍼의 한계로 제한됩니다. 따라서 버퍼의 마지막 줄을 넘어서 여백 표시를 제어 할 수 없습니다.

당신이 할 수있는 일은 그 사이의 잘못된 라인을 수정하는 것입니다.

거기에 무엇을 넣어

이 변수는 두 개의 논리 선 사이에있는 시각적 선에 표시 할 내용을 제어합니다. 중요한 부분은 'face 'linum이 라인이의 모양을 따르도록합니다 linum-mode. 이 "-----"부분은 실증적이므로 공백 또는 원하는대로 변경할 수 있습니다.

(defvar endless/margin-display
  `((margin left-margin) ,(propertize "-----" 'face 'linum))
  "String used on the margin.")

그것을하는 방법

다음 코드는 버퍼를 통과하여 linum-mode"실제"가 아닌 각 행에 오버레이를 사용 합니다 ( 사용 하는 것과 유사 ).

(defvar-local endless/margin-overlays nil
  "List of overlays in current buffer.")

(defun endless/setup-margin-overlays ()
  "Put overlays on each line which is visually wrapped."
  (interactive)
  (let ((ww (- (window-width)
               (if (= 0 (or (cdr fringe-mode) 1)) 1 0)))
        ov)
    (mapc #'delete-overlay endless/margin-overlays)
    (save-excursion
      (goto-char (point-min))
      (while (null (eobp))
        ;; On each logical line
        (forward-line 1)
        (save-excursion
          (forward-char -1)
          ;; Check if it has multiple visual lines.
          (while (>= (current-column) ww)
            (endles/make-overlay-at (point))
            (forward-char (- ww))))))))

(defun endles/make-overlay-at (p)
  "Create a margin overlay at position P."
  (push (make-overlay p (1+ p)) endless/margin-overlays)
  (overlay-put
   (car endless/margin-overlays) 'before-string
   (propertize " "  'display endless/margin-display)))

그리고 우리 linum-mode는 줄 번호를 업데이트 할 때마다 실행되기를 원합니다 .

(add-hook 'linum-before-numbering-hook #'endless/setup-margin-overlays)

이것을 구성에 넣을 수 있습니다.

(set-face-background 'fringe "#f4a460")

... 색상 코드를 원하는 색상으로 변경하십시오.