Excel에서 시트 간을 전환하는 키보드 단축키

Excel 2007에는 워크 시트 간을 전환하는 키보드 단축키가 있습니까?

Ctrl+ PgUp는 왼쪽으로 이동합니다.

Ctrl+ PgDn오른쪽으로 이동합니다.

첫 번째 또는 마지막 시트를 활성화하는 VBA 매크로 및 사용자 정의 키보드 단축키

실제 키보드 바로 가기를 첫 번째 또는 마지막 워크 시트로 이동하려면 "PERSONAL"통합 문서의 모듈에이 코드를 입력하십시오.

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

개발자 탭> 매크로로 이동하십시오. 이 매크로 (ToFirstSheet 및 ToLastSheet)를 찾아보십시오. 하나를 선택하고 옵션을 클릭 한 다음 키보드 단축키를 지정하십시오. 다른 쪽도 똑같이하십시오.

이를 "개인"통합 문서에 저장하면 모든 Excel 파일에서 사용할 수 있습니다.

이전 또는 다음 시트를 활성화하기 위해 내장 된 키보드 단축키

한 워크 시트를 왼쪽이나 오른쪽으로 이동하려면 다음과 같은 기본 키보드 단축키를 사용할 수 있습니다.

Ctrl+PgUp

Ctrl+PgDn

이전 또는 다음 시트를 활성화하는 VBA 매크로

VBA를 사용하여 동일한 작업을 수행하는 방법은 다음과 같습니다.

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

이전 또는 다음 시트를 반환하는 VBA 함수

이전 또는 다음 워크 시트 개체를 얻으려면이 함수를 사용하십시오.

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

다음과 같은 기능을 사용하십시오.

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub

단축키를 사용하여 Go대화 상자 로 이동할 수도 있습니다 . 그런 다음 foo!A1"foo"라는 시트에서 왼쪽 상단 셀로 이동하는 것과 같은 것을 입력 할 수 있습니다 . 페이지 업 및 페이지 다운은 일반적으로 빠르지 만 잘 명명 된 시트가 많은 경우 (예 : 20+ 이상) 더 빠를 수 있습니다. 시트에 테이블 이름을 지정한 경우 Go도 잘 작동합니다.

일반적으로 F5를 누르면 Go대화 상자 가 열립니다 .