Ubuntu의 시스템 버퍼에서 키보드 단축키 복사 및 붙여 넣기를 위해 VIM을 구성 하시겠습니까?

어떻게 사용하는 VIM을 구성해야합니까 Ctrl- c복사 및 Ctrl- v우분투 시스템 버퍼에서 붙여?

MS Windows의 기본 동작 :-

mswin.vim 파일에서 발췌 한 내용은 다음과 같습니다.

" CTRL-X and SHIFT-Del are Cut
vnoremap <C-X> "+x
vnoremap <S-Del> "+x

" CTRL-C and CTRL-Insert are Copy
vnoremap <C-C> "+y
vnoremap <C-Insert> "+y

" CTRL-V and SHIFT-Insert are Paste
map <C-V>       "+gP
map <S-Insert>      "+gP

cmap <C-V>      <C-R>+
cmap <S-Insert>     <C-R>+

" Pasting blockwise and linewise selections is not possible in Insert and
" Visual mode without the +virtualedit feature.  They are pasted as if they
" were characterwise instead.
" Uses the paste.vim autoload script.

exe 'inoremap <script> <C-V>' paste#paste_cmd['i']
exe 'vnoremap <script> <C-V>' paste#paste_cmd['v']

imap <S-Insert>     <C-V>
vmap <S-Insert>     <C-V>

" Use CTRL-Q to do what CTRL-V used to do
noremap <C-Q>       <C-V>

그리고 블록 모드 잘라 내기 / 붙여 넣기에 필요한 paste.vim 스크립트 :-

    " Vim support file to help with paste mappings and menus
" Maintainer:   Bram Moolenaar <Bram@vim.org>
" Last Change:  2006 Jun 23

" Define the string to use for items that are present both in Edit, Popup and
" Toolbar menu.  Also used in mswin.vim and macmap.vim.

" Pasting blockwise and linewise selections is not possible in Insert and
" Visual mode without the +virtualedit feature.  They are pasted as if they
" were characterwise instead.  Add to that some tricks to leave the cursor in
" the right position, also for "gi".
if has("virtualedit")
  let paste#paste_cmd = {'n': ":call paste#Paste()<CR>"}
  let paste#paste_cmd['v'] = '"-c<Esc>' . paste#paste_cmd['n']
  let paste#paste_cmd['i'] = 'x<BS><Esc>' . paste#paste_cmd['n'] . 'gi'

  func! paste#Paste()
    let ove = &ve
    set ve=all
    normal! `^
    if @+ != ''
      normal! "+gP
    endif
    let c = col(".")
    normal! i
    if col(".") < c " compensate for i<ESC> moving the cursor left
      normal! l
    endif
    let &ve = ove
  endfunc
else
  let paste#paste_cmd = {'n': "\"=@+.'xy'<CR>gPFx\"_2x"}
  let paste#paste_cmd['v'] = '"-c<Esc>gix<Esc>' . paste#paste_cmd['n'] . '"_x'
  let paste#paste_cmd['i'] = 'x<Esc>' . paste#paste_cmd['n'] . '"_s'
endi

대부분의 항목이 기본 설정이라고 가정하면 이는 최소한입니다 ** :

:behave mswin
:set clipboard=unnamedplus
:smap <Del> <C-g>"_d
:smap <C-c> <C-g>y
:smap <C-x> <C-g>x
:imap <C-v> <Esc>pi
:smap <C-v> <C-g>p
:smap <Tab> <C-g>1> 
:smap <S-Tab> <C-g>1<

• 1 행 : Shift + 화살표가 텍스트를 선택하게하고 더 많이 수행합니다 *

• 2 행 : "+ (및"*)를 기본 레지스터 (gui / term 클립 보드)로 설정

• 3,4,5,6 행 : Ctrl-x / c / v 잘라 내기 / 복사 및 붙여 넣기

• 7,8 행 : Tab / SHIFT + TAB 들여 쓰기 / 들여 쓰기 선택

주의 : *** [: set] tings는이 동작을 변경시킬 수 있으며, 내가 말한 것처럼 최소한의 조정이 필요에 따라 많은 조정이 필요할 수 있습니다. * [: behave]는 많은 [: set] tings가 문서를 읽도록 변경합니다.

Ctrl-V를 맵핑하여 시스템 클립 보드를 잡고 레지스터에 던져서 커서 아래 화면에 붙여 넣는 시스템 명령을 실행하십시오.

vmap <C-c> y:call system("xclip -i -selection clipboard", getreg("\""))<CR>:call system("xclip -i", getreg("\""))<CR>
nmap <C-v> :call setreg("\"",system("xclip -o -selection clipboard"))<CR>p

출처 : http://vim.wikia.com/wiki/In_line_copy_and_paste_to_system_clipboard