zsh에서 ssh의 명령 완성을 편집하는 방법은 무엇입니까?

입력 한 후 호스트 이름을 표시하도록 zsh에서 명령 완료를 설정하고 싶습니다.

ssh [TAB]

내 .ssh / config 파일에서 이름을 가져오고 (그리고 바람직하게는 known_hosts 및 / etc / hosts 및 그 밖의 다른 곳에서) 하나의 단일 목록을 제시하십시오.

현재이 중 일부를 수행하지만

1. .ssh / config를 전혀 사용하지 않습니다.
2. .ssh / config를 사용하면 사용자 이름을 입력 할 필요가 없지만 먼저 사용자 이름이 필요합니다.
3. 여러 목록을 제공합니다 (아마도 known_hosts에서 하나와 / etc / hosts에서 다른 하나).

따라서 ssh [TAB]를 입력 한 후 알려진 사용자 이름과 알려진 호스트 이름을 (바람직하게는 단일) 목록에 포함하고 싶습니다

(1 때문에 답변이 여기에 저장되며 2) 아마도 더 효율적일 것입니다. 아무도 대답하지 않으면 답을 찾아 낼 것입니다.)

여기 내 관련 부분이 있습니다 .zshrc. 나는 다른 오늘을 작성할 수 있도록 그것은 2002 년 이후 변경되지 않은,하지만 여전히에서 완전한 호스트 이름에 작동 ~/.ssh/config하고 ~/.ssh/known_hosts(있는 경우 HashKnownHosts오프 - 그것은 그 당시에는 존재하지 않았다).

h=()
if [[ -r ~/.ssh/config ]]; then
  h=($h ${${${(@M)${(f)"$(cat ~/.ssh/config)"}:#Host *}#Host }:#*[*?]*})
fi
if [[ -r ~/.ssh/known_hosts ]]; then
  h=($h ${${${(f)"$(cat ~/.ssh/known_hosts{,2} || true)"}%%\ *}%%,*}) 2>/dev/null
fi
if [[ $#h -gt 0 ]]; then
  zstyle ':completion:*:ssh:*' hosts $h
  zstyle ':completion:*:slogin:*' hosts $h
fi

ssh완성 을 제공하는 기능은 /usr/share/zsh/functions/Completion/Unix/_ssh내 시스템에 있습니다.

또한 man zshcompsys문서를 참조하십시오 (특히 여러 곳에서 나타나는 "호스트"와 두 곳에서 나타나는 "ssh"에 대한 검색).

zstyle명령을 추가 ~/.zshrc하면 완료 기능을 수정하지 않고도 원하는 작업을 수행 할 수 있습니다.

dig를 사용하여 주어진 도메인의 모든 호스트 목록을 사용 하여이 작업을 수행합니다. 아래 기능을 호스트 파일 또는 정적 목록을 포함하여 원하는 조회 시스템으로 바꿀 수 있습니다.

function complete_host_from_zone () {
    reply=(`dig axfr ouraynet.com @ns1.ouraynet.com | grep -e '^[a-z]' | cut -d\. -f1`)
}
compctl -x 'p[1]' -K complete_host_from_zone -- ssh

참고 : 위의 코드는 구성에서 ssh 명령의 전체 시스템을 완전히 대체하지 않을 수 있습니다. 문제가있는 경우 "ssh"명령을 "mycompletetest"와 같은 다른 임의의 명령으로 변경하고 완료가 작동하는지 확인하십시오.

또한 이것은 완료 될 때마다 dns 영역 전송을 수행합니다! 이것을 많이 사용하거나 상당히 정적 인 도메인에서 사용하면 조회를 수행하고 결과를 저장하는 것이 좋습니다. 조회 기능에서 reply = zone_result를 설정하십시오.

해시 known_hosts파일을 유지하고 싶지 않으며 오히려 HashKnownHosts꺼지지 않습니다 . @Gilles가 이미 내 역사에있는 것과 시드하는 것이 내 요구에 매우 효과적이라는 것을 알았습니다.

h=($(echo $(history | awk '{print $4 " " $5 "\n"}' | grep 'ssh ' | awk '{print $2}' | sort -u)))
if [[ -r ~/.ssh/config ]]; then
  h=($h ${${${(@M)${(f)"$(cat ~/.ssh/config)"}:#Host *}#Host }:#*[*?]*})
fi
if [[ -r ~/.ssh/known_hosts ]]; then
   h=($h ${${${(f)"$(cat ~/.ssh/known_hosts{,2} || true)"}%%\ *}%%,*}) 2>/dev/null
fi
if [[ $#h -gt 0 ]]; then
  zstyle ':completion:*:ssh:*' hosts $h
  zstyle ':completion:*:slogin:*' hosts $h
fi

또한 FWIW, 이것은 Bash에 사용한 것입니다.

# SSH Autocompletion
complete -W "
  $(echo $(grep '^\s*ssh ' ~/.bash_history | sort -u | sed 's/^ssh //' | awk '{print $1}'))
  $(echo $(history | awk '{print $2 " " $3}' | grep 'ssh ' | awk '{print $2}' | sort -u))
  $(sed 's/#.*//;' ~/.ssh/config | awk ' /^Host (.+)$/ {$1 = "";print tolower($0)}')
" ssh