Windows 7에서 notepad.exe 교체

좋아, 정말로 Windows 7의 기본 notepad.exe를 Editpad로 바꾸고 싶습니다 (예, 실제 실행 파일을 바꾸고 싶지 않습니다. 아니라 Notepad2와 같은 것을 사용하고 싶지 않으므로 제안하지 마십시오) . 전에 저에게 도움이 된 다음 배치 스크립트를 사용했습니다.

@echo off
TITLE EditPad Install Script for Complete Windows Vista and 7 Notepad Replacement
echo.
echo EditPad Install Script for Complete Windows Vista and 7 Notepad Replacement
echo Version 2.0
echo.
echo Confirm to apply? (Press Ctrl-C and answer Y to terminate)
pause
echo.
echo.

if exist %SystemRoot%\notepad.original.exe goto exist_editpad_already
if exist %SystemRoot%\System32\notepad.original.exe goto exist_editpad_already
takeown /f %SystemRoot%\notepad.exe
takeown /f %SystemRoot%\System32\notepad.exe
icacls %SystemRoot%\notepad.exe /grant "%USERNAME%":f
icacls %SystemRoot%\System32\notepad.exe /grant "%USERNAME%":f
IF EXIST %SystemRoot%\SysWOW64 (bcdedit.exe -set loadoptions "DDISABLE_INTEGRITY_CHECKS")
copy %SystemRoot%\notepad.exe %SystemRoot%\notepad.original.exe
copy %SystemRoot%\System32\notepad.exe %SystemRoot%\System32\notepad.original.exe
echo.
echo Original notepad.exe has been renamed to "notepad.original.exe" in its original folder.
echo.
echo Overwriting %SystemRoot%\notepad.exe with "%~dp0\EditPad.exe"
copy "%~dp0\EditPad.exe" %SystemRoot%\notepad.exe /y
echo Overwriting %SystemRoot%\System32\notepad.exe with "%~dp0\EditPad.exe"
copy "%~dp0\EditPad.exe" %SystemRoot%\System32\notepad.exe /y
echo.
echo EditPad installation is completed.
echo If no error occurred, EditPad will now replace all Notepad functions.
echo.
pause
goto eof

:exist_editpad_already
echo.
echo INSTALLED EditPad ALREADY! (notepad.original.exe exists in windows or windows system32)
echo.
pause
goto eof

:eof

이 스크립트는 notepad.exe를 Editpad 실행 파일로 대체했지만 이제 텍스트 파일을 열려고하면 "NOTEPAD.EXE 복사본이 손상된 것 같습니다. 오류가 발생합니다. 원래 설치 패키지에서 다시 설치하십시오. "

Windows 7 64 비트를 사용하고 있습니다. 이 바보 같은 오류 메시지를 표시하지 않고 Windows에서 Editpad를 notepad.exe로 사용하도록하려면 어떻게해야합니까?

업데이트 :
약간 도움이 될만한 정보가 더 있다고 생각합니다. 문제 는 system32 디렉토리 내부 에서 editpad.exe 를 실행하는 것으로 보입니다 . 다른 exe 파일을 다른 파일로 대체해도 system32\notepad.exe제대로 실행되지만 editpad.exe해당 디렉토리 내 에서 실행하려고하면 Windows 7에서 "게시자를 확인할 수 없습니다.이 소프트웨어를 실행 하시겠습니까?"라는 팝업 대화 상자가 나타납니다. 실행을 클릭하면 '파일이 손상되었습니다'오류가 발생하지만 system32 디렉토리 내에서 파일을 실행하는 경우에만 해당됩니다. system32 디렉토리 에서이 exe를 실행하는 방법을 찾아야합니다.

내 생각은 EditPad를 올바르게 실행하기 위해 Image File Execution 레지스트리 항목을 피기 백 할 수있는 서포터 응용 프로그램을 만드는 것입니다.

참고 : 나타나는 오류 메시지 나 변경 내용을 취소 하여 원래 Windows 메모장을 먼저 복원해야합니다 . 그렇지 않으면 Windows는 무엇을 시도하든 오류 메시지가 계속 표시 될 수 있습니다.

