내 스크립트 Batch_Admin을 사용하여 모든 유형의 Batch 자체 스크립트 또는 BAT 또는 .CMD에서 사용할 수 있도록 관리자를 자동으로 상승시킬 수 있습니다. 이 기능은 표준 도구를 사용하여 다른 Windows 시스템에서와 같은 방식으로 표준 환경에서 작업 할 수 있도록합니다. 여러 표준 및 내장 Windows 명령을 사용합니다. 다른 외부 스크립트를 사용하지 마십시오. 스크립트 배치뿐만 아니라 모든 프로그램을 관리자로 호출하는 데 사용할 수 있습니다. 작은 스크립트를 작성하면 Administartor 권한이 필요한 프로그램을 호출 할 수 있습니다. 검색 경로 폴더 (% PATH %)에이를 배치하십시오.
이를 사용하려면 관리자로 실행될 상위 배치 스크립트에 다음 행 (정확히)을 삽입하면됩니다. 이는 상위 스크립트 상단에서 수행하는 것이 가장 좋으며 먼저 CALL을 통해 호출되는 일부 하위 스크립트를 사용하는 것이 가장 좋습니다 (아래의 자세한 설명 참조).
net session >nul 2>nul&if errorlevel 1 Batch_Admin "%~0" %*
이것은 CALL 구문에 의해 호출되는 모든 하위 스크립트 안에 삽입 될 수 있습니다. 메시지에 여전히 관리자 권한이없는 동안 메시지를 표시하려면 Batch_Admin을 호출하기 전에 5 초 동안 "ShowAdminInfo"변수를 초 수로 설정하십시오.
SET ShowAdminInfo=5
net session >nul 2>nul&if errorlevel 1 Batch_Admin "%~0" %*
작동 방식 :
• VBScript를 통해 UAC.ShellExecute를 호출하여 사용자 권한을 가져옵니다.
• 배치는 스크립트 또는 BAT 또는 CMD를 실행합니다.
• 스크립트 호출자는 호출에 긴 이름 공간을 따옴표로 묶을 수 있습니다.
• 호출이 전송되지 않은 것처럼 명령 줄에서 전달 된 마스터 스크립트를 호출하는 모든 매개 변수를 반환하고 느낌표 (!) 및 백분율 (%)과 같은 특수 문자를 사용하여 처음부터 무언가를 시작합니다. 괄호 ()
•이 스크립트가 마스터 인 디렉토리에서 호출이 발생한 경우 마스터 스크립트 위치를 유지합니다.
• 보조 변수 앞에 "ShowAdminInfo"변수를 설정하면 메시지가 표시됩니다. 추가 정보를 제공하는 관리자의 권한을 즉시 전달하고 정보에 입각 한 결정을 내릴 수없는 5 초 동안. 설정해야하는 설정의 예 : SET ShowAdminInfo = 5 기본적으로이 변수는 정의되어 있지 않으므로 표시되지 않습니다.
• 스크립트는 시스템 검색 경로 % PATH % 및 네트워크 리소스 (예 : \ Computer \ share \ test.bat)에서도 호출합니다.
• 스크립트가 거의 동시에 여러 Batch_Admin을 호출 할 때 필요한 보조 파일을 작성하는 데 대한 오해를 방지합니다. 1에서 100 사이의 난수를 사용합니다.
• 그러나 가장 좋은 방법은 부모 스크립트에서 사용하는 것입니다. 관리자 권한으로 전환하려면 항상 변수에 의존하지 않고 새 창에서 새 환경에서 스크립트를 완전히 다시 실행해야합니다. 변수는 이전에 스크립트에 설정되어 있으며 이러한 변수의 값이 전달되지 않아 관리자로 호출 할 수 없습니다. . 스크립트 만 다시 실행됩니다.
완전한 스크립트 Batch_Admin 아래. 이에 대한 자세한 정보는 내 사이트에 있습니다.
다음 텍스트를 메모장에 복사하여 디스크에 다음과 같이 저장하십시오. Batch_Admin.bat
@echo off
if "%~1"=="" (echo *** Batch_Admin ***&echo.&echo Automatically get admin rights for another Batch. See info inside.&TIMEOUT /T 30>nul&goto:eof)
:: A D M I N I S T R A T O R - Automatically get admin rights for script batch. Paste this on top: net session >nul 2>nul&if errorlevel 1 Batch_Admin "%~0" %*
:: Also keep Batch directory localisation and then set variable: PATH_BAT
:: if earlier variable "ShowAdminInfo" is empty (not defined) then no info, else showing info with number of seconds
::
:: Elaboration: Artur Zgadzaj
setlocal
setlocal DisableDelayedExpansion
SET "Localy="
if exist "%~1" SET "Localy=YES"
if exist "%~1.BAT" SET "Localy=YES"
if exist "%~1.CMD" SET "Localy=YES"
if defined Localy FOR %%I IN ("%~1") DO SET "PATH_BAT=%%~dI%%~pI"
SET P1=%~1
SET Parameters=%*
SET Parameters=%Parameters:!=^^!%
setlocal EnableDelayedExpansion
SET Parameters=!Parameters:%P1%=!
SET Parameters=!Parameters:%%=%%%%!
setlocal DisableDelayedExpansion
SET Parameters=%Parameters:~3%
net session >nul 2>nul&if not errorlevel 1 goto Administrator_OK
if not defined ShowAdminInfo goto skip_message_Administrator
echo.
echo Script: %~1
echo.
echo *****************************************************************
echo *** R U N N I N G A S A D M I N I S T R A T O R ***
echo *****************************************************************
echo.
echo Call up just as the Administrator. You can make a shortcut to the script and set:
echo.
echo shortcut ^> Advanced ^> Running as Administrator
echo.
echo Alternatively run once "As Administrator"
echo or in the Schedule tasks with highest privileges
echo.
echo Cancel Ctrl-C or wait for launch %ShowAdminInfo% seconds ...
TIMEOUT /T %ShowAdminInfo% > nul
:skip_message_Administrator
MD %TEMP% 2> nul
SET /A $Admin$=%RANDOM% * 100 / 32768 + 1
SET "Percent="
del "%TEMP%\$Admin_%$Admin$%_Test.bat" 2>nul
echo %Parameters% > "%TEMP%\$Admin_%$Admin$%_Test.bat"
if not exist "%TEMP%\$Admin_%$Admin$%_Test.bat" SET Percent=^"
del "%TEMP%\$Admin_%$Admin$%_Test.bat" 2>nul
echo @SET "PATH_BAT=%PATH_BAT%" > "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat"
echo @SET "BatchFullName=%BatchFullName%" >> "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat"
if defined Localy (echo @CD /D "%PATH_BAT%" >> "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat")
echo @"%~1" %Parameters% %Percent% >> "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat"
echo SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\$Admin_%$Admin$%_Batch_getPrivileges.vbs"
echo UAC.ShellExecute "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat", "", "", "runas", 1 >> "%TEMP%\$Admin_%$Admin$%_Batch_getPrivileges.vbs"
"%TEMP%\$Admin_%$Admin$%_Batch_getPrivileges.vbs"
endlocal
exit /B
:Administrator_OK
"%~1" %Parameters%
goto:eof
REM *** A D M I N I S T R A T O R - Automatically get admin rights (The End) ***
