화면에서 누르는 키를 렌더링하는 Windows 유틸리티 [닫힘]

많은 사람들에게 원격으로 교육을 제공하고 있으며 많은 응용 프로그램 바로 가기 키를 다룰 것입니다.

MousePose 의 화면에 키 스트로크가 표시되는 것을 보았습니다 . Windows 용 비슷한 제품이 있습니까?

MousePose의 다른 기능 (팬시 마우스 포인터 등)은 나에게 유용하지 않으며 키 누름의 OSD 만 있습니다.

KeyPosé 는 Windows 용 MousePosé 의 무료 대안입니다. 스크린 캐스트 에서 작동중인 것을 볼 수 있습니다 .

다음은 샘플 스크린 샷입니다.

나는 Carnac을 강력히 추천한다 . GitHub에서 호스팅되는 무료 프로젝트입니다.

프리젠 테이션, 스크린 캐스트를위한 키보드 로깅 및 프리젠 테이션 유틸리티로서보다 나은 키보드 사용자가 될 수 있습니다.

GitHub 에서 훌륭하게 실행되고, 잘 설계되었으며, 오픈 소스입니다 .

https://github.com/bfritscher/carnac/releases/tag/v3-beta : 마우스 입력의 수정 및 시각화와 포크 릴리스를 찾으십시오

도구 인 키 캐스트를 공유하고 싶습니다.

https://brookhong.github.io/2014/04/28/keycast-on-windows.html

이 목적으로 AutoHotkey_L 스크립트를 작성했습니다.

실행하려면 AutoHotkey_L ( direct dl )을 사용하십시오 .FOSS 입니다. 또한 AutoHotkey를 사용하면 스크립트를 EXE (간단히 )로 컴파일 할 수 있습니다 .Ahk2Exe.exe /inDisplayPressedKeyOnScreen.ahk/outDisplayPressedKeyOnScreen.exe

마우스 커서 근처에 누른 키 OSD와 같은 표준 툴팁을 표시 할 수 있습니다. 또한 마우스 버튼 클릭과 휠 스크롤을 표시합니다.

(프레임 및 흐리게 처리는 설명 목적으로 수행되며, 스크립트 자체에는 방해가없는 텍스트 만 표시됨)

다음은 스크립트입니다 (메모장에 복사하여 붙여 넣기, DisplayPressedKeysOnScreen.ahk로 저장).

#NoEnv
#SingleInstance force
#InstallKeybdHook

Global KeyStates, MouseState, ClickCount, IdleDelay, LargeDisplay

IdleDelay=3000

LargeDisplay=1
; 0 = Tooltip near mouse pointer
; 1 = Big pane at screen bottom

If LargeDisplay
{
;Initializing GUI
;modded func originated from http://www.autohotkey.com/board/topic/8190-osd-function/

SysGet Monitor, Monitor

GUIx := MonitorLeft
GUIw := MonitorRight - MonitorLeft
GUIh := (MonitorBottom - MonitorTop) * GUIw * 0.00003
If (GUIh > ((MonitorBottom - MonitorTop) * 0.3))
    GUIh := (MonitorBottom - MonitorTop) * 0.3

opacity=230
fname="Tahoma"
fsize:=GUIh * 0.65 ; really, pixel = 0.75 point, but with 0.75 lowercase letter with lower part (like "g") get cut
fcolor=cccccc
bcolor=222222
fformat="600"

Gui +LastFound +AlwaysOnTop +ToolWindow -Caption
Gui Margin, 0, 0 ;pixels of space to leave at the left/right and top/bottom sides of the window when auto-positioning.
Gui Color, ffffff ;changes background color
Gui Font, s%fsize% w%fformat%, %fname%

;    0x80 = SS_NOPREFIX -> Ampersand (&) is shown instead of underline one letter for Alt+letter navigation
Gui Add, Text, c%bcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName, tesT test test
Gui Add, Text, c%fcolor% Center +0x80 w%GUIw% h%GUIh% BackgroundTrans VblkOsdCtrlName2 xp-3 yp-3 , tesT test test

WinSet ExStyle, +0x20 ; WS_EX_TRANSPARENT -> mouse klickthrough
WinSet TransColor, ffffff %opacity%
}


