메모장 ++를 사용하여 .txt 파일에서 하나의 문자와 세 개의 숫자 추출

메모장 ++에서 특정 데이터를 많은 .txt 파일에서 추출하고 싶습니다. 하나의 파일에 많은 데이터가 있지만 특정 정보 만 필요합니다 ...

이것은 파일에서 보이는 것입니다 :

© Q Ńü Vý 8ź) € G '€ \ Y € € w) € â` € K¶ K¶} ¶gg ‚Z ™ y ë (\ Y
SCfsfgh4GHGH1 + € ‡ € € € €? ° € ¸ € kk € PS 3 : 모델러 버전 1101322에 의해 생성 된 파일 전송 SCH_900000_9008 @ Ź @ -A233 ™ ž B¤ ˙˙˙˙˙˙˙˙˙˙˙˙ '˙ rtSdpeRB ˙ GÚS)

그리고 이것을 추출해야합니다 :

A233

팁 :-기호 앞에 공백이 있습니다 (-A233). 또한 모든 파일의 문자 A 옆에 다른 번호가 있습니다.

원본 파일에서 다음과 같이 보입니다 (복사 붙여 넣기를 통해 많은 공간이 추출 됨).

다음과 함께 바꾸기 (ctrl-h)를 사용할 수 있습니다.

무엇을 찾다: .*? -(A\d+)

다음으로 교체하십시오. \1\n

파일에 ".와 일치하는 개행"상자가 있는지 확인하십시오.

설명:

.*? - -줄 바꿈을 포함하여 "-"까지의 모든 항목을 찾습니다.

(A\d+) -A 다음에 1 개 이상의 숫자가 나오는 캡처 그룹을 정의합니다.

\1\n -일치하는 번호를 캡처 한 번호와 줄 바꾸기로 대체

당신 \n은 당신이 선택한 구분 기호로 바꿀 수 있습니다

마지막 일치 이후의 텍스트는 삭제되지 않지만 이미 텍스트 편집기에 있으므로 삭제하는 것이 간단합니다.

.txt 파일이 많이 있으므로 각 파일에서 수동으로 값을 추출하는 대신 간단한 자동화를 수행하는 것이 좋습니다. 아래에서 WSH VBScript를 사용하는 것이 좋습니다.

strRes = ""
For Each strPath In WScript.Arguments
    With CreateObject("Scripting.FileSystemObject")
        If .FileExists(strPath) Then
            strRes = strRes & .GetFileName(strPath) & vbCrLf
            strCont = LoadTextFromFile(strPath, "us-ascii")
            With CreateObject("VBScript.RegExp")
                .Global = True
                .MultiLine = True
                .IgnoreCase = False
                .Pattern = "-A(\d{3})"
                Set objMatches = .Execute(strCont)
                For Each objMatch In objMatches
                    strRes = strRes & objMatch.SubMatches(0) & vbCrLf
                Next
            End With
        End If
    End With
Next
ShowInNotepad strRes

Function LoadTextFromFile(strPath, strCharset)
    With CreateObject("ADODB.Stream")
        .Type = 1 ' TypeBinary
        .Open
        .LoadFromFile strPath
        .Position = 0
        .Type = 2 ' adTypeText
        .Charset = strCharset
        LoadTextFromFile = .ReadText
        .Close
    End With
End Function

Sub ShowInNotepad(strToFile)
    Dim strTempPath
    With CreateObject("Scripting.FileSystemObject")
        strTempPath = CreateObject("WScript.Shell").ExpandEnvironmentStrings("%TEMP%") & "\" & .GetTempName
        With .CreateTextFile(strTempPath, True, True)
            .WriteLine strToFile
            .Close
        End With
        CreateObject("WScript.Shell").Run "notepad.exe " & strTempPath, 1, True
        .DeleteFile (strTempPath)
    End With
End Sub

이 코드를 메모장에 붙여 넣고 텍스트 파일로 저장 한 다음 .txt파일 확장자를 수동으로 바꾸십시오 .vbs. 그런 다음 탐색기 창에서 텍스트 파일을 선택하고 스크립트로 끌어다 놓기 만하면됩니다.

공유 한 파일의 경우 다음과 같이 출력됩니다.

30_SCH51BQ139.txt

036

30_SCH51BQ141.txt

038

30_SCH51BQ144.txt

040

30_SCH51BQ147.txt

043