해당 월의 일요일 수 계산

8

Microsoft Excel에서 주어진 달의 일요일 수를 결정하려고합니다. 예산 스프레드 시트를 작성하고 있으며 5 개 일요일이 4 개월이 아닌 한 달에있을 때 일부 보조 계정에 추가 자금이 제공됩니다.

내가 참조 해야하는 유일한 셀은 셀 A1에 있고 현재 월과 같은 시트의 제목입니다. 예를 들어6/1/14

— wbeard52
소스

12

A1매월 시작일 이 어디 인지 보십시오 .

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))),"ddd")="Sun"))

시작 날짜 와 종료 날짜 "Sun"로 바꾸어 요일 변경 과 날짜 범위에 사용할 수도 있습니다 .A1EOMONTH(A1,0)

— 제이 아르
소스

1

와. 이것은 정말 창의적입니다. 이해하겠습니다. 간접 및 행 함수를 사용하여 한 달 전체의 날짜 값을 작성합니까? 그런 다음 Sun, Mon 등의 형식으로 텍스트로 변환합니다. Sun의 상태를 평가하고 결과를 1 또는 0으로 변경 한 다음 결과를 합산합니다. 그 맞습니까?

— wbeard52

yup 정확하게 .. :)

— Jay-ar

9

언급 한 날짜가 항상 첫 번째 달인 경우이 날짜도 작동합니다.

=INT((WEEKDAY(A1-1)+EOMONTH(A1,0)-A1)/7)

— 테일 린
소스

단순한. 위의 공식에 비해 매우 우아합니다. 감사.

— wbeard52

3

이전 답변과 매우 유사하지만 조금 더 깨끗합니다 ...

=SUMPRODUCT(N(WEEKDAY(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))))=1))

— 사용자
소스

3

=DAY(EOMONTH(A1,0))-NETWORKDAYS.INTL(A1,EOMONTH(A1,0),11)

편집 : NETWORKDAYS.INTL이 언제 도입되었는지 확실하지 않은 Excel 2016에서 작동합니다.

— SRCP
소스

Networkdays.Intl은 모든 엑셀에서 작동하지 않습니다

— yass

아 맞아. 그가 2016 년을 말하는 것을 보지 못했습니다. 2016 년이 있습니다. 네트워크 데이와 달리 Networkdays.intl을 사용하면 주말을 선택할 수 있습니다. 이 경우 주말에 일요일 만 있다고 Excel에 말했는데, 이것이 11의 약자입니다. 따라서 일요일을 계산하지 않는 기간의 일수를 제공합니다.

— SRCP

NETWORKDAYS.INTLExcel 2010 부터 사용할 수 있습니다 . 이름 옆에 숫자 2010이 있습니다. Excel 2010에서 작동하는 스크린 샷

— phuclv

1

나는이 고양이를 피부에 바르는 또 다른 방법을 찾았다 고 믿는다.

날짜를 입력하지 않고 프로젝션을위한 큰 시트 (예 : 18 개월)가 필요한 경우 수식에 월과 연도를 알려주고 그에 따라 형식을 지정할 수 있습니다. 이것은 해당 요일이 포함 된 헤더 셀에 대한 절대 참조와 결합되었으며 훨씬 더 작고 깔끔한 테이블이 있습니다 (제 의견으로는).

A3 = Jan, B3 = 2017, C2 : I2 = 3 Char Day 약어 (예 : SUN)

C3 셀에 수식 입력

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy"))&":"&EOMONTH(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy")),0))),"ddd")=C$2))

즐거운 사냥

— 제레미 캐스트
소스

1

의 첫 번째 요일이 필요하지 않은 허용되는 답변 의 약간의 변형입니다 A1.

이것은 다음으로 대체 A1하여 달성됩니다 .

date(year(today()),month(today()),1)

이것은 이번 달에 원하는 것으로 가정합니다.

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(date(year(today()),month(today()),1)&":"&EOMONTH(date(year(today()),month(today()),1),0))),"ddd")="Sun"))

— CalvT
소스