파이썬 데코레이터와 Lisp 매크로

파이썬 데코레이터를 볼 때 누군가가 Lisp 매크로 (특히 Clojure)만큼 강력하다고 진술했습니다.

PEP 318에 주어진 예제를 보면 Lisp에서 오래된 오래된 고차 함수를 사용하는 멋진 방법 인 것처럼 보입니다.

def attrs(**kwds):
    def decorate(f):
        for k in kwds:
            setattr(f, k, kwds[k])
        return f
    return decorate

@attrs(versionadded="2.2",
       author="Guido van Rossum")
def mymethod(f):
    ...

Clojure Macro의 Anatomy에 설명 된 것처럼 예제에서 코드 변환을 보지 못했습니다 . 또한, 파이썬의 누락 동질성 은 코드 변환을 불가능하게 할 수 있습니다.

자,이 두 가지를 어떻게 비교하고 당신이 할 수있는 일이 같다고 말할 수 있습니까? 증거는 그것을 반대하는 것으로 보인다.

편집 : 의견을 바탕으로 두 가지를 찾고 있습니다.“강력한”과“굉장한 일을 쉽게 할 수있는”에 대한 비교.

장식은 기본적으로 단지입니다 기능 .

일반적인 Lisp의 예 :

(defun attributes (keywords function)
  (loop for (key value) in keywords
        do (setf (get function key) value))
  function)

위의 함수는 (에 의해 반환되는 DEFUN) 심볼이며 심볼의 속성 목록 에 속성을 넣습니다 .

이제 함수 정의를 중심으로 작성할 수 있습니다.

(attributes
  '((version-added "2.2")
    (author "Rainer Joswig"))

  (defun foo (a b)
    (+ a b))

)  

파이썬에서와 같이 멋진 구문을 추가하려면 리더 매크로를 작성하십시오 . 리더 매크로를 사용하면 s-expression 구문 레벨에서 프로그래밍 할 수 있습니다.

(set-macro-character
 #\@
 (lambda (stream char)
   (let ((decorator (read stream))
         (arg       (read stream))
         (form      (read stream)))
     `(,decorator ,arg ,form))))

우리는 다음과 같이 쓸 수 있습니다 :

@attributes'((version-added "2.2")
             (author "Rainer Joswig"))
(defun foo (a b)
  (+ a b))

Lisp 리더는 다음을 읽습니다.

(ATTRIBUTES (QUOTE ((VERSION-ADDED "2.2")
                    (AUTHOR "Rainer Joswig")))
            (DEFUN FOO (A B) (+ A B)))

이제 Common Lisp 에 데코레이터 형식이 있습니다.

매크로와 리더 매크로의 결합.

실제로 함수가 아닌 매크로를 사용하여 실제 코드에서 위의 번역을 수행합니다.

(defmacro defdecorator (decorator arg form)
  `(progn
     ,form
     (,decorator ,arg ',(second form))))

(set-macro-character
 #\@
 (lambda (stream char)
   (declare (ignore char))
   (let* ((decorator (read stream))
          (arg       (read stream))
          (form      (read stream)))
     `(defdecorator ,decorator ,arg ,form))))

동일한 리더 매크로에서 위와 같이 사용됩니다. 장점은 Lisp 컴파일러가 여전히 소위 최상위 양식 으로 간주한다는 점입니다 . * file 컴파일러는 최상위 양식을 특수하게 처리합니다 (예 : 컴파일 타임 환경 에 해당 양식에 대한 정보 추가) . 위의 예에서 매크로는 소스 코드를보고 이름을 추출 함을 알 수 있습니다.

Lisp 리더 는 위 예제를 다음과 같이 읽습니다.

(DEFDECORATOR ATTRIBUTES
  (QUOTE ((VERSION-ADDED "2.2")
           (AUTHOR "Rainer Joswig")))
  (DEFUN FOO (A B) (+ A B)))

그러면 매크로가 다음으로 확장됩니다.

(PROGN (DEFUN FOO (A B) (+ A B))
       (ATTRIBUTES (QUOTE ((VERSION-ADDED "2.2")
                           (AUTHOR "Rainer Joswig")))
                   (QUOTE FOO)))

매크로는 리더 매크로와 매우 다릅니다 .

매크로는 소스 코드를 전달 받고 원하는대로 수행 한 다음 소스 코드를 반환합니다. 입력 소스가 유효한 Lisp 코드 일 필요는 없습니다. 그것은 무엇이든 될 수 있으며 완전히 다르게 쓰여질 수 있습니다. 결과는 유효한 Lisp 코드 여야합니다. 그러나 생성 된 코드가 매크로를 사용하는 경우 매크로 호출에 포함 된 코드의 구문은 다시 다른 구문 일 수 있습니다. 간단한 예 : 일종의 수학 구문을 허용하는 수학 매크로를 작성할 수 있습니다.

(math y = 3 x ^ 2 - 4 x + 3)

이 표현식 y = 3 x ^ 2 - 4 x + 3은 유효한 Lisp 코드가 아니지만 매크로는이를 구문 분석하고 유효한 Lisp 코드를 다음과 같이 반환 할 수 있습니다.

(setq y (+ (* 3 (expt x 2))
           (- (* 4 x))
           3))

Lisp에는 많은 다른 매크로 사용 사례가 있습니다.

파이썬 (언어)에서 데코레이터는 함수를 수정할 수없고, 랩핑 만하기 때문에 lisp 매크로보다 훨씬 강력하지는 않습니다.

CPython (인터프리터)에서 데코레이터는 바이트 코드에 액세스 할 수 있기 때문에 함수를 수정할 수 있지만 함수는 먼저 컴파일되어 데코레이터가 뒤섞 일 수 있으므로 구문을 변경할 수 없습니다. 동등한 작업을 수행해야합니다.

현대 리스프는 S- 표현식을 바이트 코드로 사용하지 않으므로 S- 표현 목록에서 작업하는 매크로는 위에서 언급 한 것처럼 바이트 코드 컴파일 전에 작동합니다. 파이썬에서는 데코레이터가 그 뒤를 실행합니다.

파이썬 데코레이터를 사용하여 새로운 제어 흐름 메커니즘을 도입하는 것은 매우 어렵습니다.

새로운 제어 흐름 메커니즘을 도입하기 위해 Common Lisp 매크로를 사용하는 것은 쉽지 않습니다.

이것으로부터 그들은 아마도 똑같이 표현 적이 지 않을 것입니다 (나는 그들이 실제로 의미하는 바를 생각하기 때문에 "강력한"을 "표현"으로 해석하기로 선택합니다).

그것은 분명히 기능과 관련이 있지만, 파이썬 데코레이터에서 호출되는 메소드를 수정하는 것은 쉽지 않습니다 (이것은 f예제 의 매개 변수 일 것입니다 ). 그것을 수정하려면 ast 모듈에 열중 할 수 있지만) 매우 복잡한 프로그래밍에 빠질 것입니다.

이 행을 따라 작업이 완료되었습니다. 매크로 파이 패키지에서 정말 마음에 드는 예제를 확인하십시오.