CMake에서 컴파일러가 Clang인지 어떻게 테스트합니까?

크로스 플랫폼 CMake 빌드 스크립트 세트가 있으며 Visual C ++ 및 GCC를 사용한 빌드 를 지원 합니다.

Clang을 시도하고 있지만 CMake 스크립트를 사용하여 컴파일러가 Clang인지 여부를 테스트하는 방법을 알 수 없습니다.

컴파일러가 Clang인지 아닌지 테스트하려면 어떻게해야합니까? 우리는 현재 사용하고있는 MSVC및 CMAKE_COMPILER_IS_GNU<LANG>각각 GCC 비주얼 C를 테스트 ++합니다.

신뢰할 수있는 점검은 CMAKE_<LANG>_COMPILER_ID변수 를 사용하는 것 입니다. 예를 들어 C ++ 컴파일러를 확인하려면 다음을 수행하십시오.

if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  # using Clang
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  # using GCC
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "Intel")
  # using Intel C++
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
  # using Visual Studio C++
endif()

ccache 와 같은 컴파일러 래퍼 를 사용 하는 경우에도 올바르게 작동합니다 .

CMake 3.0.0부터 CMAKE_<LANG>_COMPILER_IDApple 제공 Clang 의 값은 현재 AppleClang입니다. Apple 제공 Clang과 일반 Clang을 모두 테스트하려면 다음 조건을 사용하십시오.

if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  # using regular Clang or AppleClang
endif()

AppleClang 정책 설명 도 참조하십시오 .

CMake 3.15 는 clang-cl 과 일반 clang 프론트 엔드 를 모두 지원합니다 . 변수를 검사하여 프런트 엔드 변형을 결정할 수 있습니다 CMAKE_CXX_COMPILER_FRONTEND_VARIANT.

if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  if (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "MSVC")
    # using clang with clang-cl front end
  elseif (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "GNU")
    # using clang with regular front end
  endif()
endif()

OGRE 3D 엔진 소스 코드는 다음 검사를 사용합니다 .

if (CMAKE_CXX_COMPILER MATCHES ".*clang")
    set(CMAKE_COMPILER_IS_CLANGXX 1)
endif ()

맞춤법 오류를 피하기 위해 대소 문자를 구분하지 않는 비교를 사용합니다.

string( TOLOWER "${CMAKE_CXX_COMPILER_ID}" COMPILER_ID )
if (COMPILER_ID STREQUAL "clang")
    set(IS_CLANG_BUILD true)
else ()
    set(IS_CLANG_BUILD false)
endif ()

의 정규식 만들기 위해 MATCHES대소 문자 구분을, 나는 모든 노력 여기 (CMake에서 지원하지 않는 것) 성공하지 않고있다.

이것은 sakra의 답변에서 수정 된 cmake 초보자를위한 약간 더 자세한 답변입니다. 다음 줄을 추가하십시오 CMakeLists.txt.

if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
  MESSAGE("Clang")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  MESSAGE("GNU")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Intel")
  MESSAGE("Intel")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")
  MESSAGE("MSVC")
endif()

그런 다음 cmake .CMakeLists.txt가있는 폴더에서 실행 하십시오. 그러면 답변과 함께 많은 결과가 나타납니다.

...
-- Detecting CXX compile features
-- Detecting CXX compile features - done
GNU
-- Configuring done
-- Generating done
...