TrayTip %A_ScriptName%, To Exit`, press the Right Windows logo key.

Loop
{
Input SingleKey, L1 V M I B, {LControl}{RControl}{LAlt}{RAlt}{LShift}{RShift}{LWin}{AppsKey}{F1}{F2}{F3}{F4}{F5}{F6}{F7}{F8}{F9}{F10}{F11}{F12}{Left}{Right}{Up}{Down}{Home}{End}{PgUp}{PgDn}{Del}{Ins}{BS}{Capslock}{Numlock}{PrintScreen}{Pause}
GetKeyStates()

;    IfInString ErrorLevel, EndKey
;   CollectedText .= (CollectedText =="" ? "" : " + " ) . SubStr(ErrorLevel, 8)
If SingleKey
{
    SingleKeyText=
    If (SingleKey==Chr(27))
    SingleKeyText=Esc
    Else If (SingleKey==Chr(32))
    SingleKeyText=Space

    If (GetKeyState("LControl", "P") || GetKeyState("RControl", "P"))
    {
    If (SingleKey==Chr(10) && EnterPressed)
        SingleKeyText=Enter
    Else If (SingleKey >= Chr(1) && SingleKey <= Chr(26)) ; With "M" in Input, Ctrl-A through Ctrl-Z correspond to Chr(1) through Chr(26)
        SingleKeyText := Chr(Asc("A")-1+Asc(SingleKey))
    } Else {
    If (SingleKey==Chr(10))
        SingleKeyText=Enter
    }

    If Not SingleKeyText
    SingleKeyText:=SingleKey
    ShowKeys(KeyStates . SingleKeyText)
;    . (MouseState ? "`n" . MouseState : "")
    EnterPressed=0
    GoSub ClearMouseState
} Else {
    ShowKeys(SubStr(KeyStates, 1, -3) . (MouseState ? " + " . MouseState : ""))
}
SetTimer TooltipOff, % -IdleDelay
}

RWin::
ExitApp

~*Enter::
EnterPressed=1
return

~*LButton::
~*RButton::
~*MButton::
~*XButton1::
~*XButton2::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3) . " Pressed"
MouseTooltip()
return

~*WheelDown::
~*WheelUp::
~*WheelLeft::
~*WheelRight::
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3)
MouseTooltip()
return

