무인 설치 후 Office 2010 자동 정품 인증

OCT를 사용하여 무인 Office 2010 설치를 만들었습니다. 우리는 KMS 대신 MAK를 사용하고 있습니다 (내 결정이 아님). 설치 후 Office 2010을 정품 인증하는 방법이 있습니까? 설치하는 동안 키가 설정되어 있어도 활성화되지 않습니다.

랩 환경에 있기 때문에 사용자에게 활성화하라는 메시지가 표시되는 것을 원하지 않습니다.

누군가 궁금해하는 경우-Office는 office14 디렉토리에 OSPP.VBS를 설치하고 특히 사무실 활성화를 처리 할 수 ​​있습니다.

OCT에서는 c:\windows\system32\cscript C:\"Program Files (x86)\Microsoft Office\Office14\OSPP.VBS" /act설치 후 실행되도록 설정했습니다 .

그 후 모든 사무용품이 활성화됩니다. Visio, Project 및 Office를 자동 설치하고 세 제품을 모두 한 번에 정품 인증 한 후 Office가 정품 인증을 시작하도록합니다.

이 게시물의 물을
흐릿하게 만들지는 않지만 OCT에서 다음 명령을 사용하여 설정했습니다. [WindowsFolder] \ system32 \ cscript [INSTALLLOCATION] \ OSPP.VBS
/ act 매개 변수 사용

다른 사람이 해당 정보를 필요로하는 경우를 대비하여. 로스

post sysprep 스크립트 에서이 배치를 처리하면 트릭을 수행해야합니다. 32 비트 및 64 비트 시스템과 다른 OS에서 작동하는지 테스트했습니다.

어쩌면 누군가가 이것 또는 무엇이든 vbs 할 수 있습니다.

activateproper.cmd

REM CUSTOMER NAME HERE
REM DATE LAST MODIFIED

set _win7vlk=XXXXX-8FFQX-YYYYY-33XHT-ZZZZZ
set _2010vlk=YYYYY-YYYYY-WQGB6-KW8P8-XXXXX

REM Use current working dir
cd /d "%~dp0"

if not defined _win7vlk if not defined _2010vlk goto :nokey

echo Checking for internet connectivity needed to activate
echo This screen will not progress until internet is established
echo If you are using firewall please disable the firewall temporarily

:LOOP
PING -n 3 google.com|find "TTL" >NUL
IF NOT ERRORLEVEL 1 goto :ENDLOOP
IF     ERRORLEVEL 1 goto :LOOP
:ENDLOOP
echo Internet Detected

echo Change the time
net time \\LANMACHINEWITHCORRECTTIME /set /y

echo Prompt to activate Windows 7 if needed
if exist "%windir%\system32\slmgr.vbs" FOR /F "tokens=5" %%a in ('cscript "%windir%\system32\slmgr.vbs" -xpr') do (set _act=%%a)
if "%_act%" neq "activated." if defined _win7vlk (
    cscript "%windir%\system32\slmgr.vbs" -ipk %_win7vlk%
    cscript "%windir%\system32\slmgr.vbs" -ato
    )

echo Prompt to activate Office 2010 if needed
if exist "%PROGRAMFILES%\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES%
if exist "%PROGRAMFILES% (x86)\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES% (x86)

if defined _offver if defined _2010vlk (FOR /F "tokens=3* delims=: " %%a in ('cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /dstatus') do (
    if "%%a" == "---OOB_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---OOT_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---NOTIFICATIONS---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    ))



:nokey

AUTO_ACTIVATE 속성 값을 설정하여 MAK 키를 설치할 때 Office 2010을 활성화 할 수도 있습니다. 이렇게 하려면 다음 단계를 수행하십시오 .

1. OCT 의 왼쪽 창에서 설정 속성 수정을 선택한 다음 오른쪽 창에서 추가 를 클릭 합니다.

2. 에서 추가 속성 값 대화 상자에서 이름 상자에 AUTO_ACTIVATE . 속성 이름은 대문자 여야합니다.

3. 에서 값 상자에 1을 , 다음을 클릭 확인 .