CMake에서 C ++ 11을 어떻게 활성화합니까?

CMake 생성 makefile을 실행하여 프로그램을 컴파일하려고하면 오류가 발생합니다.

C ++ 98 모드에서는 루프 기반 범위가 지원되지 않습니다.

나는 추가하는 시도 add_definitions(-std=c++0x)내에 CMakeLists.txt, 그러나 그것은 도움이되지 않았다.

나는 이것을 시도했다.

if(CMAKE_COMPILER_IS_GNUCXX)
    add_definitions(-std=gnu++0x)
endif()

내가 할 때 g++ --version, 나는 얻는다 :

g ++ (우분투 / 리나로 4.6.1-9 우분투 3) 4.6.1

또한 시도했지만 SET(CMAKE_CXX_FLAGS "-std=c++0x")작동하지 않습니다.

CMake를 사용하여 C ++ 11 기능을 활성화하는 방법을 이해하지 못합니다.

CMake 3.1 은 사용할 수 있는 CMAKE_CXX_STANDARD 변수를 도입했습니다 . 항상 CMake 3.1을 사용할 수 있다는 것을 알고 있다면 최상위 CMakeLists.txt 파일에이 파일을 쓰거나 새 대상이 정의되기 직전에 파일을 넣을 수 있습니다.

set (CMAKE_CXX_STANDARD 11)

이전 버전의 CMake를 지원해야하는 경우 사용할 수있는 매크로는 다음과 같습니다.

macro(use_cxx11)
  if (CMAKE_VERSION VERSION_LESS "3.1")
    if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
      set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11")
    endif ()
  else ()
    set (CMAKE_CXX_STANDARD 11)
  endif ()
endmacro(use_cxx11)

이 매크로는 현재 GCC 만 지원하지만 다른 컴파일러로 확장하는 것은 간단해야합니다.

그런 다음 use_cxx11()C ++ 11을 사용하는 대상을 정의하는 CMakeLists.txt 파일의 맨 위에 쓸 수 있습니다.

macOS를 대상으로하는 clang 사용자를위한 CMake 문제 # 15943

CMake 및 clang을 사용하여 macOS를 대상으로하는 경우 기능이 작동하지 않는 버그 가 있습니다 CMAKE_CXX_STANDARD(컴파일러 플래그를 추가하지 않음). 다음 중 하나를 수행해야합니다.

• CMake 3.0 이상을 요구 하려면 cmake_minimum_required 를 사용하십시오 . 또는

• project명령 전에 CMakeLists.txt 파일 맨 위에 다음 코드를 사용하여 정책 CMP0025를 NEW로 설정하십시오 .

  # Fix behavior of CMAKE_CXX_STANDARD when targeting macOS.
  if (POLICY CMP0025)
    cmake_policy(SET CMP0025 NEW)
  endif ()
  

CMake 명령 target_compile_features()은 필요한 C ++ 기능을 지정하는 데 사용됩니다 cxx_range_for. 그런 다음 CMake는 C ++ 표준을 사용하도록 유도합니다.

cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
project(foobar CXX)
add_executable(foobar main.cc)
target_compile_features(foobar PRIVATE cxx_range_for)

CMake는 C ++ 컴파일러가 적절한 명령 행 플래그로 호출되는지 확인하므로 CMake add_definitions(-std=c++11)변수 를 사용 하거나 수정할 필요가 없습니다 CMAKE_CXX_FLAGS.

아마도 C ++ 프로그램이 이외의 다른 C ++ 기능을 사용하고있을 것 cxx_range_for입니다. CMake 전역 속성 CMAKE_CXX_KNOWN_FEATURES에는 선택할 수있는 C ++ 기능이 나열됩니다.

대신 사용 target_compile_features()도 CMake 속성을 설정하여 명시 적으로 C ++ 표준을 지정할 수 있습니다 당신 CXX_STANDARD 과 CXX_STANDARD_REQUIRED당신의 CMake 목표를 위해.

더 자세한 답변을 참조하십시오 .

나는 사용하고있다

include(CheckCXXCompilerFlag)
CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
if(COMPILER_SUPPORTS_CXX11)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
elseif(COMPILER_SUPPORTS_CXX0X)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
else()
        message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
endif()

당신이 놀고 싶어하지만 C++11, g++ 4.6.1꽤 오래되었습니다. 최신 g++버전 을 얻으십시오 .

Cxx 표준을 설정하는 가장 쉬운 방법은 다음과 같습니다.

 set_property(TARGET tgt PROPERTY CXX_STANDARD 11)

