어쨌든이 둘을 확실히 구별 할 수 있습니까?

시작 화면에서 작업 표시 줄이나 전원 단추를 찾을 수 있다는 것을 알았지 만 실제로 8.1 업데이트 1을 표시하는 곳이 있는지 알고 싶습니다. MS가 알고있는 것은 이 페이지 그러나 최신 ISO에서 업데이트가 슬립 스트림으로 처리되는 것처럼 특히 프로그램 방식으로이를 감지하는 방법이 유용 할 것입니다.

내가 알 수있는 한, ver 과 wmic os Windows 8.1과 Windows 8.1간에 동일합니다. 업데이트 1, 시스템 등록 정보에서 여전히 Windows 8.1을보고합니다.

가능한 해결책

아래에 운영 체제가 Windows 8.1인지 여부를 확인할 수있는 일괄 스크립트가 있습니다 KB2919355 . 종료 코드는 다음 중 하나입니다.

• 0: Windows 8.1
• 1: Windows 8.1 업데이트 (KB2919355 설치)
• 2: Windows 8.1이 아닙니다.

배치 스크립트 A - 업데이트 확인

이것은 가장 신뢰할 수있는 방법입니다. 스크립트는 먼저 운영 체제가 Windows 8.1인지 여부를 버전과 6.3.9600. 그런 다음 KB2919355 업데이트가 이미 설치되었는지 확인하기 위해 설치된 모든 업데이트를 쿼리합니다.

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

wmic qfe get hotfixid | findstr /i /c:"KB2919355" >nul
set /a errorlevel=%errorlevel% ^^ 1

exit /b %errorlevel%

배치 스크립트 B - 빌드 버전 확인

대안으로 모든 업데이트를 열거 할 필요가 없기 때문에 첫 번째 스크립트보다 빠른 Windows 빌드 버전을 확인할 수 있습니다. 레지스트리 값을 사용하므로 안정성이 떨어질 수 있습니다.

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

for /f "tokens=4 delims=. " %%G in (
'"reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "BuildLabEx" | findstr /i /c:"REG_SZ" "'
) do set /a build=%%~G

if %build% geq 17031 exit /b 1
exit /b 0

배치 스크립트 C - 빌드 버전 확인 (Internet Explorer)

이전 스크립트와 마찬가지로 여기에서는 Internet Explorer (IE) 버전이 확인된다는 점을 제외하고는 개념이 비슷합니다.

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

for /f "tokens=3,6 delims=. " %%G in (
'"reg query "HKLM\SOFTWARE\Microsoft\Internet Explorer" /v "svcVersion" | findstr /i /c:"REG_SZ" "'
) do set /a major=%%~G & set /a build=%%~H

if %major% equ 11 if %build% geq 17031 exit /b 1
if %major% geq 12 exit /b 1
exit /b 0

노트 스크립트는 KB2919355 업데이트가 설치된 Windows 8.1 시스템에서 12 이상의 모든 IE 버전을 사용할 수 있다고 가정합니다.

Windows RT 8.1, Windows 8.1 및 Windows Server 2012 R2의 향후 보안 및 비보안 업데이트는 모두이 업데이트를 설치해야합니다. 향후 업데이트를 계속 받으려면 Windows RT 8.1, Windows 8.1 또는 Windows Server 2012 R2 기반 컴퓨터에이 업데이트를 설치하는 것이 좋습니다.

_{출처: Windows RT 8.1, Windows 8.1 및 Windows Server 2012 R2 업데이트 : 2014 년 4 월}

위의 내용을 감안할 때 최신 IE 버전이 업데이트를 전제 조건으로 요구한다고 생각하는 것이 합리적입니다. Windows Vista에 IE 9를 설치하려면 SP2가 필요합니다. .

파싱하기 BuildLabEx 끈

reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" | findstr BuildLabEx

그 수가 더 큰 경우 17031 사용자에게는 업데이트 1이 설치되어 있습니다.

WuInstall이라는 명령 줄 유틸리티를 사용합니다 ( http://www.wuinstall.com ) 패치 스크립트를 사용하면 업데이트가 설치되었는지 확인할 수 있습니다.

설치된 모든 업데이트를 표시하는 명령 줄

WUInstall.exe / search / criteria "IsInstalled = 1"/ 오프라인

특정 KB가 설치되어 있는지 확인하려면 (많은 필터링 옵션이 있음) 다음을 확인하십시오.

WUInstall.exe / search / criteria "IsInstalled = 1"/ 오프라인 / 일치 "KB982214"

이 유틸리티는 / xmlout이라는 옵션을 사용하여 xml 파일로 리다이렉트하거나 예를 들어 파일로 리디렉션 할 수있는 몇 가지 명령 행 출력을 수행합니다. & gt; out.txt

Windows의 모든 버전에서 눈에 띄는 차이가 있다는 것을 눈치 챘을 때 Windows에서 "winstore"폴더를 확인하기 만하면됩니다.

WinStore 명령을 실행하여 실행할 수도 있습니다.

REM 시뮬레이션 OS 검사 : 설치 기음: CD\ 존재하는 경우 "c : \ windows \ WinStore"goto WIN8

: Win8 win8 시스템의 REM 특정 코드