빈 줄에 zsh 탭 완성

나는 찾을 수 없었던 tcsh'ism을 원합니다. 내용이없는 빈 줄에서 탭 키를 누르고 ls와 동등한 것을보고 싶습니다. 즉 내가 원하는 말

$ <tab>

다른 것을하고 나에게 \ t를주는 것. 명령 완료를위한 환상적인 리소스를 찾았지만이 기본 사례에는 해당되지 않습니다. 이것에 대한 도움이 될 것입니다! 감사.

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

Tab행 시작 부분의 동작은 스타일에 의해 제어됩니다 . 그러나 지원되는 동작은 두 가지뿐입니다.insert-tab

• 평소대로 완료 zstyle ':completion:*' insert-tab false
• 아래에 탭을 삽입 zstyle ':completion:*' insert-tab true
• 아래에서 하나 또는 다른 하나 zstyle ':completion:*' insert-tab pending[=N]

해당 위치에서 명령을 완료하려면 zstyle ':completion:*' insert-tab true수행하십시오. 현재 디렉토리에 파일을 나열하는 것과 같이 다른 것을 원하면을 수정해야합니다 _main_complete.

zsh-workers 목록 의 최근 스레드에 대해 설명했습니다 insert-tab.

빈 줄에서 tab을 누르면 zsh에서 tcsh의 자동 목록이 완전히 구현됩니다.

% <TAB>

여기있어:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

tcsh를 더 자세히 모방하려면 .zshrc에도 추가하십시오.

unsetopt always_last_prompt       # print completion suggestions above prompt

빈 줄뿐만 아니라 명령을 입력하는 동안 TAB 사용을 향상시키는 이 zsh 위젯을 작성 했습니다 .

• 빈 명령 줄과 명령 중간에 파일 을 나열 합니다 .
• 빈 명령 행에 디렉토리 를 나열 합니다.
• 빈 명령 줄에 실행 파일 이 나열 됩니다.

전역 변수가있는 경우 "cd"또는 "./"를 앞에 추가하도록 구성 할 수 있습니다.

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA