채우기 영역 / 단락을 단락 접두사로 식별하는 방법은 무엇입니까?

다음 버퍼가 있다고 가정 해 봅시다.

1. lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum

M-q여기에 때리는 것은 text-mode다음과 같습니다.

1. lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem
ipsum lorem ipsum lorem ipsum lorem ipsum

반면 markdown-mode에을 활성화 하면 다음과 같은 결과가 나타납니다 (마크 다운은 예일 뿐이며 다양한 모드에서 유사한 동작이 나타납니다).

1. lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem
   ipsum lorem ipsum lorem ipsum lorem ipsum

텍스트 모드를 구성하려면 어떻게해야합니까?

special을 작성 하여이 작업을 수행 할 수 있다고 생각 fill-paragraph-function하지만이 변수는 nilin로 설정되어 markdown-mode있으므로 더 쉬운 방법이 있습니다.

필자는 오랫동안 이런 종류의 일을 처리하는 filladapt 모드의 행복한 사용자였습니다. 자세한 내용은

http://emacswiki.org/emacs/FillAdapt

해당 페이지에서 :

KyleJones의 Filladapt는 프로그램 코드의 주석 시퀀스와 같은 채우기 접두사를 추측하고 "1"과 같은 글 머리 기호를 처리하여 Emacs의 채우기 기능을 향상시킵니다. 또는 "*".

예를 들어

* Pretend I'm a really super long line.
* And the window's narrow.

으로

* Pretend I'm a really super
  long line.
* And the window's narrow.

(fill-paragraph &optional JUSTIFY REGION)

[...]

If `fill-paragraph-function' is non-nil, we call it (passing our
argument to it), and if it returns non-nil, we simply return its value.

If `fill-paragraph-function' is nil, return the `fill-prefix' used for filling.

[...]

markdown-mode아마도 함수가 채우기를 수행하는 데 사용되도록 설정 fill-paragraph-function됩니다 .nilfill-prefix

(let ((fill-prefix (make-string (length "1. ") ? ))
  (fill-paragraph))

전체 예 :

(let* ((num 15)
       (numstr (format "%d. " num))
       (fill-prefix (make-string (length numstr) ? )))
  (with-temp-buffer
    (loop for i from 1 to 15 do
          (insert (format "lorem ipsum (%d) doler sit amet " i)))
    (beginning-of-line)
    (insert numstr)
    (fill-paragraph)
    (buffer-string)))

;; =>

"\
15. lorem ipsum (1) doler sit amet lorem ipsum (2) doler sit amet
    lorem ipsum (3) doler sit amet lorem ipsum (4) doler sit amet
    lorem ipsum (5) doler sit amet lorem ipsum (6) doler sit amet
    lorem ipsum (7) doler sit amet lorem ipsum (8) doler sit amet
    lorem ipsum (9) doler sit amet lorem ipsum (10) doler sit amet
    lorem ipsum (11) doler sit amet lorem ipsum (12) doler sit amet
    lorem ipsum (13) doler sit amet lorem ipsum (14) doler sit amet
    lorem ipsum (15) doler sit amet "

Sean의 요지는 나를 올바른 방향으로 지적했으며 여기에 그것을 해결 한 발췌 문장이 있습니다.

(defun my-adaptive-fill-function ()
  "Return prefix for filling paragraph or nil if not determined."
  (cond
   ;; List item inside blockquote
   ((looking-at "^[ \t]*>[ \t]*\\([0-9]+\\.\\|[*+-]\\)[ \t]+")
    (replace-regexp-in-string
     "[0-9\\.*+-]" " " (match-string-no-properties 0)))
   ;; Blockquote
   ((looking-at "^[ \t]*>[ \t]*")
    (match-string-no-properties 0))
   ;; List items
   ((looking-at "^\\([ \t]*\\)\\([0-9]+\\.\\|[\\*\\+-]\\)\\([ \t]+\\)")
    (match-string-no-properties 0))
   ;; No match
   (t nil)))

;; Paragraph filling in text-mode.
(add-hook 'text-mode-hook
  (lambda ()
    (set (make-local-variable 'paragraph-start)
         "\f\\|[ \t]*$\\|[ \t]*[*+-] \\|[ \t]*[0-9]+\\.[ \t]\\|[ \t]*: ")
    (set (make-local-variable 'paragraph-separate)
         "\\(?:[ \t\f]*\\|.*  \\)$")
    (set (make-local-variable 'adaptive-fill-first-line-regexp)
         "\\`[ \t]*>[ \t]*?\\'")
    (set (make-local-variable 'adaptive-fill-function)
         'my-adaptive-fill-function)))