Windows 7에서 Outlook 일정 알림을 최신 상태로 유지하는 방법

방금 Windows 7을 사용하기 시작했으며 Outlook 알림을 표시하고 눈에 잘 띄게 표시하는 방법을 알고 싶습니다. 작업 표시 줄의 Outlook 스택에있는 또 다른 창처럼 신중하게 계속 열립니다. 결과적으로, 나는 그것들이 다른 모든 것 뒤에 튀어 나오므로 계속 간과합니다.

간과하기 쉽지 않은 방법은 무엇입니까?

(분명히, 자신을 최전선으로 몰아 넣는 독창적 인 앱은 원하지 않습니다. 그러나 그러한 행동이 바람직한 곳이 몇 개 있으며 Outlook 일정 알림이 그 중 하나입니다.)

Outlook 2010에서도 같은 문제가있었습니다. 아래 언급 된 단계를 사용하면 매력처럼 작동합니다. 모든 매크로를 활성화하는 것을 잊지 마십시오 : 보안 센터> 매크로 설정.

• 나중에 디지털 인증서 생성 : 시작을 누르고 '인증서'를 입력 한 다음 'VBA 프로젝트의 디지털 인증서'를 선택하십시오.
• 인증서 이름을 입력하십시오. 확인을 클릭하십시오. Outlook을 열고 Alt+ F11를 눌러 VBA 편집기를 시작하십시오.
• 왼쪽의 트리에서 'Microsoft Office Outlook Objects'를 펼치고 'ThisOutlookSession'을 두 번 클릭하십시오.