팁 : Dracs에서 제안한 메모장 교체 프로그램 은 아래에있는 것과 비슷한 작업을 자동으로 수행 합니다. 응용 프로그램이 닫힌 소스 와 같이 피해야 할 이유가없는 한 먼저 시도하십시오 . 이 경우 아래 방법을 사용할 수 있습니다.

1. 다음 코드를 사용하여 배치 파일을 작성하십시오. 배치 파일의 이름은 Replacer.bat 일 수 있으며 EditPad의 설치 폴더와 같은 곳에 배치 할 수 있습니다. 주어진 경로에 EditPad가 설치되어 있다고 가정합니다. 그렇지 않으면 변경하십시오.

   SET NotepadTempVar=%*
   IF DEFINED NotepadTempVar SET NotepadTempVar=%NotepadTempVar:"C:\Windows\System32\notepad.exe"=%
   IF DEFINED NotepadTempVar SET NotepadTempVar=%NotepadTempVar:"C:\Windows\notepad.exe"=%
   IF DEFINED NotepadTempVar (
       FOR /F "tokens=*" %%A IN ("%NotepadTempVar%") DO SET NotepadTempVar=%%A
   )
   IF DEFINED NotepadTempVar (
       START "" "C:\Program Files\EditPad\EditPad.exe" "%NotepadTempVar%"
   ) ELSE (
       START "" "C:\Program Files\EditPad\EditPad.exe"
   )
   

   • 주의! ""START 명령 뒤에 빈 문자열이 있어야합니다 . 그렇지 않으면 시스템이 새 명령 프롬프트 창 을 작성하는 무한 루프로 들어갈 수 있습니다 .
   • 시스템을 반영하기 위해 두 번째 및 세 번째 줄에서 원래 메모장 의 경로를 확인해야 할 수도 있습니다 . 32 비트 및 64 비트 Windows에서 경로가 동일하다는 것을 알았습니다. 경로는 대소 문자를 구분하지 않지만 따옴표를 묶는 데주의하십시오.

   • 64 비트 Windows에서는 두 번째 및 세 번째 행 사이 에이 추가 행 을 추가해야합니다 .

     IF DEFINED NotepadTempVar SET NotepadTempVar=%NotepadTempVar:"C:\Windows\SysWOW64\notepad.exe"=%
     

     
     

2. (선택 사항) 사용 의 exe 변환기에 배치를 실행 프로그램에 배치 파일을 컴파일 할 수 있습니다. "보이지 않는 응용 프로그램"옵션을 선택하십시오.

   • Batch To Exe Converter 를 사용하지 않으 려면 다른 솔루션을 사용하거나 컴파일 된 EXE파일 대신 다음 단계에 배치 파일 자체를 사용할 수 있습니다 . 그러나 배치 파일 자체를 사용하는 경우 EditPad가 열리기 전에 명령 창이 일시적으로 깜박입니다.
     
     

3. 열기 레지스트리 편집기를 시작 메뉴를 열고 검색하여 regedit(또는 실행하는 실행 명령을 사용하여 regedit).

4. 로 이동 HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options

5. 라는 이름의 키 (왼쪽 창에서 폴더) 경우 notepad.exe내부에 존재하지 않는 Image File Execution Options, 클릭 편집> 새로 만들기> 키 입력 notepad.exe새 키의 이름을. 이미 존재하는 경우 간단히 탐색하십시오.

6. 라는 항목 경우 Debugger(유형 REG_SZ)가 존재하지 않습니다 notepad.exe(오른쪽) 키를 클릭 편집> 새로 만들기> 문자열 값을 입력 Debugger새 항목의 이름으로.

7. 이름이 지정된 항목을 두 번 클릭하고 Batch To Exe Converter에서Debugger 생성 한 EXE 파일 또는 컴파일러를 사용하지 않은 경우 배치 파일 의 완전한 위치와 이름을 입력하십시오 . 위치를 따옴표로 묶습니다.

   • 예를 들어, 배치 파일을 EditPad의 프로그램 폴더에 저장했다고 가정하면 Debugger 항목의 값은 "C:\Program Files\EditPad\Replacer.bat" 또는 "C:\Program Files\EditPad\Replacer.exe" Replacer.bat는 배치 파일이고 Replacer.exe는 2 단계에서 얻은 컴파일 된 EXE 파일입니다 (있는 경우) .
     
     

