셀에 정보가있는 경우 IF 및 ISBLANK 문을 사용하여 셀 범위 판별

10

셀 범위가 비어 있는지 확인하는 수식이 있습니다.

그들 모두가 비어 있다면 나는 또 다른 공백을 반환하고 싶습니다.

범위의 셀 중 하나라도 비어 있지 않으면 value 반환하고 싶습니다 Major Milestone Due.

내가 현재 가지고있는 공식은 다음과 같습니다.

=IF(ISBLANK(BM2:BQ2),"","Major Milestone Due")

Major Milestone Due모든 빈 셀에 특정 행 범위가 있어도 모든 것을로 반환 합니다.

microsoft-excel

— 히스
소스

16

COUNTA비어 있지 않은 범위의 셀 수를 제공합니다 .

시도해보십시오 ...

 =IF(NOT(COUNTA(BM2:BQ2)),"","Major Milestone Due")

— jcfollower
소스

기본 공식 : NOT (COUNTA (BM2 : BQ2))은 AND (COUNTA (BN2), NOT (COUNTA (BM2 : BQ2)))

— Rhak Kahr

9

배열 수식으로 입력 한 경우 수식이 정확합니다 .

를 isblank사용하여 배열 수식으로 입력하지 않으면 배열 작동하지 않습니다 ctrl+ shift+ enter. 주위에 중괄호를 사용하여 다음과 같이 표시됩니다.

{=IF(ISBLANK(BM2:BQ2),"","Major Milestone Due")}

또한 if-counta는이 문제를 수행하지 않습니다.

=IF(COUNTA(BM2:BQ2)=0,"","Major Milestone Due")

— 레이스 타파 리아
소스

배열 수식이 정확하지 않습니다. 이 버전은에서 이동합니다 TRUE에 FALSE범위의 첫 번째 셀에 값이 포함되어있는 경우. 범위 내의 모든 셀을 올바르게 확인하려면 AND추가해야합니다. –{=IF(AND(ISBLANK(BM2:BQ2)),"","Major Milestone Due")}

— Marcus Hughes

@MarcusHughes 왜 그럴까요? 그것은의 배열 수식 및 전체 배열에서 작동

— Raystafarian

내가 모르는 이유를 정확히의를,하지만 난 그것을 테스트 (엑셀 2010)과는 작동하지 않는다 ISBLANK. 해당 수식을 입력하고 범위의 첫 번째 셀을 비운 다음 범위의 이후 셀에 데이터를 입력하십시오. ISBLANK조건은 여전히을 반환 TRUE합니다. 첫 번째 셀에 데이터를 입력 한 경우에만 FALSE올바르게 반환 됩니다. 이제를 추가하십시오 AND. 범위의 셀에 데이터가 추가되면 원하는대로 반환 FALSE됩니다. (나는 이것이 2010 년에 단지 몇 가지 이상한 우연하지 않습니다 있으리라 믿고있어)

— 마커스 휴즈

2

고려해야 할 중요한 사항은 "공백"에 대한 정의입니다. "다른 공백을 반환하고 싶습니다"라는 문구를 사용한 사실에 따르면, "빈"을 공백으로 표시 되는 셀로 정의 하고 있지만 실제로는 출력 ""되지 않으므로 비어 있지 않은 수식이 포함될 수 있습니다. .

이 두 수식은 실제로 빈 셀을 찾기 때문에 이러한 종류의 셀을 공백으로 처리하려는 경우 COUNTA및 ISBLANK메소드가 작동하지 않습니다 . 출력되는 수식을 처리하기 위해 다음 두 가지 옵션이 있습니다.""

범위의 크기를 항상 알고 있다면 다음 중 하나를 사용할 수 있습니다.

=IF( COUNTBLANK(BM2:BQ2)=5, "", "Major Milestone Due")
=IF( COUNTIF(BM2:BQ2,"")=5, "", "Major Milestone Due")

여기서 5 는 범위의 크기입니다. 이 방법은 다이나믹 레인지에서는 작동하지 않습니다.

약간 더 복잡한 수식 (적어도 설명하기가 더 복잡합니다!)은 SUMPRODUCT다음을 사용합니다 .

=IF( SUMPRODUCT(--(BM2:BQ2<>""))=0, "", "Major Milestone Due")

( COUNTIF(BM2:BQ2,"<>")와 동일한 문제가 있음에 유의하십시오 COUNTA.)

— 마커스 휴즈
소스

-1

나는 거의 동일한 질문에 대한 답을 찾기 위해이 페이지에 도착했다.

그것이 COUNTA언급 된 것을 보았을 때 , 나는 무엇을해야하는지 거의 즉시 알았습니다. 약간 다른 컨텍스트 not started에서 동일한 행의 모든 셀이 비어있는 경우 열 왼쪽에 열 범위가 있습니다 (공백).

다음 공식이 저에게 효과적입니다.

=IF(COUNTA(P3:U3)=0,"Not Started"...)

줄임표는 IF내 수식에 여러 가지 추가 기능 이 있음을 나타내며 , 하나 이상의 항목이 채워지면 범위에서 추가 테스트를 수행합니다.

— 데이비드 에이 그레이
소스

슈퍼 유저에 오신 것을 환영합니다. 귀하의 답변이 공감대에 끌 렸습니다. 아마도 우리는 복제를 피하려고 노력하기 때문입니다. 각 답변은 이미 제공 한 내용과 실질적으로 다른 솔루션을 제공하기위한 것입니다. 이것은 본질적으로 Raystafarian의 대답의 두 번째 부분을 복제합니다.

— fixer1234

내 대답은 의견으로 던져졌어야합니다.

— David A. Grey