모든 Powerpoint 슬라이드의 언어를 한 번에 변경하려면 어떻게합니까?

이 스레드는 꽤 오래되었지만 Microsoft는 내가 아는 솔루션을 제공하지 않았습니다. Mac 사용자에게는 Keynote에서 프레젠테이션을 열고, 맞춤법 언어를 변경하고, 전체 프레젠테이션을 편집 한 다음 PowerPoint로 내보내는 또 다른 방법을 제안합니다.

전체 PowerPoint 의 언어를 쉽게 변경하려면 보기 탭을 열고 개요 보기를 선택하십시오 .

이제

• Ctrl+ A모두 선택합니다.
• 도구 → 언어 → 설정할 언어를 선택하십시오.

마찬가지로 모든 항목을 선택한 상태에서 글꼴, 색상 등과 같은 다른 항목을 변경할 수 있습니다. 물론 많은 경우에 슬라이드 마스터를 변경하면이 작업을 수행하는 것이 좋습니다. 많은 편집자가있는 프레젠테이션에는 많은 '하드'서식 설정이있을 수 있습니다. 기본 마스터에서 벗어나 일관성을 유지하기 위해 재설정해야합니다. 개별 슬라이드를 마스터 스타일로 재설정 할 수도 있지만이 경우 자리 표시 자도 함께 움직일 수 있으며 일부 상황에서는 바람직하지 않을 수 있습니다.

PowerPoint 2013

• 보기 → 개요 → Ctrl+ 를 통해 모든 슬라이드 (왼쪽 메뉴에서)를 선택하십시오 A.
• 검토 → 언어 → 언어 교정 설정 ... → 설정할 언어를 선택하십시오.

나에 관해서는-PowerPoint를 다시 시작 해야했습니다. 아마 편집 언어를 변경했기 때문에 :

• 검토 → 언어 → 언어 교정 설정 ... → 언어 기본 설정 → 언어 편집을 선택합니다 .

Powerpoint 2010을 사용 하여 개요 메뉴를 열었습니다.

모든 텍스트를 선택하고 (Ctrl + A) 언어 메뉴를 열고 교정 언어를 설정하십시오.

그리고 효과가있었습니다!

언어 메뉴는 검토 리본 탭 (슬라이드 쇼 탭 뒤의 스크린 샷에는 표시되지 않음)에 있습니다.

기존 답변은 개요에있는 텍스트에 적용됩니다. 불행히도 필자의 경우 이것은 그림, 표 등 텍스트의 중요한 부분을 다루지 않았습니다.

이 매크로는 나를 위해 문제를 해결했습니다.

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

위의 매크로에서 사용되는 "msoLanguageIDEnglishUS"는 원하는 언어로 바꿀 수 있습니다. 언어의 전체 목록은 이 기사 에서 찾을 수 있습니다

(크레디트는 여기에 원래 매크로를 게시 한 Ganesh Kumar에게갑니다 . 모양 그룹화의 첫 번째 수준에 대한 지원을 추가했습니다. 매크로를 더 향상시키기 위해 매크로를 재귀 적으로 만들어 다른 그룹 등을 포함하는 그룹을 찾을 수 있습니다.)

모든 항목을 원하는 언어로 변경하는 재귀 버전을 제공하기 위해 Inigo의 답변 을 개선했습니다 .

이 버전은 그룹 유형 인 각 셰이프를 재귀 적으로 조사합니다. 일부 실험은을 제시 msoGroup하고 msoSmartArt그룹 종류 - 텍스트 객체를 저장할 수있는 형태의 다른 유형을 발견하면 그 목록에 추가 부담을.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Inigo, Duncan, Maria 및 DomDev의 답변을 바탕으로 현재와 미래의 도형, 테이블, 그룹, SmartArt에 적용됩니다.

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Duncan 버전은 테이블 이외의 모든 작업에 적합합니다. https://stackoverflow.com/questions/4735765/powerpoint-2007-set-language-on-tables-charts-etc-that-contains-text 와 함께 작동하는 것으로 보이는 다른 코드를 발견했습니다.

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

Mastergalen이 제공 한 답변 외에도 새로 입력 한 텍스트에 대한 의견을 제시 할 수 있습니다.

알다시피, 새 텍스트를 입력하기 시작할 때마다 언어가 자동으로 변경됩니다 (매우 성가시다). PowerPoint의 현재 기본 언어를 변경해야합니다.

• PowerPoint 창이 활성 창인지 확인하십시오
• 의 Windows Taskbar경우 (예, 실제로하지 파워 포인트), 체크 Language bar표시,
  • 그렇지 않으면 Control Panel > Region and Language > Keyboards and Languages. 를 클릭 Change keybords...하고 Language bar탭으로 전환하여 Docked in the taskbar옵션을 확인하십시오 . (이것은 Win7에서 왔으므로 다른 버전에서는 약간 다를 수 있습니다).
• 이제 주요 작업- Language bar작업 표시 줄에서 언어 코드를 클릭하고 EN으로 전환하십시오 (현재 PowerPoint에서 영어를 사용하려는 경우). 이제부터 PowerPoint의 모든 새 텍스트는 선택한 언어로 표시됩니다.
• 원래 언어로 쓰려면 다시 바꾸십시오.

PowerPoint 2016에서 여전히 잘 작동하는 2014 년에 추가 기능을 다시 만들었습니다. https://github.com/wobba/officeaddin/releases/tag/v1.0.1

사용 된 언어를 검색하고 한 번에 모두 변경하여 반복 할 수 있습니다.