Windows 배치 스크립트 (.bat)에서 전달 된 인수 목록 가져 오기

$@스크립트에 전달 된 모든 인수 목록을 보유하는 Bash의 Windows 배치 대응 물을 찾고 싶습니다 .

아니면 귀찮게해야 shift합니까?

dancavallaro 는 %*모든 명령 행 매개 변수 (스크립트 이름 자체 제외)에 대해 올바른 권한을 가지고 있습니다 . 다음과 같은 유용한 정보도 있습니다.

%0- 배치 파일을 호출하는 데 사용되는 명령 (수 foo, ..\foo, c:\bats\foo.bat, 등)
%1첫 번째 명령 줄 매개 변수이며,
%2두 번째 명령 줄 매개 변수,
등까지에 %9(그리고 SHIFT9 후 사람들을 위해 사용할 수 있습니다).

%~nx0-호출 방법에 관계없이 배치 파일의 실제 이름 (some-batch.bat)
%~dp0-드라이브 및 스크립트 경로 (d : \ scripts)
%~dpnx0- 스크립트 의 정규화 된 경로 이름 (d : \ scripts \ some -batch.bat)

https://www.ss64.com/nt/syntax-args.html 및 https://www.robvanderwoude.com/parameters.html의 추가 정보 예

%* 스크립트에 전달 된 모든 인수를 보유하고있는 것 같습니다.

%1... %n및 %*인수를 보유하지만 내용이 해석되므로 액세스하기 까다로울 수 있습니다.
따라서 정상적인 진술로 이와 같은 것을 처리하는 것은 불가능합니다

myBatch.bat "&"^&

cmd.exe가 앰퍼샌드 중 하나를 실행하려고하면 각 줄이 실패합니다 (% 1의 내용은 "&"&).

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

그러나 임시 파일에 대한 해결 방법이 있습니다

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

트릭은 after 문 을 활성화 echo on하고 확장하는 %1것 rem입니다 (% 2 .. % *와 함께 작동).
그러나의 출력을 리디렉션 echo on하려면 두 개의 FOR-LOOPS가 필요합니다.

추가 문자 * #는 /?(REM에 대한 도움말을 표시 할 것) 과 같은 내용에 대해 안전하도록 사용됩니다 .
또는 줄 끝의 캐럿 ^은 여러 줄 문자로 작동 할 수 있습니다.

FOR / F는 확장 지연이 해제 된 상태에서 작동해야하며 그렇지 않은 경우 "!" 파괴 될 것이다.
여분의 문자를 제거한 후 가져 왔습니다 param1.

그리고 사용하기에 param1안전한 방식으로, 지연 확장을 가능하게한다.

편집 : % 0에 대한 한 가지 언급

%0다음과 같이 배치를 호출하는 데 사용되는 명령을 포함합니다. FoO.BaT
그러나 함수를 호출 한 후 함수 이름 %0을 %~0포함합니다 (또는 함수를 호출하는 데 사용 된 문자열).
그러나 %~f0여전히 파일 이름을 기억할 수 있습니다.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

산출

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

다음에이 정보를 찾아야 할 때를 찾았습니다. 브라우저와 구글을 여는 대신 call /?cmd를 입력하면 얻을 수 있습니다.

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

스크립트에 대한 모든 인수를 검색하는 방법은 다음과 같습니다.

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

다음은 인수를 가져 와서 env vars로 설정하는 매우 간단한 방법입니다. 이 예제에서 나는 그것들을 키와 값이라고 부릅니다.

다음 코드 예제를 "args.bat"로 저장하십시오. 그런 다음 명령 행에서 저장 한 배치 파일을 호출하십시오. 예 : arg.bat --x 90 --y 120

프로세스를 안내하는 몇 가지 에코 명령을 제공했습니다. 그러나 최종 결과는 --x의 값은 90이고 --y의 값은 120입니다 (즉, 위에 지정된 예제를 실행하는 경우 ;-)).

그런 다음 '정의 된 경우'조건문을 사용하여 코드 블록을 실행할지 여부를 결정할 수 있습니다. "arg.bat --x hello-world"라고 말하면 "IF DEFINED --x echo %-x %"문을 사용할 수 있고 결과는 "hello-world"가됩니다. 배치를 실행하는 것이 더 합리적입니다.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

루핑을 사용하여 모든 인수를 가져오고 순수한 배치로 :

Obs : 없이 사용하는 경우 :?*&<>

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!")

:: write/test these arguments/parameters ::
for /l %%l in (1 1 !_cnt!)do echo/ The argument n:%%l is: !_arg_[%%l]!

goto :eof 

코드는 필요한 경우 인수 번호로 무언가를 수행 할 준비가되었습니다.

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"

echo= !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt

다음 코드는 배열 ( ' params')을 시뮬레이트합니다 . 스크립트가 수신 한 매개 변수를 가져와 변수 params_1.. 에 저장합니다 . params_n여기서 n= params_0= 배열의 요소 수 :

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

공백이 포함 된 따옴표 안에 매개 변수가 있으면 %*올바르게 작동하지 않습니다. 내가 찾은 가장 좋은 해결책은 모든 인수를 조인하는 루프를 갖는 것입니다 : https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

