Windows가 업데이트를 강제로 확인하도록하려면 어떻게합니까?

XP 또는 7을 새로 설치 한 후 Windows 업데이트를 어떻게 "강제"할 수 있습니까?

일주일 후에 "오래된"Windows 업데이트를 원하지 않으므로 "한 단계"로 수행 할 수 있습니까? Windows가 업데이트를 확인하도록 강제하는 "매직"명령이 있습니까? 있다면 업데이트를 설치하십시오.

스크립트를 사용하여 업데이트를 자동으로 확인하고 설치할 수 있습니다. 이것은 XP 또는 Windows 7에서 작동합니다.

다운로드 할 수있는 스크립트의 숫자가 있습니다, 여기 내입니다 :

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain.  It may be freely
' used, modified, and distributed.  However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
'   0 = scripting failure
'   1 = error obtaining or installing updates
'   2 = installation successful, no further updates to install
'   3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete.  Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop 

다음과 같이 명령 행에서이를 실행하십시오.

cscript wsusupdate.vbs

내 스크립트는 최소한의 기능이지만 여전히 유용 할 수 있습니다. 많은 추가 기능을 갖춘 다른 스크립트가 있습니다. Google 검색을 시도하십시오.

일반적인 Windows Update 사용 방법 외에도 명령 줄에서 강제로 확인할 수 있습니다.

관리자 명령 프롬프트를 열고 다음을 실행하십시오.

C:\> %windir%\system32\wuauclt.exe /detectnow

Wuauclt.exe는 Windows Update의 자동 업데이트 클라이언트이며 Microsoft Update에서 사용 가능한 업데이트 (다양한 버전의 MS Windows 플랫폼 용)를 확인하는 데 사용됩니다.

이것은 강제로 설치되지 않습니다.

업데이트를 확인하려면 제어판, 보안, Windows Update로 이동 한 다음 "업데이트 확인"을 클릭하십시오.

업데이트를 강제로 다시 검색하는 다른 방법은 % windir % \ Windows \ SoftwareDistribution \ Download에 저장된 모든 업데이트를 삭제하여 슬레이트를 깨끗하게 정리하는 것입니다 .

    NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

그런 다음 Windows Update로 이동하여 "업데이트 확인"으로 이동하십시오. 시스템 볼륨의 모든 업데이트 가능한 파일이 검사되기 때문에 1 시간이 걸릴 수 있습니다 (이후 "업데이트 확인"은 빠릅니다). 이 접근 방식은 오류를 제거하고 업데이트를 중단하며 최소한 MS가 보는 한 깨끗하고 최신 시스템을 제공합니다.

새로운 Windows 설치를 업데이트하기 위해 wuinstall 이라는 타사 도구를 사용하고 있습니다. 이를 통해 자동 재부팅을 포함한 전체 업데이트 프로세스를 자동화 할 수 있습니다. 사용자 참석없이 새로운 창을 최신으로 유지할 수있는 가장 빠른 방법 중 하나라고 생각합니다.

Windows 7에서 새로 설치하는 과정에서 IE를 업그레이드했거나 IE를 아직 실행하지 않고 소개 질문에 대답 한 경우 Windows Update에서 오류가 발생합니다. 또한 GUI를 거치지 않고 Windows Update를 Microsoft Update로 전환하는 방법을 찾지 못했기 때문에 IE를 수동으로 시작하고 초기화 한 다음 GUI를 통해 Windows Update를 설정하므로 Microsoft Update로 전환하여 초기 오류. 귀하의 마일리지가 다를 수 있습니다.

IE8 & WI4.5 를 설치 하여이 게시물 의 단계를 성공적으로 수행하면 자동 업데이트가 트리거되어 다운로드를 시작합니다.