• 이 코드에 붙여 넣기 :

  Private Declare PtrSafe Function FindWindowA Lib "user32" _
  (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
  
  Private Declare PtrSafe Function SetWindowPos Lib "user32" ( _
  ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
  ByVal X As Long, ByVal Y As Long, ByVal cx As Long, _
  ByVal cy As Long, ByVal wFlags As Long) As Long
  
  Private Const SWP_NOSIZE = &H1
  Private Const SWP_NOMOVE = &H2
  Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
  Private Const HWND_TOPMOST = -1
  
  Private Sub Application_Reminder(ByVal Item As Object)
  Dim ReminderWindowHWnd As Variant
  On Error Resume Next
  ReminderWindowHWnd = FindWindowA(vbNullString, "1 Reminder")
  SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
  
  End Sub
  

• 도구> 디지털 서명 ...이 실행되도록 매크로에 서명하고 앞에서 만든 인증서를 선택하십시오.

• VBA 창을 닫습니다
• 파일> 옵션> 보안 센터> 보안 센터 설정> 매크로 설정에서 모든 매크로를 사용하십시오.

이 문제를 해결하기 위해 AutoHotKey를 사용할 수도 있습니다. 이 스크립트는 포커스를 훔치지 않고 미리 알림 창을 표시합니다 (Win10 / Outlook 2013에서 테스트).

TrayTip Script, Looking for Reminder window to put on top, , 16
SetTitleMatchMode  2 ; windows contains
loop {
  WinWait, Reminder(s), 
  WinSet, AlwaysOnTop, on, Reminder(s)
  WinRestore, Reminder(s)
  TrayTip Outlook Reminder, You have an outlook reminder open, , 16
  WinWaitClose, Reminder(s), ,30
}

AHK 스크립트 - 컴파일 된 EXE

내가 찾은 가장 좋은 대답은 다음과 같습니다 . 간단한 VBA를 사용하여 Outlook 약속 미리 알림을 다른 창 앞에 다시 표시하는 방법.

"ThisOutlookSession"에 간단한 VBA 코드 몇 줄을 추가해야합니다. 이제 매번 창이 나타납니다. 훨씬 낫다.

• 나중에 디지털 인증서 생성
• 시작을 누르고 '인증서'를 입력하고 'VBA 프로젝트의 디지털 인증서'를 선택하십시오.
• 인증서 이름을 입력하십시오
• 끝난
• Outlook을 열고 Alt + F11을 눌러 VBA 편집기를 시작하십시오.
• 왼쪽의 트리에서 'Microsoft Office Outlook Objects'를 펼치고 'ThisOutlookSession'을 두 번 클릭하십시오.

• 이 코드에 붙여 넣어 원하는대로 텍스트를 따옴표로 수정하십시오. 따옴표는 그대로 두십시오.

  Private Sub Application_Reminder(ByVal Item As Object)
  
  
      If TypeOf Item Is AppointmentItem Then
      MsgBox "Message text", vbSystemModal, "Message title"
      End If
  
  
  End Sub
  

• 도구> 디지털 서명…으로 이동하여 앞에서 만든 인증서를 선택하여 매크로가 실행되도록 매크로에 서명하십시오.

• VBA 창을 닫습니다

버전 1803 (2018 년 2 월)부터 "다른 창 위에 알림 표시"옵션을 사용할 수 있습니다. 기본적으로 활성화되어 있지 않습니다.

방법이 없다. 우리 회사는 Microsoft에 직접 이관하려고했습니다. 사람들이 여기에서하는 한 가지는 더 눈에 잘 띄지 않게하는 소리입니다. 그러나 Microsoft는 의도적으로 설계된 것이라고 말했습니다.

위의 Gullu의 anwer와 동일하지만 다른 창 제목을 수용하도록 변경되었습니다.

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

'// TO ACCOUNT FOR WINDOW TITLE CHANGING WITH NOTIFICATION COUNT:
Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    'On Error Resume Next
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder(s)"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

이것은 나도 나를 괴롭혔다. 몇 가지 강렬한 검색 후 부분 답변을 찾았습니다 : http://www.pcreview.co.uk/forums/hidden-outlook-reminders-t3972914.html

"작업 표시 줄 및 시작 메뉴 속성"에서 "작업 표시 줄 단추"설정을 "절대로 결합하지 않음"으로 변경하면 그룹이 분리되고 열려있는 다른 항목 앞에 미리 알림이 나타납니다.

나는 그것을 시험하려고했고 그것이 일관성이 없다는 것을 알았다. 한 번은 내가 작업했던 내용 뒤에 숨겨져 있었고, 또 한 번은 갑자기 나타났습니다. 두 경우 모두 작업 표시 줄에 Outlook과 다른 모양의 아이콘이 있었으므로 적어도 눈에 띄게 될 가능성이있었습니다.

Filebox eXtender를 사용 했는데 첫 번째 알림이 들어 오면이를 열고 캡션 표시 줄의 오른쪽 상단에있는 새로운 '핀'아이콘을 클릭합니다. 그런 다음 다음 알림이 오면 포 그라운드로 들어옵니다.

미리 알림 창을 맨 위로 가져 오는 ShowReminders ( http://www.sagelamp.com/pages/showreminders.aspx ) 라는 추가 기능을 찾았습니다 . 미리 알림 창을 최소화 한 경우에도 작동합니다.

마침내 Outlook VBA와 간단한 EXE를 사용하는 간단한 솔루션을 찾습니다.

다음은 회의 약속을 다시 놓치지 않는 방법입니다.

이 목적을 위해 왜 독립형 exe 응용 프로그램입니까? 글쎄, VBA에 큰 빨간색 상자가 포함되어 있지만 그 솔루션에는 문제가 가득했습니다 (큰 빨간색 상자를 맨 위에 유지하려면 hwnd 및 기타 비정상적인 시스템 속성을 사용해야하기 때문입니다). 따라서 한 가지 일을하는 기본 EXE가 아닌 이유를 간단하게 만들 수 있습니다. Microsoft의 무료 도구를 사용할 수 있습니다 (Visual Studio Community 2015는 무료).

이것은 EXE 코드입니다. 하나의 양식으로 간단한 창 양식 응용 프로그램. 이 코드를 컴파일하십시오.

Imports System.Timers
Public Class Form1
    Dim tTimer As New Timer
    Public Sub New()
        InitializeComponent()
        Me.StartPosition = Windows.Forms.FormStartPosition.CenterScreen
        Me.TopMost = True
        Me.TopLevel = True
    End Sub
    Private Sub Form1_DoubleClick(sender As Object, e As EventArgs) Handles Me.DoubleClick
        Application.Exit()
    End Sub 
    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
        flashingQuick()
    End Sub
    Sub flashingQuick()
        tTimer.Start()
        AddHandler tTimer.Elapsed, New ElapsedEventHandler(AddressOf TimerTick)
    End Sub
    Sub TimerTick(ByVal source As [Object], ByVal e As ElapsedEventArgs)
        Dim theTimer As System.Timers.Timer = DirectCast(source, System.Timers.Timer)
        theTimer.Interval = 500
        theTimer.Enabled = True
        If Me.BackColor = System.Drawing.SystemColors.Control Then
            Me.BackColor = Color.Red
        Else
            Me.BackColor = System.Drawing.SystemColors.Control
        End If
    End Sub
End Class

그리고 이것이 VBA 전망에 필요한 전부입니다. 이것을 ThisOutlookSession에 넣으십시오

Private Sub Application_Reminder(ByVal Item As Object)
    On Error Resume Next
    If Item.MessageClass <> "IPM.Appointment" Then
      Exit Sub
    End If
    Dim sAPPData As String
    Dim sFileName As String
    sAPPData = Environ("AppData")
    sFileName = "\Microsoft\Windows\Start Menu\Programs\BigRedBox\BigRedBox.exe"
    If Dir(sAPPData & sFileName) <> "" Then
        Call Shell(sAPPData & sFileName)
    End If
End Sub

이것은 독일어 버전에서 작동 하는 향상된 tbone의 답변 버전입니다.

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Private Declare PtrSafe Function BringWindowToTop Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hwnd As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop (ReminderWindowHWnd)
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung(en)")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop ReminderWindowHWnd
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

독일어 창 제목과 몇 가지 새로운 기능 ( BringWindowToTop, SetForegroundWindow및 SetFocus)을 추가했습니다.

독일어 Windows 10에서 Outlook 2016과 함께 작동합니다.

나는 않았다 없는 새 인증서를 (시작을 눌러 "인증서"를 입력 아무것도 보이지 않았다) 생성, 관리, 그러나 서명 할 때 단순히 목록에서 다른 인증서를 선택했습니다.