당신이 사용할 수있는 ForCommad 하여 Arg 목록을 얻을 .

도움말 : For /? 도움말 :Setlocal /?

여기 내 방법이 있습니다 =

@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER Scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
 Echo Arg_!Count! = %%I
 set /a Count+=1 
)
Echo Count Of Args = !Count!
Endlocal

Shift 명령이 필요하지 않습니다.

@ 에코 오프
:스타트

:: 여기에 코드를 삽입하십시오
echo. %% 1은 현재 : % ~ 1
:: 여기에 코드를 삽입하십시오

"% ~ 2"NEQ ""(
    시프트
    goto : 시작
)

위의 많은 정보를 통해 추가 연구와 궁극적으로 답변을 얻었으므로 다른 사람에게 도움이되기를 바라면서 상처 입은 일에 기여하고 싶었습니다.

• 또한 파일 내에서 처리 될 수 있도록 다양한 변수를 배치 파일로 전달하려고했습니다.

• 따옴표를 사용하여 배치 파일에 전달하는 것이 좋았습니다.

• 나는 그것들이 아래와 비슷하게 처리되기를 원하지만 수동으로 쓰는 대신 루프를 사용합니다.

그래서 이것을 실행하고 싶었습니다.

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

그리고 for 루프의 마술을 통해 배치 파일 내 에서이 작업을 수행하십시오.

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

내가 가진 문제는 for 루프를 사용하려는 모든 시도가 작동하지 않는다는 것입니다. 아래 예제 :

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

그냥 할 것입니다 :

set "_appPath=C:\Services\Logs\PCAP"

그리고 아닙니다 :

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

설정 후에도

SETLOCAL EnableDelayedExpansion

이유는 for 루프가 전체 라인을 읽고 루프의 첫 번째 반복 중에 두 번째 매개 변수를 %% B에 할당했기 때문입니다. % *는 모든 인수를 나타내므로 처리 할 단일 행만 있습니다. for 루프의 한 번의 패스 만 발생합니다. 이것은 의도적으로 설계된 것으로 내 논리는 잘못되었습니다.

그래서 for 루프 사용을 중단하고 if, shift 및 goto 문을 사용하여 수행하려는 작업을 단순화했습니다. 약간의 해킹에 동의했지만 내 요구에 더 적합합니다. 모든 인수를 반복 한 다음 if 문을 사용하여 모든 인수를 처리하면 루프에서 벗어날 수 있습니다.

내가 성취하려고했던 것에 대한 승리의 진술 :

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

업데이트-대신 아래를 수정해야했습니다. % 1을 참조하려고 할 때이 방법으로 shift를 사용하면 모든 환경 변수가 노출되었습니다.

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

때로는 몇 가지 명령 줄 매개 변수를 추출해야하지만 첫 번째 매개 변수가 아닌 일부 매개 변수를 추출해야합니다. 다음과 같은 호출을 가정 해 봅시다.

Test.bat uno dos tres cuatro cinco seis siete

물론 확장자 ".bat"는 필요하지 않습니다. 최소한 동일한 폴더에 test.exe가 있습니다. 우리가 원하는 것은 "tres cuatro cinco"출력을 얻는 것입니다 (한 줄이든 세 줄이든 상관 없음). 목표는 세 가지 매개 변수 만 필요하고 세 번째 매개 변수부터 시작하는 것입니다. 간단한 예를 들기 위해 각각에 대한 조치는 "에코"이지만 선택한 매개 변수에 대해 더 복잡한 조치를 생각할 수 있습니다.

나는 당신에게 더 잘 맞는 것을 볼 수 있도록 몇 가지 예 (옵션)를 만들었습니다. 불행히도 "for %% i in (% 3, 1, % 5)"와 같은 범위에서 for 루프를 기반으로하는 좋은 방법은 없습니다.

@echo off 
setlocal EnableDelayedExpansion

echo Option 1: one by one (same line)
echo %3, %4, %5
echo.

echo Option 2: Loop For one by one
for %%a in (%3, %4, %5) do echo %%a
echo.

echo Option 3: Loop For with check of limits
set i=0
for %%a in (%*) do (
    set /A i=i+1
    If !i! GTR 2 if !i! LSS 6 echo %%a
)
echo.

echo Option 4: Loop For with auxiliary list
for /l %%i in (3,1,5) do  (
    set a=%%i
    set b=echo %%
    set b=!b!!a!
    call !b!
)
echo.

echo Option 5: Assigning to an array of elements previously
set e[0]=%0
set i=0 
for %%a in (%*) do (
    set /A i=i+1
    set e[!i!]=%%a
)
for  /l %%i in (3,1,5) do (
    echo !e[%%i]!
)
echo.

echo Option 6: using shift and goto loop. It doesn't work with for loop
set i=2
:loop6
    set /A i=i+1
    echo %3
    shift
    If %i% LSS 5 goto :loop6

아마도 더 많은 옵션을 찾거나 여러 옵션을 결합 할 수 있습니다. 그들을 즐기십시오.

Windows 버전 (그렇지만 socat 필요)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

설정 :

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd