다음 1, 2, 3, 4, 5과 같이 정수가있는 열이 있습니다. 이 값을 다음과 같이 길이가 3으로 채워진 다른 열을 만들고 싶습니다 001, 002, 003, 004, 005.

Google 스프레드 시트에서 문자열을 길이에 맞출 수 있습니까?

이것에 대한 표준 기능을 찾을 수 없었습니다.

권장되는 방법은 TEXT () 함수 를 사용하는 것입니다 .

귀하의 경우에 어떻게 사용하는지에 대한 간단한 요약 :

=TEXT(5,"000")

출력 :

005

물론 리터럴 5를 소스 번호가있는 다른 셀에 대한 참조로 대체해야합니다.

표시 변경 만 원하는 경우 사용자 지정 숫자 형식 "000"을 셀에 적용 할 수 있습니다 .

셀을 선택하고 형식> 숫자> 추가 형식> 사용자 정의 숫자 형식 ...을 클릭하십시오 .

에서 문서 편집기 도움말 :

숫자의 숫자입니다. 결과에 중요하지 않은 0이 나타납니다.

임시 솔루션

여기에 내가 생각해 낸 임시 해결 방법이 있습니다.

작업 공식

이 공식을 사용하십시오.

`=IF(LEN(A2)<3, CONCATENATE(REPT("0", 3-LEN(A2)), A2), A2)`

3패딩 길이 0와 패딩 문자로 교체하십시오 . A2패딩 소스입니다.

설명

다음 스프레드 시트를 고려하십시오.

-------------
| A   |  B  |
-------------
| 1   | 001 |
-------------
| 2   | 002 |
-------------
| 31  | 031 |
-------------
| 45  | 045 |
-------------
| 500 | 500 |
-------------

채우려는 정수가있는 초기 열 (A)이 있습니다. (B) 열에는 데이터를 처리하는 특수 수식이 포함됩니다.

사슬 같이 잇다!

우선 우리 A는 패딩 문자열로 열의 값을 연결하는 방법이 필요 합니다. 우리는 CONCATENATE기능으로 이것을 할 수 있습니다 :

=CONCATENATE("00", A2)

반복!

지금은 패딩 문자 0가 수식에서 두 번 반복됩니다. 이것은 좋지 않습니다. 이 REPT함수를 사용 하여 다음과 같이 패딩 문자를 여러 번 반복 할 수 있습니다 .

=REPT("0", 2)

이 공식은 0두 번 반복 됩니다. 그것들을 결합합시다 :

=CONCATENATE(REPT("0", 2), A2)

길이를 계산하십시오!

그게 낫다. 그러나 패딩 길이는 수식에서 상수 값을 가지며 9보다 큰 숫자에서는 작동하지 않습니다. 패딩 된 문자열의 길이를 계산하여 ( LEN함수 사용 )이를 목표 길이에서 빼서이 문제를 해결할 수 있습니다 .

=3-LEN(A2)

그것을 우리의 공식에 추가합시다 :

=CONCATENATE(REPT("0", 3-LEN(A2)), A2)

그러나 999보다 큰 값에 대해서는 음수 결과가 표시되고 REPT함수 가 중단 됩니다 (반복 횟수는 음수 일 수 없음).

조건을 추가하여 쉽게 해결할 수 있습니다.

=IF(LEN(A2)<3, "APPLY REPT", "OUTPUT AS IS")

마지막 평화를 함께합시다 :

=IF(LEN(A2)<3, CONCATENATE(REPT("0", 3-LEN(A2)), A2), A2)