Windows 10의 시작 메뉴와 다른 사용자로 어떻게 실행합니까?

시작 메뉴에서 다른 사용자 (예 : 도메인 관리자 계정)로 응용 프로그램을 실행하면 (응용 프로그램을 Shift + 마우스 오른쪽 단추로 클릭하여) Windows 7 및 XP의 옵션이었습니다.

그러나 Windows 10에서 해당 옵션을 찾을 수 없습니다. 해결 방법은 1) Windows 탐색기에서 응용 프로그램을 찾거나 (Shift + 마우스 오른쪽 단추 클릭) 2) 명령 줄에서 runas.exe를 사용하는 것 같습니다.

그러나 이러한 해결 방법을 사용하기 위해 먼저 실행 파일 이름을 찾아 보았습니다. 모든 RSAT 도구의 이름이나 실행 가능한 이름이 없기 때문에 조금 어렵습니다.

(예 : "Active Directory 사용자 및 컴퓨터"는 dsa.msc, "라우팅 및 원격 액세스"는 rrasmgmt.msc)

더 간단한 방법이 있습니까?

1. Windows + R 키 조합을 눌러 레지스트리 편집기를 열고 regedit 입력 한 후 Enter를 누르십시오. UAC가 프롬프트하면 예를 클릭하여 계속하십시오.
2. 이동 HKEY_CURRENT_USER\Software\Policies\Microsoft\Windows\Explorer-이 키를 찾지 못하면 마우스 오른쪽 버튼을 클릭하고 Windows에서 탐색기 키를 추가하고 DWORD 값을 추가하십시오.ShowRunasDifferentuserinStart
3. 오른쪽 창에서 ShowRunasDifferentuserinStart 키를 마우스 오른쪽 단추로 클릭 한 다음 수정을 클릭하십시오.
4. 1 값 데이터 상자에 값으로 입력 
5. 확인을 클릭하여 설정을 저장하십시오.
6. 레지스트리 편집기를 닫습니다. 시스템을 다시 시작하십시오.

재부팅 후 "추가"드롭 다운 아래에 "다른 사용자로 실행"옵션이 있어야합니다.

나는 여러 도메인 가입 및 비 도메인 가입 PC 에서이 작업을 수행했으며 매력처럼 작동합니다.

출처 : windows10update.com

바로 가기를 마우스 오른쪽 버튼으로 클릭하면됩니다.

이 설명대로는 Windows의 모든 버전과 동일한 단축키 사용 "에서 runas"를 만들 수 있습니다 대답 에 의해 크리스 드 와이어

1. 마우스 오른쪽 단추를 클릭> 새로 작성> 바로 가기
2. 대상에 "runas / user : ComputerName \ administrator program.exe"를 입력하십시오.

.....

runas 명령을 사용하여 바로 가기를 만들려면

.....

StartIsBack ++ 을 사용 하여 기능을 다시 얻을 수도 있습니다 .

StartIsBack ++과 같은 프로그램을 사용할 수없는 경우 시작 메뉴 및 작업 표시 줄 Show "Run as different user" command on Start그룹 정책을 사용 으로 설정하여 동작을 활성화 할 수 있습니다.

관련-Windows 8 및 8.1의 "시작"응용 프로그램 표시 줄에서 "다른 사용자로 실행"을 추가하거나 제거하는 방법

이 기능을 가능하게하는 또 다른 (아마도 새로운) 솔루션이 있는데, 이는 다른 것보다 훨씬 간단합니다. 간단하게 탐색에 설정 > 업데이트 및 보안 > 개발자 , 그리고 아래에 Windows 탐색기 하나를 적용 할 수있는 일들의 목록을 볼 수 있습니다.

당신이 적용 할 수있는 것들의 목록은 첫 번째 모습을 이해하기가 조금 어려울 수 있지만, 그것이 다음과 같이 작동한다고 생각합니다. 그리고 타격 적용 -회색으로 표시되지 않고, 현재 선택하고있는 것들을 가능하게 할 것이다.

방금 설명한 설명에 따라 시작에서 다른 사용자로 실행을 표시하기 위해 변경 정책 만 사용하려면 다른 모든 사용자에서 확인을 제거하고 적용을 눌러야 합니다.

마지막으로, 내가 이야기하고있는 특정 설정의 스크린 샷이 있습니다.

Secondary Logon 서비스 ( seclogon)가 실행되는 동안 다음 코드 블록은 Batch 및 VBScript 파일의 조합으로 작업을 자동화 할 수 있습니다. 배치 파일은 상대 경로 참조를 사용하여 파일을 현재 및 선택된 사용자 계정의 읽기 권한을 허용하는 경로에 배치 할 수 있습니다. 두 파일 모두 같은 경로에 있어야합니다. ShellExecute동사 를 함께 사용 runasuser하면 Windows가 호스트 컴퓨터에서 허용하는 로그온 방법 중에서 선택할 수있는 프롬프트를 표시합니다.

이 프로세스는 컴퓨터 시스템에 로그인 한 후 발생하도록 사용자 시작 프로세스에 추가 할 수 있습니다.

배치 파일: {RunAsUser}{CMD}.cmd

@Echo Off

If "%~1" NEQ "/CALLBACK" Goto :label_Process_Run_As_User

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM Start the process once running as designated user
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

cd C:\
start "" %~dp0cmd.lnk

Goto :EOF

:label_Process_Run_As_User

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM Section below verifies if Secondary Login is available
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

REM Query [Secondary Logon]
sc query seclogon 1> nul 2> nul || (
    Goto :label_Missing_Secondary_Login
)

REM Check to see if [Secondary Logon] service is not disabled
sc qc seclogon | Find /i "START_TYPE" | Find /i "DISABLED" 1> nul 2> nul && (
    Set flg.SecLog.Enabled=F
) || (
    Set flg.SecLog.Enabled=T
)

REM Check to see if [Secondary Logon] service is Running
sc queryex seclogon | Find /i "STATE" | Find /i "RUNNING" 1> nul 2> nul && (
    Set flg.SecLog.Running=T
) || (
    Set flg.SecLog.Running=F
)

REM Determine if action should work
If /i "%flg.SecLog.Enabled%:%flg.SecLog.Running%" EQU "F:F" Goto :label_Secondary_Login_Unavailable

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM Section below starts the RunAsUser process
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

REM System configuration was validateed and RunAsUser will commence

Set "str.SELF=%~0"

WSCRIPT /E:VBSCRIPT "%~dp0RunAsUser.txt"

Goto :EOF

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
REM Section below provides written notices to user for error conditions
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:label_Secondary_Login_Unavailable
Echo.
Echo Unable to utilize the Secondary Logon system service because it is disabled.
Echo.
pause
Goto :EOF

:label_Missing_Secondary_Login
Echo.
Echo Unable to find the Secondary Logon system service
Echo.
pause
Goto :EOF

VBScript 파일 : RunAsUser.txt

'-------------------------------------------
'
' Launch Process RunAsUser
CreateObject("Shell.Application").ShellExecute CreateObject("WScript.Shell").Environment("PROCESS")("str.SELF"), "/CALLBACK", "", "runasuser", 1
'
' Display a message box to pause script
msgbox "Enter username or select Certificate for account" & vbCrLf & "On the windows dialog that will popup." & vbCrLf & vbCrLf & "Click OK once process opens", vbokonly
'
' Quit the script
On Error Resume Next
Window.Close ' HTA Must be Closed Through the Window Object
Err.Clear
Wscript.Quit ' VBS Must be Closed Through the Wscript Object
Err.Clear
On Error Goto 0
'
' ----------------------------------------------------------------------