Windows 배치, 다른 지역 설정, 디렉토리 이름 바꾸기 YYYYmmDD_HHmmSS

두 컴퓨터의 날짜 및 시간 :

10/25/2017 3:36:05 a.m. __ on Windows 7  
2017-10-25 03:07:23 ______ on Windows XP  

국가 별 설정이 변경되면 출력을 표준 날짜 시간 형식 으로 자동화 하기 위해
권장되는 유틸리티 프로그램 및
배치 파일 명령은 무엇입니까? (디렉토리 R : \ 1 이름 변경)

ren R:\1 R:\20171025_021459

R:\yyyyMMdd_HHmmss  
R:\20171025_021459  

지역 설정을 무시하는 표준 날짜 시간 형식을 얻으려면 어떻게해야합니까?

다음 배치 파일을 사용하십시오 (의 로컬 시간 출력을 구문 분석하는 올바른 방법 wmic임).

@echo off
setlocal
rem use findstr to strip blank lines from wmic output
for /f "usebackq skip=1 tokens=1-6" %%g in (`wmic Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year ^| findstr /r /v "^$"`) do (
  set _day=00%%g
  set _hours=00%%h
  set _minutes=00%%i
  set _month=00%%j
  set _seconds=00%%k
  set _year=%%l
  )
rem pad with leading zeros
set _month=%_month:~-2%
set _day=%_day:~-2%
set _hh=%_hours:~-2%
set _mm=%_minutes:~-2%
set _ss=%_seconds:~-2%
rem use YYYYmmDD_HHmmSS format for the timestamp
set _stamp=%_year%%_month%%_day%_%_hh%%_mm%%_ss%
ren R:\1 %_stamp%
endlocal

추가 자료

• Windows CMD 명령 행의 AZ 색인 -Windows cmd 행과 관련된 모든 것에 대한 훌륭한 참조 자료.
• for / f- 다른 명령의 결과에 대한 루프 명령.
• getdate -OS 로케일, 언어 또는 사용자가 선택한 날짜 형식 (제어판 / 지역)에 관계없이 날짜 및 시간을 표시합니다.
• 변수 - 변수의 일부를 추출합니다 (하위 문자열).
• wmic -Windows 관리 인스 트루먼 테이션 명령.

이것은 당신이 구체적으로하고 싶은 일을하는 짧은 방법입니다. 내 업무 라인에서 서비스 수준 계약은 왕이되어 얼마나 사소한 지에 관계없이 일반적으로 사용하는 처리 시간을 줄입니다.

@echo off
REM Get date and time in YYYYMMDDhhmmss format
for /f "tokens=2 delims==." %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
rem put underscore in the middle of date and time stamp
ren R:\1 %dt:~0,8%_%dt:~8,6%