8. 다음을 수행하여 설정을 테스트하십시오.

   • 시작 메뉴에서 Windows 메모장을 엽니 다. 대신 EditPad가 열립니다.
   • 텍스트 파일 또는 Windows 메모장과 관련된 파일을 두 번 클릭하십시오.
   • 다른 테스트는 일반적으로 Windows 메모장을 열어야한다는 것을 의미합니다. 대신 EditPad를 열 것입니다.

문제가 있으면 1 단계에서 만든 배치 파일의 경로가 올바르지 않을 수 있습니다. 올바르게 수행 한 경우 다른 모든 단계는 문제없이 정상이어야합니다. 배치 파일의 경로를 확인하고 수정하십시오 (필요한 경우 EXE를 다시 컴파일하십시오).

Image File Execution Options 레지스트리 키를 사용하십시오 .

• regedit.exe관리자로 엽니 다 .
• 로 이동 HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options
• 이름이 지정된 새 키 (폴더)를 만듭니다. notepad.exe
• REG_SZ이름이 지정된 새 값을 작성하고 Debugger해당 값을 Editpad.exe실행 파일 경로로 설정하십시오 .

끝난. 시스템을 수정하거나 제거 할 필요는 없지만 notepad.exe프로그램이 프로그램을 어떻게 실행하려고하더라도 (탐색기에서 직접 프로그램을 두 번 클릭하면) EditPad가 실행됩니다.

64 비트 Windows를 사용 중이고 32 비트 프로그램을 사용하려는 경우 HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows NT\ CurrentVersion\Image File Execution Options대신 변경하십시오 . (이 정보는 Notepad2-Windows 메모장 교체 페이지에 있습니다.)

메모장 대체 도구를 사용하여 컴퓨터 에서이 작업을 수행했습니다 . 실제로 파일을 대체하지는 않지만 선택한 프로그램을 사용하기 위해 메모장에서 수행 한 작업을 수행합니다. 메모장을 설치 한 후 원래 메모장을 보지 못했습니다. 제거는 모든 것을 쉽게 되돌릴 수 있습니다.

notepad.exe 파일을 교체해야 %WINDIR%\winsxs\Backup하지만 이것도 제대로 작동하지 않을 수 있습니다 . 이는 Windows Resource Protection 과 관련이 있습니다 .

관리자 모드에서 배치 파일을 실행하기 만하면됩니다.

1. 배치 파일을 마우스 오른쪽 버튼으로 클릭하십시오.
2. "관리자 권한으로 실행"을 선택하십시오.
3. 설치 진행

이미이 스크립트를 이미 실행 한 적이 있다면 즉시 작동하지 않으므로 % SystemRoot % 및 % SystemRoot % \ System32에서 notepad.original.exe를 삭제해야합니다.

rm %SystemRoot%\notepad.original.exe
rm %SystemRoot%\System32\notepad.original.exe

또한 관리자 모드에서이를 실행해야하므로 위의 행을 파일로 복사하고 위의 원래 배치 파일과 동일한 지시 사항을 수행하십시오.

당신은 썼다 :

이 스크립트는 notepad.exe를 Editpad 실행 파일로 대체했지만 이제 텍스트 파일을 열려고하면 "NOTEPAD.EXE 복사본이 손상된 것 같습니다. 오류가 발생합니다. 원래 설치 패키지에서 다시 설치하십시오. "

notepad.exe 는 Windows 보호 파일 이므로 교체가 약간 까다 롭습니다.

HowTo Geek 웹 사이트 의 수동 솔루션은 다음과 같습니다 . Windows 7에서 메모장을 바꾸는 방법

http://www.howtogeek.com/howto/12617/how-to-replace-notepad-in-windows-7/

다른 옵션은 다음 스위치와 함께 배치 파일에서 Sysinternals 명령 줄 유틸리티 PsExec 을 사용하는 것 입니다.

...PsExec.exe" -i -d -s...

PsExec : http://technet.microsoft.com/en-us/sysinternals/bb897553

이 도움을 바랍니다. 알려주세요.