이동식 드라이브에서 Windows 7이 휴지통을 사용하지 않도록하려면 어떻게합니까?

이동식 드라이브에서 Windows 7이 휴지통을 사용하지 않도록하려면 어떻게합니까? 이미 Windows에 해당 드라이브의 기능을 사용하지 말라고 지시했지만 Windows는 여전히 "휴지통"폴더를 만듭니다. 그것은 비어 있지만 나는 거기에서 그것을 원하지 않습니다. 단순히 숨기지 않습니다. 카 스테레오에서 이동식 드라이브를 사용하고 있으며 "재활용 된"폴더가 컴퓨터를 잠급니다.

휴지통은 시스템 디렉토리이며 어쨌든 만들어집니다. 레지스트리 해킹이있을 수 있지만 OS를 복원하거나 핫픽스를 설치하면 재설정 될 수 있으므로 귀찮게하지 마십시오.

휴지통을 보지 않으려면 다음을 수행하십시오.

1. "폴더 및 검색 옵션"에서 운영 체제 파일을 숨 깁니다.

   

2. 삭제 된 파일이 휴지통에 복사되지 않도록하십시오 (오른쪽 클릭).

   

3. 데스크탑을 개인화하여 휴지통을 숨기십시오.

   

그러나 Windows는 여전히 "휴지통"폴더를 만듭니다.

피하기는 매우 쉽습니다.

폴더를 삭제하고 메모장을 연 다음 해당 $Recycle.Bin드라이브의 루트 디렉토리에서 와 같이 빈 파일을 저장하십시오 . 이제 Windows는 폴더를 작성할 수 없습니다.

이 드라이브에서 휴지통을 다시 사용하려면 파일을 삭제하십시오.

Clonezilla와 같은 Linux 디스크에 드라이브를 마운트하고 섹터별로 복사하십시오. 그렇게하면 원본이 아닌 엉망이되는 사본이 있습니다. 각 드라이브에서 숨겨진 휴지통 폴더를 만드는 기본 Windows 프로세스를 중지 할 수는 없지만 Puppy Linux와 같은 많은 Linux 시스템은 드라이브를 쓰지 않으면 쓰기 작업으로 드라이브를 만지지 않습니다.

편집 : 내 나쁜 다른 게시물에 응답했다. 그러나 Puppy Linux 디스크로 Windows 시스템을 부팅하는 경우 외부 드라이브를 삽입하면 원하지 않는 파일을 드라이브에 쓰지 않고도 리사이클 러를 삭제하고 mp3를 드라이브로 옮길 수 있습니다. 그런 다음 mp3 드라이브를 제거하고, 강아지 디스크를 제거한 다음, 번거 로움없이 Windows로 재부팅 할 수 있습니다. 숨겨진 재활용 파일이 드라이브에 던져지는 것을 막는 실제 방법을 모르겠지만 해결 방법이 있습니다.

"이동식 드라이브에서 Windows 7이 휴지통을 사용하지 않도록하려면 어떻게합니까?"

시작하거나 로그인 할 때 다음 스크립트를 실행하십시오.

소스 Windows 7 : $ recycle.bin 폴더 생성을 비활성화 하시겠습니까? :

그렇습니다. 할 수 없다는 것에 화가 났기 때문에 스크립트를 작성했습니다 (아래 참조). 그것은 나를 위해 작동하지만 문제가있는 경우 조금 조정해야 할 수도 있습니다.

' Author:      HSV Guy
' Description: Script to remove Recycle Bin folder. Run on Windows startup or login.
' Notes: 1)    See http://www.sevenforums.com/tutorials/11949-elevated-program-shortcut-without-uac-prompt-create.html
'              for how to run programs/scripts with elevated permissions without a UAC prompt.
'        2)    Update value of RECYCLEBIN as per version of Windows (configured for Windows 7).
' Date:        1 April 2011

Dim SILENT
SILENT = TRUE

Call RunElevated

Dim filesys, drv, drvcoll, folder, RECYCLEBIN
RECYCLEBIN = ":\$Recycle.Bin\"

Set filesys = CreateObject("Scripting.FileSystemObject")
Set drvcoll = filesys.Drives


For Each drv in drvcoll
  If drv.IsReady And filesys.FolderExists(drv.DriveLetter & RECYCLEBIN)  Then
     Set folder = filesys.GetFolder(drv.DriveLetter & RECYCLEBIN)
     MyMsgBox "About to delete: " & folder
     folder.Delete
  Else
    MyMsgBox "Skipped " & drv.DriveLetter & ". Folder doesn't exist or device not ready."
  End If  
Next

'Source code of RunElevated function shamelessly taken from:
' http://www.insidethe.com/blog/2009/12/how-to-launch-a-wsh-vbscript-as-administrator-in-windows-7-and-vista/
Function RunElevated
    If WScript.Arguments.Named.Exists("elevated") = False Then
        'Launch the script again as administrator
        CreateObject("Shell.Application").ShellExecute "wscript.exe", """" & WScript.ScriptFullName & """ /elevated", "", "runas", 1
        WScript.Quit
    Else
        'Change the working directory from the system32 folder back to the script's folder.
        Set oShell = CreateObject("WScript.Shell")
        oShell.CurrentDirectory = CreateObject("Scripting.FileSystemObject").GetParentFolderName(WScript.ScriptFullName)
         MyMsgBox "Now running with elevated permissions" & SILENT
    End If
End Function

Function MyMsgBox(Message)
    If Not SILENT Then MsgBox Message
End Function

탐색기의 경우 사용자 구성 / 관리 템플릿 / Windows 구성 요소 / Windows 탐색기에 "삭제 된 파일을 휴지통으로 이동하지 마십시오"라는 해당 그룹 정책이있는 것 같습니다 . Windows 탐색기 또는 전체 시스템에서만 작동하는지 확실하지 않습니다.