명령 행에서 맵핑 된 네트워크 드라이브를 다시 연결할 수 있습니까?

매일 매일 Windows 명령 프롬프트에서 매핑되었지만 연결이 끊어진 네트워크 드라이브에 액세스해야합니다. 매핑 해제 및 다시 매핑하지 않고이 드라이브를 다시 연결하는 명령을 아직 찾지 못했습니다 (이 컴퓨터를 소유하지 않기 때문에 암호 추측 게임으로 이어짐). 또한 매일 밤마다 드라이브 연결이 끊어지면 드라이브가 다시 연결되도록 스크립트를 작성하고 싶습니다.

현재 가장 빠른 솔루션은 다음과 같습니다.

1. " start."를 입력 하여 탐색기를 열고
2. Alt- D주소 표시 줄에 초점을 맞추려면
3. 원하는 드라이브 문자를 입력하고 Enter 키를 누른 다음 드라이브 내용이 표시 될 때까지 기다립니다.
4. 마지막으로 탐색기를 닫고 명령 프롬프트로 돌아갑니다.

약간의 불편 함을 알고 있지만 GUI를 통해 무언가를하는 것이 끔찍한 느린 VNC 또는 PCAnywhere 연결을 통해이 작업을 수행하는 경우가 많으므로 더 나은 솔루션이 있는지 궁금합니다.

어쩌면 시도 pushd \\server\share?

회사 네트워크 드라이브에 연결하는 VPN 프로그램을 실행하려면 Windows 7을 시작해야합니다. 따라서 내 네트워크 드라이브는 자동으로 다시 연결되지 않으며 Windows 탐색기에서 열면 다시 연결됩니다.

VPN을 시작하고 네트워크 드라이브를 다시 연결하며 항상 사용하는 일부 응용 프로그램을 시작하기 위해 작은 배치 파일을 만들었습니다.

내 배치 파일에는 다음이 있습니다.

REM Connect VPN here...

REM Opens an Explorer window looking at T: forcing a reconnect
Start /min explorer t:\

timeout 3 /nobreak

REM Kill all Explorer windows beginning with "T_drive" in the title
Taskkill /fi "windowtitle eq T_drive*"

REM Finish starting up here...

exit

Taskkill /fi "windowtitle eq"명령은 대소 문자를 구분합니다!

다음 명령을 사용하여 배치 파일 (refreshletters.cmd)을 만듭니다.

( 이것은 배치 파일 내에서만 작동합니다 )

콘솔 창 (명령 줄)에서 'Disconnected'및 'Unavailable'드라이버 문자를 새로 고치기 위해 Win7 및 XP에서 테스트되었습니다.

@echo off
net use |FIND ":" > %temp%\used.txt
FOR /F " tokens=1,2,3 delims= " %%i in (%temp%\used.txt) do (

  if %%i EQU Unavailable  (
    net use %%j %%k
    echo Activated %%j
   ) ELSE (
     if %%i EQU Disconnected (
       pushd .
       cd /d %%j
       dir . %>nul
       if NOT exist %%j\. (
          net use %%j /del /y
          net use %%j %%k
          echo Remapped %%j
          ) else (
             echo Fixed-up %%j
            )
       popd
       ) ELSE (
          echo Checked %%j
          )
     )
 )

이것은 아마도 어리석은 질문이지만 "연결이 끊어진"드라이브가 H :라고 가정하면 드라이브로 직접 변경해 보셨습니까?

XPSP3에서 저에게 효과적입니다.

C:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
Disconnected H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.


C:\>h:

H:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
OK           H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.

나는 당신이 "net use"가 당신을 위해 효과가 없다고 말한 것을 알고있다. 그러나 여기 당신이 시도 할 수있는 것이있다.

net use / DELETE 옵션을 사용하여 배치 파일을 실행하여 기존 / 지속적 연결을 제거한 다음 / SAVECRED 옵션과 함께 net use를 사용하여 마지막으로 성공적인 로그온시 사용한 암호를 다시 사용할 수 있습니다. 이것이 귀하의 문제를 해결할지 확실하지 않지만 조사 할 가치가 있습니다.

여러 연결에 동일한 문제가 있으며 간헐적입니다. 컴퓨터를 재부팅 할 때 연결이 "좋은"상태가되고 때로는 연결되지 않는 경우가 있습니다. 회사 LAN을 사용하고 있기 때문에 암호 문제가 없지만 여전히 다른 문제가 있습니다.

ex.bat라는 배치 파일을 만들고 경로에 넣은 \ util 디렉토리에 다른 많은 것들과 함께 저장했습니다. "ex h :"를 입력하면 Windows 탐색기가 실행되고 h : 드라이브로 직접 이동하도록 설정됩니다. 배치 파일은 다음과 같습니다.

start explorer /e,/select,%1

키 입력 횟수가 훨씬 적습니다. 또는 처음에 작동하지 않으면 Enter 키를 눌러 h : 루트 폴더를 열고 내용을 표시하십시오. 또는 하위 폴더 "sub"가 존재하는 곳에 "ex h : \ sub"를 입력하십시오.

이 문제는 Windows XP 보안 패치 중 하나로 인해 최근에 훨씬 더 나빠진 것 같습니다.

또 다른 시도는 서버 측입니다. Windows 서버에서 레지스트리 키를 수정하면 제한 시간에 서버의 연결이 끊어지지 않습니다. 나는 거의 모든 서버 에서이 작업을 수행합니다. 파일은 다음과 같습니다

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]
"autodisconnect"=dword:ffffffff

비슷한 문제가 발생하여 명령 줄에서 간단한 "dir x :"(X :는 매핑되었지만 연결이 끊어진 드라이브 임)로 다시 연결할 수 있다는 것을 알았습니다. 이것은 Server 2003 시스템에서 XP 및 Win7의 매핑 된 드라이브까지였습니다. 컴퓨터.

