새 버전이 출시 될 때마다 Flash Player를 자동으로 업데이트하려면 어떻게해야합니까?

요약:

Flash Player 업데이트 서비스는 안정적인 일정에 따라 실행되지 않으며 업데이트 가 실행될 때 자동으로 다운로드하여 적용하지 않습니다 .

최신 버전의 Flash Player를 설치해야한다는 점을 감안할 때 (내장 플레이어와 함께 Chrome을 사용하지 않는 사용자를 위해) 새로운 업데이트를 신속하게 감지 할 수있는 방법을 찾고 싶습니다 설치되었습니다.

이 문제를 스스로 해결하려는 노력의 세부 사항은 다음과 같습니다.

부록 A : Flash Player 업데이트 서비스

OK, 플래시 플레이어 11.2의 방법으로 다시는 (정도?) 어도비는 플래시 플레이어 업데이트 서비스 (FlashPlayerUpdateService.exe이)가 된 추가 되어 플래시 플레이어 업데이트 유지하기 위해 ...

• 설치시 FPUS는 시작 유형이 수동으로 설정된 Windows 서비스로 실행되도록 구성됩니다.

• 매 시간마다이 서비스를 시작하기 위해 예약 된 작업 (Adobe Flash Player Updater.job)이 추가되었습니다.

지금까지는 양호했습니다.이 설정은 지속적으로 실행되는 서비스를 피할 수 있지만 업데이트를 신속하게 포착 할 수있을 정도로 검사가 자주 실행되도록합니다. 구글의 소프트웨어 업데이트 프로그램은 비슷한 방식으로 구성되며, 그 잘 작동합니다 ...

...하지만 설치된 Flash Player의 버전을 확인한 결과 11.6.602.180 인데 파일의 타임 스탬프를 살펴본 결과 3 월 12 일 화요일C:\Windows\System32\Macromed\Flash 에 마지막으로 업데이트 (또는 설치) 된 것으로 나타 났습니다 . 2013 년 --- 3/12/13, 5:00:08 pm .

2013 년 4 월 25 일 목요일 --- 4/25/13, 7:00:00 pm 에이 관찰을 수행했으며 Adobe 웹 사이트 를 확인한 결과 현재 Flash Player의 버전이 11.7.700.169임을 알았습니다 .

마지막 업데이트 이후 한 달이 지났는데, 웹 사이트에서 새로운 것을 볼 수 있지만 내 컴퓨터 에서 매시간 실행되는 검사 가 그것을 보았 거나 다운로드 할 의사가 있음을 나타내지 않았습니다.

부록 B : Flash Player 업데이터 수동 실행

옛날에는 실행 하면 설치 버튼 이있는 창이 나타납니다 . 이 버튼을 누르면 현재 버전의 설치 프로그램이 자동으로 브라우저를 열지 않고 다운로드되어 실행됩니다. 그런 다음 해당 설치 프로그램을 클릭하여 완료합니다. 수동이지만 작동했습니다! 현재 설치가 최신 상태가 아닌 것을 발견하면 (부록 A 참조) 먼저이 수동 업데이트 프로세스를 시도했습니다. 하나...FlashUtil32_<version>_Plugin.exe -update plugin

• 실행 (의 것을, 내 경우에는 그 다운로드 버튼을 클릭 ... 만 다운로드 버튼이있는 창을 제공하는) URL로 브라우저가 열립니다 https://get3.adobe.com/flashplayer/update/activex을 .FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• 실행 (의 것을, 내 경우에는 그 다운로드 버튼을 클릭 ... 만 다운로드 버튼이있는 창을 제공하는) URL로 브라우저가 열립니다 https://get3.adobe.com/flashplayer/update/plugin을 .FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

내가 할 수 foistware 상자 ( "! 무료 맥아피 보안 스캔 플러스")의 선택을 취소, 그것은 나를 보낸 다운로드 페이지를 계속 다운로드가 설치 (액티브, 아니 foistware : install_flashplayer11x32axau_mssd_aih.exe, 플러그인, 아니 foistware : install_flashplayer11x32au_mssd_aih.exe) 아마도 업데이트 된 Flash가 있을 수 있지만 다른 exe를 수동으로 다운로드하여 실행해야하는 경우 Flash Player 업데이트 서비스의 요점은 무엇 입니까?

발문

그 이후로 업데이트 서비스가 얼리 어답터를 수동 다운로드 페이지로 몰아 넣는 데 의도적으로 어려움을 겪고 있다고 생각했습니다. 이것이 사실이라면 아마도 내 자신의 업데이터를 작성하는 짧은 해결책이 없을 것입니다. 잘만되면 나는 틀렸다.

아마도 업데이터는 11.6.x 범위의 업데이트 만 적용합니까?

당신은 항상 내가 더 신뢰할 수있는 찾아 설치, 직접 링크를 사용할 수 있습니다 액티브 X를 ; 플러그인 .

이 .bat 파일을 사용하면 Internet Explorer, Firefox (SeaMonkey 등), Chromium 기반 (Chrome, Opera 15+ 등) 용 플래시 플레이어 를 자동으로 업데이트하거나 설치합니다 .

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

필요한 wget은 여기에서 다운로드 할 수 있으며 .bat가있는 동일한 디렉토리에 저장해야합니다.

Autoit으로 작성된 좀 더 진보 된 예제 .

특징 : 여기에 새로운 버전이 없다면 다운로드 플래시 플레이어 설치 프로그램없이 프로그램을 종료하십시오. 다운로드 설치 관리자가 실패하면 오류 메시지 상자를 표시하고 종료하십시오. 숨겨진 명령 프롬프트 창. wget이 필요하지 않습니다.

Autoit 및 Editor 설치 후 . 데스크탑-> 새로 만들기-> 자동 스크립트를 마우스 오른쪽 버튼으로 클릭하십시오. 생성 된 파일-> 편집을 마우스 오른쪽 버튼으로 클릭하십시오. 이제 ScITE 창이 표시되고 "아래에 코드를 추가하십시오"행 뒤에이 코드를 추가하십시오.

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

그런 다음 SciTE 창에서 Tools-> Build를 누르거나 F7을 누르십시오. 이제 Autoit 스크립트가있는 동일한 디렉토리에 독립형 실행 파일이 제공됩니다.

이 "업데이터"에 대해 새 폴더 (쓰기 권한이있는)를 만드는 것이 좋습니다. 이 "업데이트"에 바로 가기를 추가하여 시작할 수도 있습니다.

여기에 제거 플래시 플레이어 응용 프로그램.

그냥 배치 스크립트를 당신과 공유하고 싶습니다.이 코드를 메모장에 저장하고 이름을 Download_Install_Last_Flash_Player.bat 로 지정 하십시오.

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************