Excel에서 회계 연도의 주 결정

2 / 1 / 14-1 / 31 / 15 범위의 데이터 세트에 대해 회계 연도 1-53 주를 얻으려고합니다. 회계 연도의 첫날을 별도의 주로 설정합니다.

이 =WEEKNUM()함수는 연도의 주를 제공하지만 회계 연도의 겹침을 만듭니다. 예를 들어, 보통 주 5 주일에는 2014 년 2 월 1 일과 1/31/15 일에 레이블이 지정됩니다.

데이터 세트의 예 :

Transaction_Date
2/1/14
2/2/14
3/5/14
10/2/14
1/1/15

원하는 결과 :

Transaction_Date    Week_Of_Fiscal_Year
2/1/14               1
2/2/14               2
3/5/14               6
10/2/14             36
1/1/15              49
1/31/15             53

내 접근 방식은 회계 연도를 달력 연도의 시작 부분으로 "이동"하는 것이므로 weeknum올바른 결과를 계산하십시오
=WEEKNUM(A2-31,10+WEEKDAY(DATE(YEAR(A2-31),1,2),2)).

• A2-31 "전환 된"날짜입니다. 31 일 전에 모든 항목을 이동하면 2 월 1 일이 1 월 1 일이됩니다.
• WEEKDAY(DATE(YEAR(A2-31),1,2),..) 이것은 현재 회계 연도의 첫 번째 요일을 가져 오는 것입니다 (2 월 1 일은 첫 번째 주이고 두 번째주는 2 월 2 일에 시작하므로 첫 번째 요일도 이동 날짜 이후 (1 월 2 일)입니다).
  • 10+WEEKDAY(...,2))
  • 두 번째 인수는 WEEKNUM요일의 첫 번째 요일이며 월요일은 11, 화요일은 12입니다 ...
  • 두 번째 인수 WEEKDAY는 요일의 시작일이며 2MONDAY 에 사용해야 합니다.
  • 10+ 1-7에서 11-17로 변환

이 공식은 매년 적용되며, 2 월 1 일에 회계 연도 시작, 2 주차에 시작하면 공식에 "하드 코딩"됩니다.

WEEKNUM 번역 작업을 시작하여 달력 연도 전환 등을 처리 한 후 간단하고 단호한 방법이 있다는 것을 깨달았습니다.

열 A는 당신의 날짜입니다. B 열은 회계 연도의 주입니다. FY의 첫 번째 날 (2 월 1 일)은 A2에 참조 날짜로 입력되며 항상 1 주일이므로 B2에 하드 코딩 될 수 있습니다.

후속 날짜에 대한 공식은 B3에서 복사 할 수 있습니다.

=CEILING((WEEKDAY(A$2)+A3-A$2)/7,1)

설명

이는 거래 날짜와 회계 연도 1 일의 차이와 주에 7 일이 포함되어 있다는 사실에 의존합니다. WEEKDAY 함수는 FY가 시작되는 요일을 고려하고 날짜 차이 및 CEILING 함수는 트랜잭션이 시작되는 요일로 인한 소수 부분 차이를 처리합니다.

거래 날짜 입력을 제어 할 수 있기 때문에 내년 1 월 31 일 이후의 날짜에 대한 오류 검사를 포함 할 필요는 없습니다.

______

참조 날짜가없는 솔루션

FY의 첫날을 입력하지 않으려는 경우 거래 날짜에서 파생 일을 얻을 수 있습니다. 예를 들어 B3에서는 A $ 2 셀을 참조하는 대신 다음을 사용할 수 있습니다.

DATE(YEAR(A3)-IF(MONTH(A3)=1,1,0),2,1)

거래일로부터 FY를 결정하고 해당 연도의 2 월 1 일로 변환합니다. 원래 솔루션의 간단한 공식은 다음과 같습니다.

=CEILING((WEEKDAY(DATE(YEAR(A3)-IF(MONTH(A3)=1,1,0),2,1))+A3-DATE(YEAR(A3)-IF(MONTH(A3)=1,1,0),2,1))/7,1)

회계 연도 4 4 5 일정에 따라 주 번호를 계산하는 훨씬 간단한 솔루션을 찾았습니다.

= ISOWEEKNUM (오늘 () -301)

-301은 캘린더가 1 월에 시작된 것처럼 회계 캘린더에 대한 조정을 나타냅니다. 우리의 경우 회계 연도는 일반적으로 10 월 말에 시작되므로 일반적으로 날짜 조정이 더 커집니다. 따라서 연도가 시작되는 곳과 연차가 지연되는지 여부에 따라 올바로 작동하려면 더하거나 빼야합니다. 어느 쪽이든, 그것은 간단한 수학입니다.

분명히 셀 내의 날짜 값을 계산하려면 TODAY ()를 셀 참조로 변경하십시오. = ISOWEEKNUM (A1-301)