자세한 내용 은 CMake 설명서 를 참조하십시오.

결과적으로 SET(CMAKE_CXX_FLAGS "-std=c++0x")많은 C ++ 11 기능을 활성화합니다. 그것이 효과가 없었던 이유는 진술이 다음과 같기 때문입니다.

set(CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

이 접근 방식에 따라 어떻게 든 -std=c++0x플래그를 덮어 쓰고 작동하지 않았습니다. 플래그를 하나씩 설정하거나 list 메소드를 사용하여 작업 중입니다.

list( APPEND CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

가장 쉬운 방법 :

add_compile_options(-std=c++11)

CMake 3.8 이상에서는 다음을 사용할 수 있습니다.

target_compile_features(target PUBLIC cxx_std_11)

이것이 C ++ 11 지원을 가능하게하는 또 다른 방법입니다.

ADD_DEFINITIONS(
    -std=c++11 # Or -std=c++0x
    # Other flags
)

이 방법 만 작동하고 다른 방법이 실패하는 인스턴스가 발생했습니다. 아마도 최신 버전의 CMake와 관련이있을 수 있습니다.

최신 CMake (> = 3.1)에서 전역 요구 사항을 설정하는 가장 좋은 방법은 다음과 같습니다.

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

"모든 대상에 대해 C ++ 11을 원합니다. 선택 사항이 아니며 GNU 또는 Microsoft 확장을 사용하고 싶지 않습니다." C ++ 17부터는 여전히 IMHO가 최선의 방법입니다.

출처 : CMake에서 C ++ 11 이상 사용

나를 위해 작동하는 것은 CMakeLists.txt에 다음 줄을 설정하는 것입니다.

set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

이 명령을 설정하면 컴파일러의 C ++ 11 기능이 활성화되고 명령을 실행 한 후 코드에서 cmake ..사용 range based for loops하고 오류없이 컴파일 할 수 있어야 합니다.

이 두 줄만으로 충분하다고 생각합니다.

set(CMAKE_CXX_STANDARD 11)

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

항상 최신 C ++ 표준을 활성화하려는 경우 CMAKE_CXX_STANDARD에 대한 17 및 20 값의 최근 (CMake 3.8 및 CMake 3.11) 추가에 비추어 David Grayson의 답변을 확장 한 것입니다.

IF (CMAKE_VERSION VERSION_LESS "3.8")
    SET(CMAKE_CXX_STANDARD 14)
ELSEIF (CMAKE_VERSION VERSION_LESS "3.11")
    SET(CMAKE_CXX_STANDARD 17)
ELSE()
    SET(CMAKE_CXX_STANDARD 20)
ENDIF()

# Typically, you'll also want to turn off compiler-specific extensions:
SET(CMAKE_CXX_EXTENSIONS OFF)

set (CMAKE_CXX_STANDARD 11)링크 된 답변 대신 해당 코드를 사용하십시오 .

최신 cmake는 특정 버전의 C ++를 사용하도록 컴파일러를 구성하는 간단한 방법을 제공합니다. 누구나해야 할 일은 관련 대상 속성을 설정하는 것입니다. cmake가 지원 하는 속성 중 특정 버전의 C ++를 지원하도록 컴파일러를 구성하는 방법을 결정하는 데 사용 되는 속성 은 다음과 같습니다.

• CXX_STANDARD대상을 빌드하기 위해 기능이 요청 된 C ++ 표준을 설정합니다. 이를 11C ++ 11을 대상 으로 설정하십시오 .

• CXX_EXTENSIONS컴파일러 별 확장이 요청되는지 여부를 지정하는 부울입니다. 이것을 설정하면 Off컴파일러 별 확장에 대한 지원 이 비활성화됩니다.

시연을 위해 다음은 최소한의 작업 예제입니다 CMakeLists.txt.

cmake_minimum_required(VERSION 3.1)

project(testproject LANGUAGES CXX )

set(testproject_SOURCES
    main.c++
    )

add_executable(testproject ${testproject_SOURCES})

set_target_properties(testproject
    PROPERTIES
    CXX_STANDARD 11
    CXX_EXTENSIONS off
    )

OS X 및 Homebrew LLVM 관련 :

그 후에 cmake_minimum_required (VERSION 3.3)와 project ()를 호출하는 것을 잊지 마십시오!

또는 CMake는 project()1 행 앞에 암시 적으로 삽입 되어 Clang 버전 감지에 문제가 발생하고 다른 종류의 문제가 발생할 수 있습니다. 관련 문제 는 다음과 같습니다 .