명령 줄에서 Internet Explorer를 기본 브라우저로 설정할 수 있습니까?

Internet Explorer에서만 실행되는 웹 응용 프로그램이 있지만 Firefox가 기본 브라우저 인 경우 작동하지 않습니다. 사용자는 도메인 환경에 있으며 다음과 같은 방식으로 일괄 처리에서 응용 프로그램을 시작하려고하더라도 다음과 같습니다.

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

브라우저를 수동으로 변경하지 않으면 응용 프로그램이 시작되지 않습니다.

이 명령은 IE를 기본 브라우저로 설정합니다.

shmgrate.exe OcinstallreinstallIE

이 정책 은 사람들이 기본 브라우저를 결정하지 못하게해야합니다.

당신은 이것을 시도 할 수 있습니다, 그것은 작동합니다

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

명령의 오류 start는 처음 인용 된 문자열이 응용 프로그램의 제목이 될 것으로 예상 했기 때문에이 경우 비워 둘 수 있습니다.

iexplorer.exe시스템의 기본 웹 브라우저로 설정하기 위해 확장명을 파일 형식과 연결하고 파일 형식을 실행 파일과 연결하는 명령 assoc과 ftype명령을 사용할 수 있습니다 .

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1 여기서 인수입니다. 즉, 입력으로 프로그램에 보낼 수있는 URL 또는 파일입니다.

Windows Vista 이상, IE 7 이상

다음 배치 스크립트 는 기본 프로그램 제어판 애플릿 에서이 프로그램을 기본값으로 설정을 클릭하여 시뮬레이션 합니다. Vista / 7 및 IE 7 / IE 11에서 테스트되었습니다.

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)

pause
exit /b

비고

모든 웹 브라우저 응용 프로그램은 시작 메뉴에 인터넷 클라이언트로 나타나도록 등록 할 수 있습니다. 이 가시성은 응용 프로그램의 파일 및 프로토콜 유형에 대한 올바른 등록과 함께 응용 프로그램 기본 브라우저 상태를 제공합니다. 기본 웹 브라우저는 시스템 어디에서나 임의의 URL을 시작하는 데 사용됩니다.

참고 기존 [시작 메뉴 링크] 등록은 Windows 7 이상에서 무시됩니다. 이 등록은 Windows 7부터 더 이상 사용되지 않습니다.

_{출처 : Windows 시작 메뉴를 사용하여 인터넷 브라우저 또는 이메일 클라이언트를 등록하는 방법}

­­

파일 및 프로토콜 연결을위한 계층 적 레지스트리 구조는 컴퓨터 수준 기본값보다 사용자 별 기본값보다 우선합니다.

_{출처 : 기본 프로그램}

박쥐 파일에 두 줄 아래를 추가 할 수 있습니다

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

bat를 실행 한 후 위의 두 명령 행은 레지스트리 값을 변경하기 때문에 재부팅 / 로그 오프 및 다시 로그하십시오.

Aditinal 세부 사항은 여기에서 찾을 수 있습니다

(Fixed) -Cant가 Internet Explorer를 기본 브라우저로 설정! http://www.windowstechinfo.com/2016/03/fixed-cant-set-internet-explorer-as-the-default-browser.html

명령 줄에서 기본 브라우저를 설정하는 방법을 모르지만 그룹 정책을 통해 도메인에 대해 브라우저를 설정하고 시행 할 수 있습니다.

시작하는 것이 다음과 같습니다.

http://technet.microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

그냥 드롭 start작업에 대한 명령이나 배치 파일을 얻을 수 있습니다.

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

Windows 8 (IE 10+)의 경우 쉬운 VBS 스크립트가 있습니다.

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

IE를 기본값으로 변경하기위한 IE 페이지를 시작하고 수락 버튼을 클릭하여 시뮬레이션합니다.