커서 루프에서 사용하기 위해 여러 열을 가져 오는 방법은 무엇입니까?

Question 1

커서 루프 내에서 다음 SQL 스 니펫을 실행하려고하면

set @cmd = N'exec sp_rename ' + @test + N',' +
           RIGHT(@test,LEN(@test)-3) + '_Pct' + N',''COLUMN'''

다음 메시지가 표시됩니다.

Msg 15248, 수준 11, 상태 1, 프로 시저 sp_rename, 줄 213
매개 변수 @objname가 모호하거나 청구 @objtype(COLUMN)가 잘못되었습니다.

무엇이 잘못되었으며 어떻게 수정합니까? 열 이름을 괄호로 묶고 일부 검색 결과와 같은 []큰 따옴표 ""를 제안했습니다.

편집 1-

다음은 전체 스크립트입니다. 테이블 이름을 이름 바꾸기 sp에 어떻게 전달합니까? 열 이름이 많은 테이블 중 하나에 있기 때문에 어떻게 해야할지 모르겠습니다.

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
declare @cmd nvarchar(500) 
declare Tests cursor for
SELECT COLUMN_NAME FROM INFORMATION_SCHEMA.COLUMNS WHERE COLUMN_NAME LIKE 'pct%' AND TABLE_NAME LIKE 'TestData%'

open Tests
fetch next from Tests into @test
while @@fetch_status = 0
BEGIN
  set @cmd = N'exec sp_rename ' + @test + N',' + RIGHT(@test,LEN(@test)-3) + '_Pct' + N', column' 

  print @cmd

  EXEC sp_executeSQL @cmd

  fetch next from Tests into @test
END

close Tests 
deallocate Tests


ROLLBACK TRANSACTION
--COMMIT TRANSACTION

편집 2-이 스크립트는 이름이 패턴과 일치하는 열의 이름을 바꾸도록 설계되었습니다 (이 경우 "pct"접두사 사용). 열은 데이터베이스 내의 다양한 테이블에서 발생합니다. 모든 테이블 이름은 "TestData"로 시작됩니다.

Question 2

다음은 약간 수정 된 버전입니다. 변경 사항은 코드 주석으로 표시됩니다.

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
-- variable to hold table name
declare @tableName nvarchar(255)
declare @cmd nvarchar(500) 
-- local means the cursor name is private to this code
-- fast_forward enables some speed optimizations
declare Tests cursor local fast_forward for
 SELECT COLUMN_NAME, TABLE_NAME
   FROM INFORMATION_SCHEMA.COLUMNS 
  WHERE COLUMN_NAME LIKE 'pct%' 
    AND TABLE_NAME LIKE 'TestData%'

open Tests
-- Instead of fetching twice, I rather set up no-exit loop
while 1 = 1
BEGIN
  -- And then fetch
  fetch next from Tests into @test, @tableName
  -- And then, if no row is fetched, exit the loop
  if @@fetch_status <> 0
  begin
     break
  end
  -- Quotename is needed if you ever use special characters
  -- in table/column names. Spaces, reserved words etc.
  -- Other changes add apostrophes at right places.
  set @cmd = N'exec sp_rename ''' 
           + quotename(@tableName) 
           + '.' 
           + quotename(@test) 
           + N''',''' 
           + RIGHT(@test,LEN(@test)-3) 
           + '_Pct''' 
           + N', ''column''' 

  print @cmd

  EXEC sp_executeSQL @cmd
END

close Tests 
deallocate Tests

ROLLBACK TRANSACTION
--COMMIT TRANSACTION