~*LButton Up::
~*RButton Up::
~*MButton Up::
~*XButton1 Up::
~*XButton2 Up::
;    MsgBox %A_PriorHotkey%`n%A_ThisHotkey%
If (A_PriorHotkey == SubStr(A_ThisHotkey, 1, -3) && A_TimeSincePriorHotkey < 200)
{
    ClickCount++
    Suffix := " Clicked " . ClickCount . "x"
} Else {
    ClickCount:=0
    Suffix := " Released"
}
MouseState := "Mouse " . SubStr(A_ThisHotkey, 3, -3) . Suffix
MouseTooltip()
return

MouseTooltip(){
GetKeyStates()
ShowKeys(KeyStates . MouseState)
SetTimer ClearMouseState,  % -IdleDelay
SetTimer TooltipOff, % -IdleDelay
}

ClearMouseState:
MouseState=
ClickCount=0
return
TooltipOff:
If LargeDisplay
    Gui Hide
Else
    Tooltip
return

GetKeyStates() {
KeyStates := ""
    . ( GetKeyState("LControl", "P") ? "LControl + " : "" )
    . ( GetKeyState("RControl", "P") ? "RControl + " : "" )
    . ( GetKeyState("LAlt", "P") ? "LAlt + " : "" )
    . ( GetKeyState("RAlt", "P") ? "RAlt + " : "" )
    . ( GetKeyState("LShift", "P") ? "LShift + " : "" )
    . ( GetKeyState("RShift", "P") ? "RShift + " : "" )
    . ( GetKeyState("LWin", "P") ? "LWin + " : "" )
    . ( GetKeyState("AppsKey", "P") ? "AppsKey + " : "" )
    . ( GetKeyState("F1", "P") ? "F1 + " : "" )
    . ( GetKeyState("F2", "P") ? "F2 + " : "" )
    . ( GetKeyState("F3", "P") ? "F3 + " : "" )
    . ( GetKeyState("F4", "P") ? "F4 + " : "" )
    . ( GetKeyState("F5", "P") ? "F5 + " : "" )
    . ( GetKeyState("F6", "P") ? "F6 + " : "" )
    . ( GetKeyState("F7", "P") ? "F7 + " : "" )
    . ( GetKeyState("F8", "P") ? "F8 + " : "" )
    . ( GetKeyState("F9", "P") ? "F9 + " : "" )
    . ( GetKeyState("F10", "P") ? "F10 + " : "" )
    . ( GetKeyState("F11", "P") ? "F11 + " : "" )
    . ( GetKeyState("F12", "P") ? "F12 + " : "" )
    . ( GetKeyState("Left", "P") ? "Left + " : "" )
    . ( GetKeyState("Right", "P") ? "Right + " : "" )
    . ( GetKeyState("Up", "P") ? "Up + " : "" )
    . ( GetKeyState("Down", "P") ? "Down + " : "" )
    . ( GetKeyState("Home", "P") ? "Home + " : "" )
    . ( GetKeyState("End", "P") ? "End + " : "" )x
    . ( GetKeyState("PgUp", "P") ? "PgUp + " : "" )
    . ( GetKeyState("PgDn", "P") ? "PgDn + " : "" )
    . ( GetKeyState("Del", "P") ? "Del + " : "" )
    . ( GetKeyState("Ins", "P") ? "Ins + " : "" )
    . ( GetKeyState("BS", "P") ? "BS + " : "" )
    . ( GetKeyState("Capslock", "P") ? "Capslock + " : "" )
    . ( GetKeyState("Numlock", "P") ? "Numlock + " : "" )
    . ( GetKeyState("PrintScreen", "P") ? "PrintScreen + " : "" )
    . ( GetKeyState("Pause", "P") ? "Pause + " : "" )
}

ShowKeys(text) {
If LargeDisplay
{
    Global blkOsdCtrlName, blkOsdCtrlName2, MonitorLeft, MonitorRight, MonitorBottom, MonitorTop, GUIx, GUIy, GUIh

    CoordMode Mouse, Screen
    MouseGetPos MouseX, MouseY

    If ((!GUIy) || (MouseX >= MonitorLeft && MouseX <= MonitorRight && MouseY >= GUIy && MouseY <= (GUIy+GUIh)) ) {
    If (MouseY < (MonitorTop + (MonitorBottom - MonitorTop) / 2) )
        GUIy := MonitorBottom - (MonitorBottom - MonitorTop) * 0.2
    Else
        GUIy := MonitorTop + (MonitorBottom - MonitorTop) * 0.2
    }

    GuiControl Text, blkOsdCtrlName, %text%
    GuiControl Text, blkOsdCtrlName2, %text%

    Gui, Show, x%GUIx% y%GUIy% NoActivate
} Else {
    Tooltip % text
}
}

온 스크린 키보드를 사용하여 창과 함께 제공되는 키 누름을 표시 할 수 있습니다. 실제 키보드를 입력하면 화면의 키보드가 해당 키를 강조 표시합니다.

Presentation Pointer 는 Windows 용 MousePosé의 최상의 대안입니다. 포인터 효과, 마우스 클릭 효과, 키 스트로크를 제공하며 화면에 자유롭게 그릴 수 있지만 화면을 잠글 수는 없습니다. 그것은 실제로 프로그램의 장점입니다.

PointerFocus 는 키 입력을 표시 할 수 있습니다.

QiPress 라는 작은 Windows 앱을 작성했습니다 . 룩앤필을 변경하거나 특정 키 그룹을 표시하거나 무시하고 정적 텍스트 (예 : 자신의 이름 또는 회사 이름)를 추가 할 수있는 컨트롤이 있습니다. 클릭 연결을 사용 중지하고 팝업을 클릭 드래그하여 위치를 지정할 수 있습니다. 필요하지 않을 수도있는 다른 기능이 있지만 대부분 원하는 기능을 다룹니다.

PassMark KeyboardTest 를 사용할 수 있습니다 (무료 30 일 평가 후 구매하려면 US $ 24.00).

참고 사항 :

• SO에 대해서도 비슷한 질문이있었습니다 : 프리젠 테이션 또는 스크린 캐스트 중 키보드 단축키를 화면에 표시하는 방법
• 비슷한 질문이 OS X에 대해 요청되었습니다 : https://apple.stackexchange.com/q/62168/20338
• 소프트웨어 권장 사항에 대한 관련 질문이있었습니다 (OP는 다른 프로그램을 사용하는 동안 사용자가 현재 누르고있는 키를 표시하도록 프로그램에 요청합니다. 누른 모든 키를 표시해야하며 사용자가 키를 놓 자마자 사라져야합니다. ) : 현재 누른 키를 화면에 표시하는 유틸리티