흠, 나는 두 가지 가능한 알고리즘을 생각할 수 있습니다 : A 시퀀스를 통한 선형 스캔 또는 인덱스의 일정한 시간 조회로 사전을 작성합니다.
하나의 큰 시퀀스 A 에 대해 많은 잠재적 하위 시퀀스 B를 테스트 하는 경우 사전에 변형을 사용하는 것이 좋습니다.
선형 스캔
기술
시퀀스 A에 대한 커서를 유지합니다 . 그런 다음 하위 시퀀스 B의 모든 항목을 반복합니다 . 각 항목에 대해 일치하는 항목을 찾을 때까지 커서를 A 에서 앞으로 이동합니다 . 일치하는 항목이 없으면 B 는 하위 시퀀스가 아닙니다.
이것은 항상 O (seq.size) 에서 실행됩니다 .
의사 코드
명령 스타일 :
def subsequence? seq, subseq:
i = 0
for item in subseq:
i++ while i < seq.size and item != seq[i]
return false if i == seq.size
return true
기능적 스타일 :
let rec subsequence? = function
| _ [] -> true
| [] _ -> false
| cursor::seq item::subseq ->
if cursor = item
then subsequence? seq subseq
else subsequence? seq item::subseq
구현 예 (Perl) :
use strict; use warnings; use signatures; use Test::More;
sub is_subsequence_i ($seq, $subseq) {
my $i = 0;
for my $item (@$subseq) {
$i++ while $i < @$seq and $item != $seq->[$i];
return 0 if $i == @$seq;
}
return 1;
}
sub is_subsequence_f ($seq, $subseq) {
return 1 if @$subseq == 0;
return 0 if @$seq == 0;
my ($cursor, @seq) = @$seq;
my ($item, @subseq) = @$subseq;
return is_subsequence_f(\@seq, $cursor == $item ? \@subseq : $subseq);
}
my $A = [1, 2, 3, 4];
my $B = [1, 3];
my $C = [1, 3, 4];
my $D = [3, 1];
my $E = [1, 2, 5];
for my $is_subsequence (\&is_subsequence_i, \&is_subsequence_f) {
ok $is_subsequence->($A, $B), 'B in A';
ok $is_subsequence->($A, $C), 'C in A';
ok ! $is_subsequence->($A, $D), 'D not in A';
ok ! $is_subsequence->($A, $E), 'E not in A';
ok $is_subsequence->([1, 2, 3, 4, 3, 5, 6], [2, 3, 6]), 'multiple nums';
}
done_testing;
사전 조회
기술
시퀀스 A 의 항목 을 해당 인덱스에 매핑합니다 . 그런 다음 B의 각 항목에 적합한 인덱스를 찾고 작은 인덱스를 건너 뛰고 가능한 가장 작은 인덱스를 하한으로 선택합니다. 인덱스가 없으면 B 는 하위 시퀀스가 아닙니다.
O (subseq.size · k) 와 같이 실행됩니다 . 여기서 k 는 중복 된 수를 나타 seq냅니다. 또한 O (seq.size) 오버 헤드
이 솔루션의 장점은 룩업 테이블을 구축하는 오버 헤드를 지불하면 부정적인 결정에 훨씬 더 빠르게 도달 할 수 있다는 것입니다 (일정 시간까지).
의사 코드 :
명령 스타일 :
# preparing the lookup table
dict = {}
for i, x in seq:
if exists dict[x]:
dict[x].append(i)
else:
dict[x] = [i]
def subsequence? subseq:
min_index = -1
for x in subseq:
if indices = dict[x]:
suitable_indices = indices.filter(_ > min_index)
return false if suitable_indices.empty?
min_index = suitable_indices[0]
else:
return false
return true
기능적 스타일 :
let subsequence? subseq =
let rec subseq-loop = function
| [] _ -> true
| x::subseq min-index ->
match (map (filter (_ > min-index)) data[x])
| None -> false
| Some([]) -> false
| Some(new-min::_) -> subseq-loop subseq new-min
in
subseq-loop subseq -1
구현 예 (Perl) :
use strict; use warnings; use signatures; use Test::More;
sub build_dict ($seq) {
my %dict;
while (my ($i, $x) = each @$seq) {
push @{ $dict{$x} }, $i;
}
return \%dict;
}
sub is_subsequence_i ($seq, $subseq) {
my $min_index = -1;
my $dict = build_dict($seq);
for my $x (@$subseq) {
my $indices = $dict->{$x} or return 0;
($min_index) = grep { $_ > $min_index } @$indices or return 0;
}
return 1;
}
sub is_subsequence_f ($seq, $subseq) {
my $dict = build_dict($seq);
use feature 'current_sub';
return sub ($subseq, $min_index) {
return 1 if @$subseq == 0;
my ($x, @subseq) = @$subseq;
my ($new_min) = grep { $_ > $min_index } @{ $dict->{$x} // [] } or return 0;
__SUB__->(\@subseq, $new_min);
}->($subseq, -1);
}
my $A = [1, 2, 3, 4];
my $B = [1, 3];
my $C = [1, 3, 4];
my $D = [3, 1];
my $E = [1, 2, 5];
for my $is_subsequence (\&is_subsequence_i, \&is_subsequence_f) {
ok $is_subsequence->($A, $B), 'B in A';
ok $is_subsequence->($A, $C), 'C in A';
ok ! $is_subsequence->($A, $D), 'D not in A';
ok ! $is_subsequence->($A, $E), 'E not in A';
ok $is_subsequence->([1, 2, 3, 4, 3, 5, 6], [2, 3, 6]), 'multiple nums';
}
done_testing;
사전 검색 변형 : 유한 상태 머신으로 인코딩
기술
더 많은 메모리에서 거래 하면 알고리즘 복잡도를 O (subseq.size) 로 줄일 수 있습니다 . 요소를 인덱스에 매핑하는 대신 각 노드가 인덱스의 요소를 나타내는 그래프를 만듭니다. 가장자리는 가능한 전이를 보여줍니다. 예를 들어 시퀀스 a, b, a에는 가장자리가 a@1 → b@2, a@1 → a@3, b@2 → a@3있습니다. 이 그래프는 유한 상태 기계와 같습니다.
조회하는 동안 처음에는 트리의 첫 번째 노드 인 커서를 유지합니다. 그런 다음 하위 목록 B의 각 요소에 대해 가장자리를 걷습니다 . 그러한 엣지가 존재하지 않으면 B 는 서브리스트가 아닙니다. 모든 요소 다음에 커서에 유효한 노드 가 있으면 B 는 서브리스트입니다.
의사 코드
명령 스타일 :
# preparing the graph
graph = {}
for x in seq.reverse:
next_graph = graph.clone
next_graph[x] = graph
graph = next_graph
def subseq? subseq:
cursor = graph
for x in subseq:
cursor = graph[x]
return false if graph == null
return true
기능적 스타일 :
let subseq? subseq =
let rec subseq-loop = function
| [] _ -> true
| x::subseq graph -> match (graph[x])
| None -> false
| Some(next-graph) -> subseq-loop subseq next-graph
in
subseq-loop subseq graph
구현 예 (Perl) :
use strict; use warnings; use signatures; use Test::More;
sub build_graph ($seq) {
my $graph = {};
for (reverse @$seq) {
$graph = { %$graph, $_ => $graph };
}
return $graph;
}
sub is_subsequence_i ($seq, $subseq) {
my $cursor = build_graph($seq);
for my $x (@$subseq) {
$cursor = $cursor->{$x} or return 0;
}
return 1;
}
sub is_subsequence_f ($seq, $subseq) {
my $graph = build_graph($seq);
use feature 'current_sub';
return sub ($subseq, $graph) {
return 1 if @$subseq == 0;
my ($x, @subseq) = @$subseq;
my $next_graph = $graph->{$x} or return 0;
__SUB__->(\@subseq, $next_graph);
}->($subseq, $graph);
}
my $A = [1, 2, 3, 4];
my $B = [1, 3];
my $C = [1, 3, 4];
my $D = [3, 1];
my $E = [1, 2, 5];
for my $is_subsequence (\&is_subsequence_i, \&is_subsequence_f) {
ok $is_subsequence->($A, $B), 'B in A';
ok $is_subsequence->($A, $C), 'C in A';
ok ! $is_subsequence->($A, $D), 'D not in A';
ok ! $is_subsequence->($A, $E), 'E not in A';
ok $is_subsequence->([1, 2, 3, 4, 3, 5, 6], [2, 3, 6]), 'multiple nums';
}
done_testing;