다음 두 줄로 배치 파일 wake_network_drives.bat를 만들었습니다.

    dir x:
    dir z:

드라이브가 때때로 연결이 끊어진 것으로 표시되어 실패한 백업 프로그램 전에 밤새 실행되도록 예약 된 작업을 설정하십시오.

그냥 입력하십시오 :

NET USE H: \\server\share

(여기서 H :는 드라이브 문자입니다)

'NET /?를 입력하십시오. 이 명령이 제공하는 모든 옵션을 보려면 USE '를 누르십시오.

이러한 비밀번호를 일반 텍스트로 일괄 처리하지 않으려면 자격 증명을 포함하여 삭제 및 다시 매핑을 스크립팅 할 수 있습니다.

net use H: /delete
net use H: \\server\share /user:domain\user password /persistent:yes

공유를 삭제하지 않아야한다는 요구 사항을 충족시키지 못하지만 암호를 기억 해야하는 문제의 근본을 해결합니다.

TL; DR 요약 : 사용 net use및if exist

야간 백업 스크립트를 만드는 동안 관련 문제가 발생했습니다. 컴퓨터가 켜져 있는지 (ping 사용) 확인하고, 필요한 경우 마법 패킷을 보내서 ( MC-WOL 사용 ), Windows가 부팅 될 때까지 기다린 다음 SMB 공유에 연결하고 기다립니다. 존재합니다.

여기에 다른 답변이 훌륭하지만 매핑 된 드라이브 문자가 나타나거나 존재하지 않거나 사용자가 작업중 인 항목의 연결을 끊거나 탐색기 창이 깜박이지 않게하고 싶지 않았습니다. 즉 목표는 사용자의 방해 가 전혀없는 것 입니다.

다음은 도움이 될만한 코드입니다.

set TARGET_IP=192.168.1.3
set TARGET_PATH=\\%TARGET_IP%\d$\backups
set ATTEMPTS=0

:LOOP

REM Give up eventually
if %ATTEMPTS% GEQ 200 goto NOJOY

REM Wait for IP connectivity to host, and/or burn up a couple seconds before retry
ping -n 1 -w 2000 %TARGET_IP% | find "TTL" > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

REM See if we're already connected, and try to give it a kick
if exist %TARGET_PATH% goto CONNECTED

REM Try to reconnect
net use %TARGET_PATH% > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

:CONNECTED
echo Connected
exit /b

:NOJOY
echo Couldn't connect

원하는 경우 위의 IP 주소를 호스트 이름 (예 :)으로 바꿀 수 있습니다 server1.

net use기존 연결이없는 경우 필요합니다. 나는 혼자서 공유를 "깨우는"것이 충분하지 않은 것처럼 보이는 일부 코너 사례에 부딪쳤다. 나는 발견 if exists지시어는 다른 답변 (같은에서 언급 한 대안과 유사한 효과를 pushd, dir, Explorer, 등),하지만 가벼운 무게 접근 방식을 보였다.

StanZ의 답변이 저에게 도움이되었지만 도메인의 사용자가 다른 드라이브 매핑을 얻을 때 상태가 OK 인 매핑 된 드라이브를 프로그래밍 방식으로 결정할 수 있어야했습니다. 여기서는 net use실제 코드 전후에 실행되는 독립형 버전으로 실행 되도록 코드를 작성 했으므로 결과를 볼 수 있지만 FOR원하는 결과를 얻으려면 코드에 한 명령문 (3 줄) 만 복사하면 됩니다.

@ECHO OFF
::  
:: revision of answer from StanZ on superuser.com at the following url  
:: https://superuser.com/questions/52595/can-a-mapped-network-drive-be-reconnected-from-the-command-line/367910#367910  
:: https://superuser.com/a/367910  
:: which resulted in my  
::  
:: DriveStatusOK.bat  
:: iCharlieC  
::  
SETLOCAL ENABLEEXTENSIONS  
::  
:: you need only copy the one FOR statement (three lines)  
::   to use in your own code  
::   to force status of mapped network drives to OK  
::  
:: "tokens=1-2 delims=: " is used in the for statement  
:: to output only the drive letter from the output of...  
:: net use  
:: is piped to the first findstr which outputs only lines with drive letters  
::   then piped to another findstr to eliminate drives with a status of OK  
::   then piped to another findstr to get lines that start with a status  
::     -in other words, those lines that the first character is a letter-  
::     -this due to the fact that in our domain we have a drive  
::      that is mapped to a letter, but never has a status.  
::      I do not know the reason for this,  
::      but adding that last findstr prevents me from getting an error  
::      from trying to execute a dir on a non-existant drive letter.-  
::   then dir is executed on each drive letter (after appending ":\" to the letter)  
::      and the output redirected to NUL  
::  
:: run net use before as a visual here  
net use  
::  
FOR /F "tokens=1-2 delims=: " %%i in (  
    'net use ^| findstr ":" ^| findstr /i /v "^OK" ^| findstr /i "^[A-Z]"'  
    ) do dir "%%j:" > NUL  
::  
:: run net use after "waking" drive(s)  
net use  
::  
ENDLOCAL  

네트워크 공유가 종종 다른 이유로 창에 의해 다시 연결되거나 연결되지 않기 때문에 오래된 질문이지만 2017 및 Windows 10에서 여전히 관련이 있습니다. 이 문제와 실용적이고 완전한 실제 솔루션이 없음을 기반으로 스케줄러 작업과 VBS가 포함 된 Github 프로젝트를 만들었습니다.

스크립트는 전체 구성이 가능하며 실제 사용자의 요구에 따라 설정할 수 있습니다.

Github 프로젝트의 경로