다른 셀 값을 기반으로하는 형식 범위

다음 Excel 스프레드 시트를 고려하십시오.

셀 A4 : B7의 값에 따라 row1 : 2의 셀을 포맷하고 싶습니다. 값을 변경하면 row1 : 2의 셀이 병합되고 경계가 채워지며 채워지고 텍스트에 따라 색상이 지정되어야합니다.

서식 셀을 다음과 같이 변경하면

VBA 솔루션은 다음과 같습니다. Format테이블 의 배경색과 글꼴 색을 복사 하므로 흰색 텍스트를 원하면 해당 테이블에 흰색 텍스트를 사용하십시오. 테두리 설정 (39 및 47 행)과 사용할 형식 조건 (27-30 행)을 조정할 수 있습니다. 예를 들어 실제 데이터와 거의 관계가없는 순수한 모형 인 경우에 특히 그렇습니다.

Option Explicit
Sub MadeFormattedHeadings()

    'Declarations
    Dim ws As Worksheet
    Dim headerRange As Range
    Dim rangeSize As Integer
    Dim rangeStart As Integer
    Dim r As Long
    Dim c As Integer

    'Choose the worksheet to use
    '(Pick one of these two methods)
    Set ws = Worksheets("Sheet1")   'This uses the name on the tab seen in Excel
    Set ws = Sheet1                 'This uses the code name seen in VBA

    With ws

        'Remove previous headers
        If UCase(.Range("A1").Value) = UCase(.Range("A5").Value) Then
            .Rows("1:2").Delete
            .Rows("1:2").Insert
        End If

        'Add new headers
        rangeStart = 1
        For r = 5 To 8  '<<<< There are other methods to iterate. This is just one option.
            'Save the settings
            Set headerRange = .Range("A" & r)
            rangeSize = .Range("B" & r).Value

            'Format the first row
            With .Range(.Cells(1, rangeStart), .Cells(1, rangeStart + rangeSize - 1))
                .Merge
                .Value = headerRange.Value
                .HorizontalAlignment = xlCenter
                .Font.Color = headerRange.Font.Color
                .Interior.Color = headerRange.Interior.Color
                .BorderAround xlSolid, xlThin
            End With

            'Format the second row
            With .Range(.Cells(2, rangeStart), .Cells(2, rangeStart + rangeSize - 1))
                .Merge
                .Value = rangeSize
                .HorizontalAlignment = xlCenter
                .BorderAround xlSolid, xlThin
            End With

            'Iterate to the next section
            rangeStart = rangeStart + rangeSize
        Next

    End With

End Sub